Apache OpenOffice Community Forum

Code: Select all

REM  BACKGROUND

REM  This module is used to set up the master script provider for the supported
REM  language of choice (Python is the base).  This was obtained from reference:
REM  
REM      PythonFromCalc_8Dec2010.pdf
REM  
REM  at address:
REM  
REM      http://hobbyutil.googlecode.com/files/PythonFromCalc_8Dec2010.pdf
REM
REM  and futher information is found at address:
REM 
REM      http://stackoverflow.com/questions/7591656/
REM          how-can-i-call-a-python-macro-in-a-cell-formula-in-openoffice-org-calc 
REM
REM  The function can be called within a cell or in other ways, ie as part of
REM  a Basic procedure.  

REM  USAGE

REM  Note that the arguments and return value for the Basic function wrapper
REM  must match the underlying 'called' function.  In the case of a Python
REM  call, where we have a Basic wrapper, as fnPyFunc(a,b), and the Python 
REM  function of interest, as PyFunc(a,b) in the file utilities.py, an example
REM  usage is: 

REM  Function fnPyFunc( a As double, b As Long ) As Double
REM    Dim _function As Object
REM    _function = Provider.Master.getPythonFunctionByName( "PyFunc", "utilities.py" )
REM    fnPyFunc = _function.invoke(Array( a,b ), Array(), Array()) 'Pass args as array.
REM  End Function

Option Explicit

REM GLOBAL DATA AND PROCEDURES

Global GlobalProvider As Object							'Persistent for all modules
Private Const GScriptSvc = "vnd.sun.star.script:"				'Service that processes external scripts. 
Private Const GPythonArgs = "?language=Python&location=user"	'language Python, location ../user/Scripts/Python..

REM _SetMasterGlobals()
Sub _SetMasterGlobals()

	'Purpose: Create the master script provider (GlobalProvider) that can be used to
	'call a script language that is supported.  Once called the provider is not created
	'again.
	
	On Error GoTo ErrorHandler

	'Declare
	Dim _unosvc As Object
	
	'Create only when object does not exist
	If isNull( GlobalProvider ) Then
		_unosvc = createUnoService( "com.sun.star.script.provider.MasterScriptProviderFactory" )
		GlobalProvider = _unosvc.createScriptProvider( "" )
	End If
	
	Exit Sub
	
	ErrorHandler:
	
	'Stop by default so as not to harm any data.  Insert error message box here if needed.
	
	Stop
	
End Sub

REM PUBLIC FUNCTIONS

REM getPythonFunctionByName(a,b)
REM a is the function name as a string.
REM b is the Python script file name that contains the function, optional.
Function getPythonFunctionByName( functionname As String, Optional scriptfile As String ) As Variant

	'Purpose: Supply the Python function name to Basic and return the procedure.  If
	'the script file name is not given, defaults to main.py.

	'Declare
	Dim _scripturl As String
	Dim _scriptsvc As String
	
	_SetMasterGlobals()										'Ensure GlobalProvider is set
	
	On Error GoTo ErrorHandler

	'Initialize
	_scriptsvc = GScriptSvc & "main.py$" 					'Ensure script service is set
	If Not isMissing( scriptfile ) Then
		_scriptsvc = GScriptSvc & scriptfile & "$"
	End If
	_scripturl = _scriptsvc & functionname & GPythonArgs	'Assemble Python-specific url
	
	'Set return value.
	getPythonFunctionByName = GlobalProvider.getScript( _scripturl )
	
	Exit Function
	
	ErrorHandler:
	
	'Stop by default so as not to harm any data.  Insert Error MsgBox here if needed.
	
	Stop
	
End Function

Code: Select all

soffice --headless --convert-to txt:"Text" file_to_convert.odt