[Risolto]Automatismo tra fogli

[maxvero]

“ Sempre più difficile”, ovviamente per me e non certo per gli amici super esperti del forum di LibreOffice Calc.
Non so se tecnicamente sia possibile risolvere il mio quesito, io ci provo e spero sempre nella vostra disponibilità/pazienza/cortesia.
Devo creare un automatismo in un file piuttosto “corposo” che ho impostato.
Per semplificare ho estrapolato un modulo di esempio per poter esplicare il mio quesito (vedi file allegato).
Nel foglio TEMPISTICHE nella cella I2:L2 copio la data di: foglio1 D7 o foglio2 D7 ( o una delle celle Data riquadrate in rosso );
in automatico nelle celle I1:J1 e K1:L1 del foglio TEMPISTICHE dovrebbero copiarsi le celle
k2 - k4 o V2 – V4 o AG2 – AG4 del foglio1
lo stesso automatismo/concetto si deve riproporre con tutte le altre celle riquadrate in rosso dei fogli 1 e 2.
Per farmi capire visivamente allego anche una immagine.
Grazie a tutti e salutoni.

[gioh66]

Buondì. Sperando di aver ben compreso la tua necessità, ti propongo una soluzione con due celle aggiuntive, una per recuperare il nome del foglio e una per indicare da quale blocco estrarre i dati.
Le celle sono la N2 e O2 del foglio "TEMPISTICHE" e che sono alimentate da menù a tendina per cambiare i dati di ricerca.
Fatto ciò ho modificato la formula che richiama la data con

Codice: Seleziona tutto

=INDIRETTO(N2&"."&INDIRIZZO(7;11*O2-7;4))

e poi in I1 e K1 ho messo rispettivamente le seguenti formule

Codice: Seleziona tutto

=INDICE(INDIRETTO(N2&".A2:AG4");1;CONFRONTA($I$2;INDIRETTO(N2&".a7:AG7");0)+7)

e

Codice: Seleziona tutto

=INDICE(INDIRETTO(N2&".A2:AG4");3;CONFRONTA($I$2;INDIRETTO(N2&".A7:AG7");0)+7)

Ti riallego il file con cui fare prove.

[maxvero]

Grazie gioh66.
La vedo dura anche perchè ho notato che non ti ho dato tutti gli elementi corretti, infatti faccio riferimento a delle celle che però nell' immagine non identifichi se non con l'intuito.
Giustamente mi scrivi "sperando di aver ben compreso", hai perfettamente ragione.
Con calma cercherò di essere più preciso.
Buona serata a presto

[maxvero]

Spero di essere sufficientemente capibile, anche se non facile.
Saluti alla prossima.

[gioh66]

Con il sistema che ho impostato io puoi scegliere da quale foglio prendere la data e quale delle tre e ottenere il risultato che vuoi.
Se fai con il copia e incolla come fai a far capire alle formule qual'è il foglio da cui vuoi prendere i dati?
Ps.: io ho dato per scontato che le date siano univoche. È così o possono essere ripetute sullo stesso foglio?
Se non lo sono allora bisogna che modifichi le formule.

[maxvero]

Sono univoche, le tre date che ci sono sui singoli fogli non potranno mai essere uguali ( esempio le tre date del foglio 1 cella D7, O7 e Z7 mai uguali ). La stessa data però la potrei trovare su una sola delle stesse 3 celle ma di un altro foglio.
Gentilissimo.

[gioh66]

Buondì. Allora ci ho studiato un po' e ho trovato la soluzione senza celle d'appoggio.
In I1 e K1 ho messo rispettivamente

Codice: Seleziona tutto

=INDICE(INDIRETTO(STRINGA.ESTRAI(FORMULA(I2);2;TROVA(".";FORMULA(I2))-1)&"A1:AG4");2;CONFRONTA(I2;INDIRETTO(STRINGA.ESTRAI(FORMULA(I2);2;TROVA(".";FORMULA(I2))-1)&"A7:AG7");0)+7)

e

Codice: Seleziona tutto

=INDICE(INDIRETTO(STRINGA.ESTRAI(FORMULA(I2);2;TROVA(".";FORMULA(I2))-1)&"A1:AG4");4;CONFRONTA(I2;INDIRETTO(STRINGA.ESTRAI(FORMULA(I2);2;TROVA(".";FORMULA(I2))-1)&"A7:AG7");0)+7)

