[Résolu][Calc] Différence de comportement des dates.

[stefalci]

Bonjour à Toutes et Tous,

Je reviens vers vous pour vous soumettre un test de comportement car je ne sais plus dans quelle direction chercher.
Après de nombreux essais, j'ai repris un exemple simplifié du livre de Bernard et Laurent et je constate la même différence.
Je collecte par macro, différentes dates dans des boites de dialogue.
Sur WXP et en LO 3.6 tout fonctionne comme je le souhaite.
Sur W7-64 en LO 4.5 j'obtiens systématiquement une erreur sur l’exécution de la commande de récupération de la date dans le champ.
J'ai donc réduit au maximum l'appli et vous propose l'essai pour me confirmer sur d'autres environnements ce changement de comportement

Ci joint une petite macro de test et le message d'erreur sur la deuxième feuille du classeur.

Merci

[Dude]

Opération lunettes de vue : https://forum.openoffice.org/fr/forum/v ... =8&t=41236

[stefalci]

Merci de ce guidage Dude, j'avais lu ce post mais je ne vois pas comment faire pour récupérer la date en entier
et au format (jj/MMMM/AAAA).
Les seuls résultats que j'obtienne sont les arguments séparés JJ, MM, AAAA
Existe t il d'autres pistes pour capturer la date formatée d'un controle. J'ai un peu d'expérience en basic mais je
ne maitrise pas toutes les subtilités et dans le cas présent Xray ne m'apporte pas de solution, ou du moins j'en ai
pas trouvée.

Merci de la piste

[Churay]

../.. au format (jj/MMMM/AAAA).
Les seuls résultats que j'obtienne sont les arguments séparés JJ, MM, AAAA

Code : Tout sélectionner

sDate = sVarJJ & "/" & sVarMMMM & "/" & sVarAAAA

[stefalci]

Merci Churray, mais ca je sais faire et ne correspond pas à mon besoin.

Dans un dialogue, je récupère une date avec un contrôle date déroulant.
Jusqu'à maintenant je savais gérer avec CDateFromISO pour ma macro en LO 3.6
Avec LO 4.1.5 ca ne fonctionne plus, confirmé par les infos de Dude.
Comment je fais maintenant, pour traiter cette date avec les différents formats
dont j'ai besoin.

Désolé d'insister, mais l'exemple donné dans : https://forum.openoffice.org/fr/forum/v ... =8&t=41236
ne m'a pas été très utile car certains éléments me sont incompréhensibles. Je suis juste un débutant averti.

Merci de votre patience

[luky-luke]

Bonjour

La propriété Date du champs DateField Avec LibO 4.xxx n'est pas au format ISO. Donc Le CDateFromISO provoque une erreur.

Les seuls résultats que j'obtienne sont les arguments séparés JJ, MM, AAAA

Il te suffit d'assembler ces éléments :

Code : Tout sélectionner

Sub demanderDate()
Dim dlg As Object
Dim champDate As Variant, dateISO as Variant, laDate As Date
Dim a As Integer, m As Integer, j As Integer
Dim Jour As Long, Mois As Long, Annee As Long
dlg = CreerDialogue("Standard", "Dialog1")
if dlg.execute = com.sun.star.ui.dialogs.ExecutableDialogResults.OK then
	champDate = dlg.getControl("DateField1")
	dateISO = champDate.Date
		if IsNumeric(dateISO) Then
  			laDate = CDateFromISO(dateISO)
  		Else 'pour LibO 4.xxx
  			Jour = dateISO.Day
  			Mois = dateISO.Month
  			Annee = dateISO.Year
  			laDate = Jour & "/" & Mois & "/" & Annee
		End if
  print laDate
end if
dlg.dispose
End Sub

Le contrôle au format numérique va permettre au code de fonctionner indifféremment avec AOO ou LibO. C'est un peu lourd, mais cela à le mérite de fonctionner...... J'espère

Cordialement
Luke

[Piaf]

Bonjour
Pas forcement tout compris.

je ne vois pas comment faire pour récupérer la date en entier
et au format (jj/MMMM/AAAA).

A tester donc sous les dernières versions de LibO.

Code : Tout sélectionner

Sub OuvrirDialog	
Dim bibli As Object, monDialogue As Object, oDlg as Object
	DialogLibraries.LoadLibrary("Standard")
	bibli = DialogLibraries.GetByName("Standard")
	monDialogue = bibli.GetByName("Dialog1")
	oDlg = CreateUnoDialog(DialogLibraries.Standard.Dialog1)
	oDlg.Execute
End Sub

Sub AfficherDate(oEV As Object)
Dim dlg As Object
Dim monCtrl As Object, MaDate As Object
	dlg = oEv.Source.Context
	monCtrl = dlg.getControl("DateField1")
	MaDate = monCtrl.Date
	MsgBox("La date formatée : " & Format(CDateFromUnoDate(MaDate),"dd/mmmm/yyyy"))
End Sub

A+

[luky-luke]

Bonsoir

Pour compléter la réponse et avoir un code qui fonctionne avec LibO et AOO version 3.xxx ou 4.xxx, avec la date au format que l'on souhaite (merci Piaf pour la piqûre de rappel)

Code : Tout sélectionner

Option Explicit

Sub FormatDate
Dim oNDlg As Object
Dim champDate As Object, Madate as Variant, laDate As Date
Dim Jour As Long, Mois As Long, Annee As Long
oNDlg = CreateUnoDialog(DialogLibraries.Standard.Dialog1)
if oNDlg.execute = com.sun.star.ui.dialogs.ExecutableDialogResults.OK then
	champDate = oNDlg.getControl("DateField1")
	Madate = champDate.Date
		if IsNumeric(Madate) Then
  			laDate = CDateFromISO(Madate)
  		Else
  			Jour = Madate.Day
  			Mois = Madate.Month
  			Annee = Madate.Year
  			laDate = Jour & "/" & Mois & "/" & Annee
		End if
	print Format(laDate,"dd/mmmm/yyyy")
	print Format(laDate,"dddd dd mmmm yyyy")  
end if
oNDlg.dispose
End Sub

Cordialement
Luke

[Dude]

Rappelons quand même que CDateFromISO a un comportement aléatoire qui peut retourner une erreur si présence de séparateur.
Voir ticket 109652

[Churay]

Yeap

Ce qui me rappelle

Bonsoir

Personnellement, ce qui me gêne :
- le rythme soutenu des sorties de LO même si j'en comprends la démarche. Pour des raisons de cuisine interne, je n'ai pas opté pour la solution la plus simple des mises-à jour.
- à chaque mise à jour, les surprises inévitables
- la divergence des API : pour coder une macro même simple, il faudra tôt ou tard commencer à déterminer où on a atteri et prévoir le code en conséquence si on veut qu'elle passe un peu partout (ou prévoir de dire qu'elle fonctionne pas nécessairement sur telle ou telle suite : original isn't..)
- l'éventuelle nouvelle interface héritée de Symphony qui ne me plait pas

A l'époque je pensais tester si on est sous AOO | LO...
Dans les deux cas, il faut (depuis quelques temps), pousser la plaisanterie jusqu'au test de la version... et coder en conséquence...
On se fait à tout...

[stefalci]

Tout d'abord merci à Dude, Churay, Piaf et luky-luke de leur réactivité.

Je vais tester dans la journée. Je garderai tout de même le test de version par rapport aux remarques de Dude sur
le CDateFromISO. Et si problème, j'en ai déjà la cause et la solution.

Je confirme ça marche à merveille, et en plus je peux l'utiliser qq soit la version de LO.

Encore merci aux contributeurs

Cordialement