[Basic] (dés)activer par programme les "démons"

[jlescudie]

Avant de poster une nouvelle question, il serait agréable que vous clôturiez le(s) fil(s) précédemment initié(s) : http://user.services.openoffice.org/fr/ ... =egosearch
Notamment en ajoutant la balise [Résolu] si c'est le cas, suivez ce sujet pour savoir comment procéder : http://user.services.openoffice.org/fr/ ... c3299.html

C'est une question de politesse pour les gens qui vous ont répondu et consacré bénévolement de leur temps. Notre forum est plus lisible avec ce balisage comme vous avez pu vous en rendre compte en le parcourant.

Merci de votre collaboration

Bonjour,
J'aimerais pouvoir activer ou désactiver par programme (et non par l'interface graphique) un script lancé sur un évènement d'un formulaire ou d'un contrôle.
L'en-tête de la routine pourrait ressembler à cela :

Code : Tout sélectionner

Sub controleDemon(source as Object, evt as String, activer as Boolean) 

où source serait l'objet portant l'évènement (formulaire ou contrôle), evt un code désignant l'évènement (du genre "onLoad"), et activer indiquerait si l'on veut activer ou désactiver le lancement de la routine associée lorsque l'évènement survient.
Quelqu'un peut-il m'indiquer une piste à explorer, un fragment de tuto, voire un exemple proche ?
Merci.

[Pierre-Yves Samyn]

Bonjour

Activer/désactiver sans supprimer je n'ai jamais fait... ni cherché

Ci-joint un exemple de manipulation produisant le même résultat : ajout/suppression du script associé à l'événement Exécuter l'action du bouton nommé "Test2"

Code : Tout sélectionner

const PysNomCtrl = "Test2"	

sub PysSupprimerAction

dim PysForm as object
dim PysElementNames as object
dim PysIndex as long

' Chargement de la bibliotheque Tools car utilisation de la fonctions IndexinArray 
GlobalScope.BasicLibraries.LoadLibrary("Tools")

PysForm = thiscomponent.sheets.getByName("Feuille1").drawPage.forms.getByName("Navigation")
PysElementNames =  PysForm.ElementNames

PysIndex = IndexinArray(PysNomCtrl, PysElementNames)
PysForm.revokeScriptEvent ( PysIndex , "XActionListener", "actionPerformed", "" )

end sub


Sub PysAjouterAction

dim PysForm as object
dim PysElementNames as object
dim PysEvent as new com.sun.star.script.ScriptEventDescriptor

dim PysIndex as long

' Chargement de la bibliotheque Tools car utilisation de la fonction IndexinArray
GlobalScope.BasicLibraries.LoadLibrary("Tools")

PysForm = thiscomponent.sheets.getByName("Feuille1").drawPage.forms.getByName("Navigation")
PysElementNames =  PysForm.ElementNames
PysIndex = IndexinArray(PysNomCtrl, PysElementNames)

PysEvent.ListenerType = "com.sun.star.awt.XActionListener"
PysEvent.EventMethod =  "actionPerformed"
PysEvent.ScriptType = "StarBasic"
PysEvent.ScriptCode = "document:Standard.Module1.PysTestDeux"

PysForm.registerScriptEvent(PysIndex, PysEvent)

End Sub

Sub PysTest
print "ok"
end sub

Sub PysTestDeux
print "okDeux"
end sub