Le formule, tramite la funzione FORMULA annidata in STRINGA.ESTRAI, ricavano il nome del foglio da I2, che messa dentro INDIRETTO ricostruiscono i range per la funzione INDICE e CONFRONTA.
Allego file di prova.

[maxvero]

Ciao gioh66 non sono sparito, bellissima soluzione era quello che immaginavo e cercavo.
Ma ( c’è sempre un ma ) sono in difficoltà, è da due giorni che cerco di adattare la tua ottima soluzione al mio file però senza riuscirci.
Purtroppo le mie scarse conoscenze tecniche mi costringono a grandi limiti.
Le due formule che mi hai indicato in I1 e K1 differiscono solo nei due valori 2 e 4 da me evidenziati in rosso, a cosa fanno riferimento, e poi a cosa si riferisce FORMULA(I2) ?

=INDICE(INDIRETTO(STRINGA.ESTRAI(FORMULA(I2);2;TROVA(".";FORMULA(I2))-1)&"A1:AG4");2;CONFRONTA(I2;INDIRETTO(STRINGA.ESTRAI(FORMULA(I2);2;TROVA(".";FORMULA(I2))-1)&"A7:AG7");0)+7)
=INDICE(INDIRETTO(STRINGA.ESTRAI(FORMULA(I2);2;TROVA(".";FORMULA(I2))-1)&"A1:AG4");4;CONFRONTA(I2;INDIRETTO(STRINGA.ESTRAI(FORMULA(I2);2;TROVA(".";FORMULA(I2))-1)&"A7:AG7");0)+7)

Per semplicità io nel “modulo di esempio.ods” ho indicato solo 3 fogli (TEMPISTICHE - foglio 1 – foglio 2 ), ma in realtà sono molti di più ed esattamente 14.
Quelli però su cui io devo intervenire sono 6 e più precisamente ( TEMPISTICHE – GABBIA 1 (nominato nell’esempio foglio 1) - GABBIA 2 (nominato nell’ esempio foglio 2) – GABBIA 3 – GABBIA 4 – GABBIA 5 ) . Quindi dovrei implementare la tua formula di altri 3 fogli (GABBIE 3,4,5).
Vorrei gentilmente arrivare a capire ( se ne sono capace ovviamente con i tuoi suggerimenti) come posso fare a modificare le tue due formule; formule per me non semplici.
Però dimmi in tutta sincerità se ci posso arrivare, non vorrei farti perdere tempo.
Grazie

[gioh66]

Ciao. Allora provo a spiegarti.
Ho usato la formula INDICE che è composta di quattro argomenti: il riferimento, che indica l'area su cui fare la ricerca, riga che indica da quale riga vengono presi i dati e colonna che indica la colonna di interesse.
Poi ci sarebbe il quarto argomento "area" che però non ci interessa.
Ora nel tuo esempio le righe che ci interessano sono la 2 e la 4, in quanto l'area da cui prendere i dati è la A1:AG4 e quello che ci interessa si trova su queste righe.
Per ricavare il nome del foglio, che prelevo da I2 (se ti posizioni su I2 e guardi nella barra della formula trovi la dicitura =$foglio 1.D7) uso la funzione FORMULA, annidata in STRINGA.ESTRAI, e con cui poi tramite la funzione INDIRETTO ricostruisco i range per le funzioni INDICE e CONFRONTA.
Per capire meglio, se in una cella metti

Codice: Seleziona tutto

=FORMULA(I2)

L'output sarà

Codice: Seleziona tutto

=$'foglio 1'.D7

poi mettendo questo risultato in STRINGA.ESTRAI con cui togliere il primo carattere e quelli dopo il punto, compreso, ottieni

Codice: Seleziona tutto

$'foglio 1'

che unito con & dentro la funzione INDIRETTO con"A1:AG4", da il range

Codice: Seleziona tutto

$'foglio 1'.A1:AG4

Questo è per il range della funzione INDICE.
Per la funzione CONFRONTA il range da ricavare sarà "nomefoglio".A7:AG7 da cui ricavare la posizione della data inserita in I2 aumentata di 7 posizioni, in quanto questi si trovano spostati di 7 colonne rispetto a dove sta la data sulla riga A7:AG7
Tutto questo automatizza l'estrazione dei dati a seconda di cosa metti in I2 e non importa quanti fogli hai.
L'importante è che tutti i fogli abbiano la stessa struttura come nell'esempio che hai pubblicato.
Spero di essere stato abbastanza chiaro.

