Formula CERCA.VERT non riesco a farla funzionare

[Sabinho]

Salve a tutti,

ho seguito le istruzioni di questo post:
viewtopic.php?f=9&t=6337
perchè dovevo creare un foglio di calcolo simile, che si riportasse i nominativi con valore diverso da "0" nel foglio Sheet2.

Quindi nel foglio Sheet1 colonna C dalla riga 2 in poi ho inserito la formula:
=SE(B2=0;"";MAX($C$1:C1)+1)
per assegnare un numero progressivo ai valori diversi da "0" (e fin qui tutto ok)


Nel foglio Sheet2 sono sorti i problemi, ho inserito nella cella A2 (foglio sheet2 la seguente formula:
=SE(VAL.ERRORE(CERCA.VERT(RIF.RIGA();$Sheet1.$A$2:$C$9;1;0));"";CERCA.VERT(RIF.RIGA();$Sheet1.$A2:$C$9;1;0))
che dovrebbe essere identica a quella del post sopra riportato, con qualche piccola modifica.

Solo che non mi da alcun risultato e non riesco a capire perché. Vi ringrazio a tutti in anticipo.

[charlie]

Ciao e benvenuto sul forum.
Se intanto ti vuoi presentare puoi farlo qui: viewforum.php?f=16
Per una panoramica delle regole del forum consulta il Manuale di sopravvivenza: http://forum.openoffice.org/it/forum/vi ... hp?f=1&t=2
Buon proseguimento.

[gioh66]

L'errore è nell'impostazione del cerca verticale, che fa la ricerca a partire dalla prima colonna a sinistra della matrice. Per tanto la colonna dei progressivi devi metterla in colonna A e la formula diventa così

Codice: Seleziona tutto

=SE(VAL.ERRORE(CERCA.VERT(RIF.RIGA()-1;$Sheet1.$A$2:$C$9;2;0));"";CERCA.VERT(RIF.RIGA()-1;$Sheet1.$A$2:$C$9;2;0))

Se vuoi mantenere la struttura che hai dato al file puoi usare al posto del cerca verticale, indice e confronta.

Codice: Seleziona tutto

=SE(VAL.ERRORE(INDICE($Sheet1.A$2:A$9;CONFRONTA(RIF.RIGA()-1;$Sheet1.$C$2:$C$9;0)));"";INDICE($Sheet1.$A$2:$A$9;CONFRONTA(RIF.RIGA()-1;$Sheet1.$C$2:$C$9;0)))

Un consiglio che ti do è di non fare subito la formula con la funzione errore, altrimenti è difficile capire dove sta lo sbaglio.

[Sabinho]

Ti ringrazio infinitamente, avevo frainteso il funzionamento della funzione CERCA.VERT, pensavo cercasse in tutte le colonne della matrice, ora ho capito meglio il funzionamento. Penso che userò la seconda opzione poiché volevo inserire pure delle date per uno scadenzario, quindi mi servirà un'altra colonna libera.
Grazie mille

[gioh66]

Felice d'esserti stato d'aiuto!

[Sabinho]

Mi sono incartato nuovamente, dovevo creare una sorta di scadenzario molto semplice, ho provato a seguire la guida sullo scadenzario del forum ma è una cosa troppo complessa per le mie necessità e conoscenze, vi spiego in breve cosa avrei voluto fare e cosa ho fatto:

cosa avrei voluto fare:
semplicemente volevo far copiare in ordine di scadenza le righe presenti su "PRATICHE" nella tabella presente nel foglio "SCADENZE"

cosa ho fatto:
ho inserito nella colonna "I" del foglio PRATICHE la funzione:
=SE(D3<OGGI();"";MAX($I$1:I2)+1)
per assegnare un contatore alle righe non scadute

successivamente ho riportato tutti i dati delle sole righe non scadute nel foglio SCADENZE tra le colonne "K" e "Q".

non sapendo come ordinarle per data sempre nel foglio SCADENZE ho aggiunto un contatore dei giorni nella colonna "J" tramite:
=GIORNI(N3;OGGI())
cercando di rendere le cose più semplici avendo un altro contatore ma non ci sono riuscito lo stesso.

Ho provato allora ad inserire solo le scadenze che avessero il contatore dei giorni inferiore a 7, in modo tale da rendere le cose più semplici inserendo:
=SE(VAL.ERRORE(CERCA.VERT($J3:$J500<7;$J$3:$Q$500;3;0));"";CERCA.VERT($J$3:$J500<7;$J$3:$Q$500;3;0))
ma funziona solo con il primo valore.

Dopo svariate ricerche sul forum e infiniti tentativi non riesco a risolvere, quindi chiedo se qualcuno può darmi una soluzione. Ringrazio in anticipo tutti.

[gioh66]

Prova così, nella colonna d'appoggio, in H3 del foglio PRATICHE metti questa formula

Codice: Seleziona tutto

=SE(D3<OGGI();"";CONFRONTA(PICCOLO($D$3:$D$500;RIGHE($H$3:H3));$D$3:$D$500;0))

Nel foglio SCADENZE in K3 da copiare a verso destra e in basso metti questa formula matriciale

Codice: Seleziona tutto

=SE(VAL.ERRORE(INDICE($PRATICHE.A$3:A$500;INDICE($PRATICHE.$H$3:$H$500;PICCOLO(SE($PRATICHE.$H$3:$H500<>"";RIF.RIGA($PRATICHE.$H$3:$H500)-2);RIGHE($A$3:$A3)))));"";INDICE($PRATICHE.A$3:A$500;INDICE($PRATICHE.$H$3:$H$500;PICCOLO(SE($PRATICHE.$H$3:$H500<>"";RIF.RIGA($PRATICHE.$H$3:$H500)-2);RIGHE($A$3:$A3)))))

Le formule matriciali vanno confermate con ctrl+maiuscolo+invio e non con il semplice invio.

[gioh66]

Riguardando il file mi sono accorto che se ci sono scadenze nella stessa data, le formule che ti ho proposto nel messaggio precedente non restituiscono i valori esatti.
Per tanto ho modificato il file inserendo nel foglio pratiche due colonne d'appoggio.
la prima in I3, da copiare in basso è per estrarre le date dopo OGGI()

Codice: Seleziona tutto

=SE(VAL.ERRORE(INDICE($D$3:$D$500;PICCOLO(SE($D$3:$D$500>OGGI();RIF.RIGA($D$3:$D$500)-2);RIF.RIGA($A1))));"";INDICE($D$3:$D$500;PICCOLO(SE($D$3:$D$500>OGGI();RIF.RIGA($D$3:$D$500)-2);RIF.RIGA($A1))))

L'altra in I3 sempre da copiare in basso, mette in ordine le date

=SE(VAL.ERRORE(PICCOLO($H$3:$H$500;RIF.RIGA($A1)));"";PICCOLO($H$3:$H$500;RIF.RIGA($A1)))

Poi nel foglio SCADENZ, in K3, da copiare in basso e a destra

Codice: Seleziona tutto

=SE(RIGHE($K$3:$K3)>CONTA.NUMERI(PRATICHE.$I$3:$I$500);"";SE(VAL.ERRORE(INDICE(PRATICHE.A$3:A$500;SE(VAL.ERRORE(PICCOLO(SE(PRATICHE.$D$3:$D$500=PRATICHE.$I3;RIF.RIGA(PRATICHE.$D$3:$D$500)-2);CONTA.SE(PRATICHE.$I$3:PRATICHE.$I3;PRATICHE.$I3)));"";PICCOLO(SE(PRATICHE.$D$3:$D$500=PRATICHE.$I3;RIF.RIGA(PRATICHE.$D$3:$D$500)-2);CONTA.SE(PRATICHE.$I$3:PRATICHE.$I3;PRATICHE.$I3)))));"";INDICE(PRATICHE.A$3:A$500;SE(VAL.ERRORE(PICCOLO(SE(PRATICHE.$D$3:$D$500=PRATICHE.$I3;RIF.RIGA(PRATICHE.$D$3:$D$500)-2);CONTA.SE(PRATICHE.$I$3:PRATICHE.$I3;PRATICHE.$I3)));"";PICCOLO(SE(PRATICHE.$D$3:$D$500=PRATICHE.$I3;RIF.RIGA(PRATICHE.$D$3:$D$500)-2);CONTA.SE(PRATICHE.$I$3:PRATICHE.$I3;PRATICHE.$I3))))))

Tutte le formule sono matriciali e vanno confermate con la combinazione di tasti CTRL+MAIUSCOLO+INVIO e copiate nelle altre celle, non trascinate.

[Sabinho]

Scusa se ti ringrazio adesso ma per impegni di lavoro non mi sono collegato, cmq ti ringrazio tantissimo ora lo inserisco.

[Sabinho]

Scusa se ti ringrazio adesso ma per impegni di lavoro non mi sono collegato, cmq ti ringrazio tantissimo ora lo inserisco.

[gioh66]

Non c'è problema, fai sapere se le formule funzionano, nel caso ricordati di mettere il risolto alla discussione!