[Résolu] Afficher sur colonne les jours d'un mois déterminé

[cetoines]

Bonjour,
J'apprends tout juste à utiliser le tableur et je voudrais savoir si quelqu'un sait comment afficher dans une colonne les jours consécutifs d'un mois et d'une année choisi.
Pour se faire, j'utilise la fonction date à laquelle j'ajoute 1 sur la case en dessous. Le tout déroulé sur 31 cases, j'ai tout le mois.
ex : cela donne 01/03/2010, en dessous02/03/2011......jusqu'à 31/03/2011.

Problème : pour le mois de février les 3 dernières cases sont les 3 premiers jours de mars.
Comment faire pour que cela s'arrête au dernier jour de février 28/02/2011 (ou 29/02/20.. suivant le cas) et que rien ne s'affiche au dessous.

Merci pour votre aide car j'essaie de faire un tableau annuel : un mois par onglet (12 onglets)

Cetoines

[Grenouille]

Bonsoir,

Comment faire pour que cela s'arrête au dernier jour de février 28/02/2011 (ou 29/02/20.. suivant le cas) et que rien ne s'affiche au dessous.

Je ne comprends pas où se trouve le problème. Ne serait-il pas plus simple de supprimer les jours en trop ?

A+

[spYre]

Bonjour cetoines, bienvenu sur ce forum.

Pour contrôler l'affichage, tu peux utiliser une formule conditionnelle, du genre (en supposant que A1 contient la date de départ) :

Code : Tout sélectionner

=SI( MOIS(A1+1)=2; A1+1; "" )

(2 pour février, à adapter)

Cordialement.

[joel275]

Bonjour,
et pour que ça marche pour n'importe quel mois

Code : Tout sélectionner

=SI((MOIS(A1+1)=MOIS(A1))    ET    (A1<>"");A1+1;"")

A plus
Joël

[cetoines]

Merci pour vos messages.
En fait j'ai un peu mieux cerné mon besoin. POur un mois donné, il me faut tous les jours de ce mois et la dernière case est le premier jour du mois suivant....
Et là ça se complique...
EX : 01/03/2011, 02/03/2011.....31/03/2011 et la dernière 01/04/2011.
J'attends votre aide

Cetoines

[joel275]

Bonsoir,
en modifiant légèrement la formule donnée précédemment:

Code : Tout sélectionner

=SI((MOIS(A1+1) = MOIS(A$1)  OU  (JOUR(A1+1 ) = 1) )  ET (A1 <> ""); A1+1; "")

tu devrais obtenir le résultat souhaité

Bon dimanche
Joël

[Jean-Louis Cadeillan]

Si le nom de l'onglet est le mois (janvier, février, etc.), on peut n'avoir qu'une seule formule pour toutes les cellules de tous les onglets. Pour faciliter la lecture (et la maintenance) on peut nommer quelques formules (Insertion> Noms > Définir) :
jj , le jour du mois en cours dans la ligne considérée ==>

Code : Tout sélectionner

DATEVAL(LIGNE()&STXT(CELLULE("filename";$A$1);TROUVE("$";CELLULE("filename";$A$1))+1;9)&" 2011")

js , le premier jour du mois suivant ==>

Code : Tout sélectionner

DATE(2011;MOIS(DATEVAL(1&STXT(CELLULE("filename";$A$1);TROUVE("$";CELLULE("filename";$A$1))+1;9)&" 2011"))+1;1)

Pourquoi 9 ? C'est le nombre maximum de caractères pour un mois (le mois de septembre)...
jm , le nombre de jours du mois ==>

Code : Tout sélectionner

JOURSDANSMOIS(js-1)

La formule qui conviendra à toutes les cellules sera donc la suivante (à dérouler de la ligne 1 à la ligne 32 de chacune des feuilles) :

Code : Tout sélectionner

=SI(LIGNE()=jm+1;js;SI(LIGNE()>jm+1;"";jj))

Pour l'utiliser, il fait d'abord sélectionner tous les onglets (sélectionner le premier onglet, puis Ctrl+clic sur le dernier), saisir ou copier la formule ci-dessus en A1 du premier onglet, puis Entrée, puis la dérouler jusqu'en A32.
Cordialement
Jean-Louis
PS : on pourrait aussi automatiser l'année, si, par exemple, l'année faisait partie du nom du fichier...

[cetoines]

Merci Jean Louis.
Je n'ai pas tout compris mais je vois que ton fichier fonctionne. POur changer l'année, tu fais comment ?
Est il possible de mettre l'année dans une case et tous les onglets se mettent à jour ?
Merci
Cetoines

[Jean-Louis Cadeillan]

Est il possible de mettre l'année dans une case et tous les onglets se mettent à jour ?

Dans les formules nommées jj et js (accessibles par Insertion > Noms > Définir), il suffit de changer toutes les mentions 2011 par $janvier.$B$1, si tu veux que la liste de validité de l'année se trouve sur cette cellule.
Pour la liste de validité, tu peux utiliser par exemple (Données > Validité ==> autoriser Plage de cellules > Source )

Code : Tout sélectionner

LIGNE($A$2010:$A$2020)

Si la position en B1 de janvier ne te plaît pas, il suffit de faire un couper/coller ou un déplacement, pour que la liste de validité suive...
C'est tout
A+
Jean-Louis

[cetoines]

Ok,
Merci à toi Jean Louis
A+
Cetoines