[maxvero]

Ciao gioh66 quanto tempo mi stai dedicando, un enorme grazie.
Qualche piccolo tassello del puzzel delle indicazioni/istruzioni che mi hai dato l'ho capito, ma sono molto lontano dalla risoluzione finale. Ti allego disegnino di quello che ho capito ( credo sia poca cosa ).
Purtroppo mancano le basi, ma se hai voglia e tempo da perdere io ti seguo con grande soddisfazione di imparare cose nuove.
Però non crearti problemi nel dirmi che " sarà per un' altra volta".
Buona serata

[gioh66]

Ciao. Il risultato che ottieni con STRINGA.ESTRAI è quello che ho messo sotto

Codice: Seleziona tutto

$'foglio 1'

Se vuoi, un modo per vedere l'anteprima del risultato delle formule è selezionare la formula che ti interessa e premere F9 e compare un popup col risultato.
Guarda il video.
https://youtu.be/9QDTMYSVOI8

[maxvero]

Grazie, mi scuso per gli allegati ma faccio fatica a contenerli a 250 KB.

[gioh66]

Buondì. Allora partendo dal centro della formula se evidenzi questo

Codice: Seleziona tutto

STRINGA.ESTRAI(FORMULA(I2);2;TROVA(".";FORMULA(I2))-1)

vedi
questo nel popup

Codice: Seleziona tutto

$'foglio 1'.

se evidenzi questo

Codice: Seleziona tutto

STRINGA.ESTRAI(FORMULA(I2);2;TROVA(".";FORMULA(I2))-1)&"A1:AG4"

vedi questo

Codice: Seleziona tutto

$'foglio 1'.A1:AG4

nel primo INDIRIZZO. Nel secondo (quello del CONFRONTA) evidenziando
STRINGA.ESTRAI(FORMULA(I2);2;TROVA(".";FORMULA(I2))-1)&"A7:A7"
vedi

Codice: Seleziona tutto

$'foglio 1'.A7:A7

Ps.: la stringa bianca che mostri nell'immagine è lo screen tip di aiuto alla composizione delle formula.
Per vederlo una volta che hai messo la formula in modalità modifica (o mentre la costruisci) basta fare un click all'interno della formula e ti mostra l'aiuto del passaggio che stai compilando.

[maxvero]

Scusami tanto, ma io provo e riprovo a evidenziare quello che tu mi indichi ma mi compare solo il popup evidenziato in rosso nella immagine. Sicuramente sbaglio qualche cosa.
Gioh66 quanta pazienza hai con sto vecchietto.
Continuo a ringraziarti, non è da tutti essere così disponibili.

[gioh66]

Ma dopo che hai evidenziato la formula, premi il tasto funzione F9?

[maxvero]

Purtroppo come ti ho scritto in precedenza nella immagine anche premendo F9 non cambia nulla.
Comunque ti ringrazio e non ti faccio perdere altro tempo hai fatto il possibile.
Era una cosa non importante, uno sfizio per imparare cose nuove.
Cercherò e proverò ancora senza però approfittare della tua disponibilità.
In tutta sincerità mi sento di dire che sei persona generosa e splendida.
Grazie e ciao
Massimo

[gioh66]

Grazie a te del riscontro.

[maxvero]

Ciao gioh66,
con calma dopo parecchio tempo ho ripreso per mano il file in oggetto.
Funziona alla perfezione, come da tue indicazioni sono riuscito a risolvere con grande facilità.
Il problema era che in uno dei 5 fogli ( il quarto per la precisione ) avevo apportato una modifica aggiungendo un quarto " modulo " cova.
Eliminato quel modulo tutto ha funzionato.
Ti chiedo se io volessi aggiungere ai 5 fogli un quarto modulo cove dovrei modificare solo l'area e da A1:AG4 cambiare in A1:AR4.
Te lo chiedo per accelerare i tempi, potrei provare a modificare tutti e 5 i fogli e vedere il risultato, ma mi avvalgo della tua gentilezza.
Comunque ancora grazie, imparato un' altra cosa .
Un salutone dal Lido di Venezia, se vieni dalle mie parti un " ombra di vino e un cicchetto " te lo offro volentieri.