[Solved] A macro to insert an item into a combobox list

[martius]

I have this macro to insert an item into the List Entries of a combobox in Calc:

Code: Select all

Sub insertItem
	Dim oSheet as object, oMyCombo as object

	oSheet = ThisComponent.CurrentController.ActiveSheet
        oMyCombo = oSheet.DrawPage.Forms.getByName("MyForm").getByName("MyComboBox")

	 	NewItem$ = "test"
			with oMyCombo
				.insertItemText(.ItemCount, NewItem)
			End with
End Sub

The problem is that, after I close the Calc file, when I open the file again, the item is not there in the list entries anymore.
How can I insert an item in the list entries that no disappears after I close the calc file?
I do not want to use a "source cell range", and the combobox was inserted directly in the sheet, not in a form.
Thanks!

[JohnSUN-Pensioner]

Maybe something like that?

[Charlie Young]

I'd been looking at this, and though apparently JohnSUN did it somehow, my explorations turned up that the Control.ListSourceType property of a combobox cannot be set to VALUELIST, and so must be a table, query, or cellrange. A regular listbox allows it, but that probably doesn't allow the desired funcionalty.

[hanya]

Code: Select all

         with oMyCombo
            .StringItemList = Array(NewItem)
         End with

[Villeroy]

The combo box model is the blueprint of the control. It is roughly the same collection of properties you see in the properties dialog. The blueprint gets saved to disk.

Code: Select all

oCM = oMyCombo.getModel()
oCM.StringItemList = Array(All_Items)

Edit: Sorry, the above code applies to a box on a dialog. A form control does not expose the strict separation of model and view. Try Hanya's snippet.

[martius]

The situation is exactly like JohnSUN-Pensioner did, and the key to solve the problem is the combobox property "StringItemList", like Hanya's snippet and Villeroy's snippet.
So I could get this code below that is good to my needs:

Code: Select all

Sub insertItem
	Dim oSheet as object, oMyCombo as object
	Dim ListEntries() as string

	oSheet = ThisComponent.CurrentController.ActiveSheet
	oMyCombo = oSheet.DrawPage.Forms.getByName("MyForm").getByName("MyComboBox")
   
	NewItem$ = "Test"
	with oMyCombo
		ListEntries = .StringItemList
		NextItemIndex% = UBound(ListEntries) + 1
		Redim Preserve ListEntries(NextItemIndex)
		ListEntries(NextItemIndex) = NewItem
		.StringItemList = ListEntries()
	End with
End Sub

Thank you so much, everybody!