[Megoldva] Szám helyettesítő karakter

[P.Gyula]

Sziasztok!

Az lenne a kérdésem, hogy pl azonos tizedesjegyre végződő számokat lehet-e egy karakterrel helyettesíteni?

Konkrét példa:

Logikai "HA" függvényben szeretném az összes ,3-ra végződő számot lecseréltetni ,5-re végződőre, de nem akarom egyenként beírni azt a rengeteg számot, hanem egy karakterrel helyettesíteni a tizedesvessző előtti számokat ha erre van lehetőség

=HA(I2=2,3;2,5;HA(I2=3,3;3,5;HA(I2=4,3;4,5;HA(I2=5,3;5,5;HA(I2=6,3;6,5;HA(I2=7,3;7,5;HA(I2=8,3;8,5;HA(I2=9,3;9,5;HA(I2=10,3;10,5;HA(I2=11,3;11,5;HA(I2=12,3;12,5;HA(I2=13,3;13,5;HA(I2=14,3;14,5;HA(I2=15,3;15,5;I2))))))))))))))

Köszönöm

[Zizi64]

Ha jól értem a feladatot, akkor pont erre való az MROUND() függvény:

Kód: Egész kijelölése

=MROUND(I2;0,5)

Ez bármely törtrész esetén x,0 vagy x,5 értékre kerekít, a kerekítés szabályai szerint.


De ha neked csupán a x,3 -ra végződő törtrészeket kell helyettesítened, akkor használd az alábbi képletet:

Kód: Egész kijelölése

=IF(I2-INT(I2)=0,3;INT(I2)+0,5;I2)

(Képzed a szám törtrészét, megvizsgálod, hogy az egyenlő-e 0,3-mal. Ha igen, akkor a szám egész részéhez hozzáadsz 0,5-öt. Ha nem egyenlő, akkor az eredeti számot adja vissza a függvény.


Vigyázz, mert ha a szám pontos értéke például 14,29999, akkor ez már nem úgy működik, ahogy szeretnéd (az olyan esetekben, amikor a számot csupán 14,3 formátummal jelezteted ki, és emiatt azt gondolod, hogy a pontos értéke is ennyi).

Persze erre is van megoldás (már ha erre van szükséged):

Kód: Egész kijelölése

=IF(ROUND(I2;1)-INT(I2)=0,3;INT(I2)+0,5;I2)

Ekkor a "majdnem" x,3-ra végződő számok esetében is ki fog cserélődni a törtrész x,5 értékre.



(Az angol függvényneveket használtam a példákban. Az MROUND() függvénynek tudtommal nincs is magyar neve, mert csak azok lettek lefordítva, amelyek az Excelben is léteznek.)

[Zizi64]

...Bár észrevettem a "[Megoldva]" visszajelzést, azért még azt is ideírhattad volna, hogy számodra melyik megoldás volt a megfelelő...

[P.Gyula]

=IF(I2-INT(I2)=0,3;INT(I2)+0,5;I2)
Ezt a verziót próbáltam egyelőre és működik Calc-ban de Excel-ben valamiért nem, de az nem is fontos annyira. Köszönöm. Írtam egy rövid emailt neked.

[Zizi64]

E-mailt, vagy személyes üzenetet nem kaptam eddig tőled. (Nincs a Spam-ek között sem.) Az automatikus "témafigyelés értesítő" az rendben megjött...
(A saját profilodnál állíthatod be, ha E-mail értesítést kérsz a figyelt témákról)
Csak moderátor vagyok a fórumon, nem admin, így nem tudom megállapítani, hogy volt-e gond a fórumból történő E-mail küldéssel a közelmúltban.


Nálam, Excel2002-ben az alábbi függvény működik:

Kód: Egész kijelölése

=HA(KEREK(I2-INT(I2);1)=0,3;INT(I2)+0,5;I2)

A kerekítés nélküli változat

Kód: Egész kijelölése

=HA(I2-INT(I2)=0,3;INT(I2)+0,5;I2)

nem ad jó eredményt.
Ha megnöveled az általad jogosan PONTOSAN 0,3-nak feltételezett eredményű

Kód: Egész kijelölése

=I2-INT(I2)

függvény értékének a kijelzett tizedes jegyeinek számát (legyen a bemenő érték = 12,3) , akkor láthatod, hogy azt nem pontosan 0,3 értékként tárolja az Excel, hanem
0,3000000000000010
értékként, ami ugye nyilvánvalóan nem egyenlő a 0,3-mal! Emiatt a javasolt megoldás feltételvizsgáló része sose veszi elő a 0,5-ös segédértéket.

Ez a számítástechnikai számábrázolási pontatlanságok miatt van így. Jó példa erre, hogy míg a tízes számrendszerben az 1/10 az véges (tizedes-) tört, a kettes számrendszerben ugyanez a számérték végtelen ("kettedes-") törtként ábrázolható csak:
1/10 = 1/16 + 1/32 + 1/256 + 1/512 + 1/4096 + 1/8192 + 1/65536 + 1/131072 ...

Az OpenOffice/LibreOffice valószínűleg már dupla pontosságú számábrázolást használ, (vagy életszerűbb belső kerekítési módszereket, mint az Excel,) ezért működhet a forszírozott kerekítést nem tartalmazó függvény is.


Az

Kód: Egész kijelölése

=MROUND(I2;0,5)

esetében tévedtem, létezik az Excel2002-ben is, és működik is, de abban igazam volt, hogy nincs ott sem "magyar" neve.


...De egyébként meg ha OpenOffice-t, LibreOffice-t használsz, akkor hogy jön ide az Excel?

[P.Gyula]

...De egyébként meg ha OpenOffice-t, LibreOffice-t használsz, akkor hogy jön ide az Excel?

Kipróbáltam, hogy működik-e ott is. Ismerősöm azt használja és szeretném neki odaadni ezt a kis számolótáblázatot, amit összebarkácsoltam.

[P.Gyula]

=HA(KEREK(I2-INT(I2);1)=0,3;INT(I2)+0,5;I2)

Excel 2010-es változatban így működik:

=HA(KEREKÍTÉS(I2-INT(I2);1)=0,3;INT(I2)+0,5;I2)

Ismét köszönöm a segítségedet.

[Zizi64]

O.K. (ezek szerint most már az e-mail is.)

Köszönöm a visszajelzéseket.

[Zizi64]

Excel 2010-es változatban így működik:

=HA(KEREKÍTÉS(I2-INT(I2);1)=0,3;INT(I2)+0,5;I2)

Olyanom nincs és nem is valószínű, hogy lesz...


Köszönjük a kiegészítést!