[Résolu] Sommes sur plages similaires

[John.Doe]

Bonjour,

J'essaye de calculer le total des heures effectuées chaque semaine sur une année.

J'ai rempli sur une seule colonne (colonne B) toutes les heures effectuées chaque jour.

Ensuite sur une autre colonne je veux obtenir le total des heures pour chaque semaine.

Par exemple la 1ère semaine (de 2022) commence le 3 janvier et finit le 9 janvier.
J'ai donc mis =SOMME(B3:B9) pour avoir le total de la 1ère semaine.
Je voudrais ensuite reproduire en dessous du résultat le total de la semaine 2, 3, 4, etc.

Comment indiquer à Calc que je veux juste en-dessous =SOMME(B10:B16) , =SOMME(B17;B23) , =SOMME(B24;B30) etc. ?

Merci d'avance pour votre aide

[Jean-Louis Cadeillan]

Bonjour,
Une solution, par exemple :

Code : Tout sélectionner

=SOMME(INDIRECT("B"&7*LIGNE(A1)-4&":B"&7*LIGNE(A1)+2))

à étendre vers le bas autant que nécessaire.
Cordialement,
Jean-Louis

[Lorentz]

Bonjour,
Je pense que l’utilisation de la fonction DECALER couplée à SOMME peut être une solution très pratique pour automatiser les calculs de plages hebdomadaires. Cela permet de definir des plages dynamiques sans les MAJ manuellement à chaque fois. Voici un exemple de code qui pourrait convenir

Code : Tout sélectionner

=SOMME(DECALER(A1;0;0;7;1))

Dans cet exemple, DECALER(A1;0;0;7;1) sélectionne une plage de 7 lignes à partir de A1, ce qui est utile pour les données hebdomadaires. Avez-vous déjà testé ce type d'approche ?

[Jean-Louis Cadeillan]

Bonjour,
Merci à Lorentz pour cette approche plus élégante, DECALER() est effectivement une fonction très polyvalente, mais pour répondre à la structure initiale exposée par John.Doe, il faudra la mettre en œuvre avec quelques modifications :

Code : Tout sélectionner

=SOMME(DECALER(B$3;7*(LIGNE(A1)-1);0;7;1))

le $ dans B3 permet de ne pas toucher à la référence initiale quand on recopie la formule vers le bas. Le deuxième argument, qui est le décalage du nombre de lignes par rapport à la référence doit pouvoir sauter de 7 en 7 pour trouver la bonne première valeur de la plage de 7 cellules (7 est donné par le 4e argument) dans la colonne B, d'où 7*(LIGNE(A1)-1).
Cordialement,
Jean-Louis

[John.Doe]

Merci infiniment à tous les 2, ça fonctionne très bien