[Risolto] Prospetto contabilita creazione mastrini

[Francesco90]

Salve a tutti. Ho fatto su calc un prospetto per tenere sott'occhio tutte le spese.
Vorrei aggiungere qualche funzionalità ma non so come.
In particolare vorrei creare una tabella che riepiloga voce per voce le spese o i guadagni relativi a una categoria.
Vi posto il file dove ho inserito un abbozzo di tabella (con i bordi arancioni cosi' ci capiamo meglio che sono lì i miei dubbi) che ovviamente non funziona.
Attendo vostre sapienti indicazioni. Grrrazie

per_forum_conti.ods

(23.67 KiB) Scaricato 125 volte

[gioh66]

Salve! Prova questa formula matriciale (da confermare con la combinazione di tasti ctrl+maiuscolo+invio) da mettere nella cella H23 e da copiare e incollare a destra e in basso.

Codice: Seleziona tutto

=SE(VAL.ERRORE(INDICE($A$4:$E$39;PICCOLO(SE($C$4:$C$39=$H$21;RIF.RIGA($A$4:$A$39)-3);RIF.RIGA($A1));CONFRONTA(H$22;$A$2:$E$2;0)));"";INDICE($A$4:$E$39;PICCOLO(SE($C$4:$C$39=$H$21;RIF.RIGA($A$4:$A$39)-3);RIF.RIGA($A1));CONFRONTA(H$22;$A$2:$E$2;0)))

Inoltre ti conviene dare una formattazione condizionale alle celle per nascondere gli 0, infatti nell'esempio che hai postato per la voce carburante di darebbe come data 30/12/1899, non essendoci un valore nella tabella "conto corrente", che è il giorno zero da cui calc inizia a contare i giorni per calcolare le date.

[Francesco90]

Ciao!, grazie della velocissima risposta . Ho ancora due domande:
1. Sotto la colonna "entrate", sempre nella tabella arancione, vorrei comparisse l'importo guadagnato.
2. Non saprei come fare la questione delle date .
Il problema a quanto mi pare di capire c'è solo per quelle movimentazioni come nel caso del 10 feb 2019. Cioè, se imposto nella tabella arancione "carburante" la data me la visualizza vuota e questo è un problema. C'è un modo per far capire al sistema che la data che deve prendere in considerazione è la prima che trova nel prospetto nero immediatamente sopra?

[gioh66]

Ciao! La cosa più semplice potrebbe essere di riportare tutte le date delle varie operazioni nella colonna "date", ma se vuoi mantenere questa struttura della tabella e se ti va bene una colonna d'appoggio, che nell'esempio che allego ho messo in A, allora in A4 metti questa formula e tira in basso fin dove ti serve:

Codice: Seleziona tutto

=MAX(B$4:$B4)

Poi in I23 metti questa formula matriciale

Codice: Seleziona tutto

=SE(VAL.ERR(INDICE($A$4:$F$39;PICCOLO(SE($D$4:$D$39=$I$21;RIF.RIGA($D$4:$D$39)-3);RIF.RIGA($A1));CONFRONTA(I$22;$A$2:$F$2;0)));"";INDICE($A$4:$F$39;PICCOLO(SE($D$4:$D$39=$I$21;RIF.RIGA($D$4:$D$39)-3);RIF.RIGA($A1));CONFRONTA(I$22;$A$2:$F$2;0)))

da confermare con ctrl+maiuscolo+invio e da copiare e incollare in basso.
Poi devi ri-formattare le celle da H23 a L30 come valuta.
Facendo così non è necessario fare una formattazione condizionale per nascondere gli 0, sempre che non ti dia fastidio vedere 0€ quando non c'è nessun importo nell'intervallo H23 a L30.
Ps.: la colonna A si può nascondere. Inoltre per i totali delle entrate e uscite basta che fai la somma delle celle sopra. In K31 metti

Codice: Seleziona tutto

=SOMMA(K23:K30)

e tiri a destra.

[Francesco90]

Sai che sei veramente bravo. Vorrei capire quel formulone matriciale per poter non chiedere più aiuto xD
Inoltre ti spiego il problema. Ho un file abbastanza grosso e complicato(per me) su tutte le spese dell'anno.
Vorrei inserirci questa tabellina arancione e visto che il file è già compilato, non posso, o meglio non ho voglia xD, di andare a inserire tutte le date mancanti. Quindi la soluzione è quella che hai prospettato, inserire la colonna 'A' di appoggio. Solo che non so come inserirla senza fare danni.

[gioh66]

Ciao, non fai nessun danno, ma se vuoi essere sicuro crea una copia del file originale e lavora su quello. Per aggiungere la nuova colonna ti basta selezionare la colonna A, tasto destro "inserisci colonna a sinistra" e tutto viene traslato verso destra, poi inserisci le formule che ti ho suggerito, l'unica cosa devi aumentare i riferimenti degli intervalli che ora si fermano alla riga 39.
Per quanto riguarda la formula si basa sulla funzione INDICE che si compone di quattro argomenti: Riferimento, riga, colonna e area.
Riferimento è l'intervallo di celle in cui cercare il valore corrispondente
Riga è il numero di riga in cui si trova il valore voluto, in questo caso l'ho fatto con la funzione PICCOLO(SE( che in base al criterio voluto "carburanti" lo va a cercare nell'intervallo D4:D39 e mi restituisce le posizioni di riga RIF.RIGA($D$4:$D$39)-3 (il meno 3 serva a correggere il conteggio che deve partire sempre da 1, essendo la tua tabella costruita a partire dalla riga 4). la formula RIF.RIGA($A1), serve alla funzione piccolo per determinare qual'è, la prima, la seconda, la terza riga in cui c'è "carburanti", man mano che la formula viene copiata in basso.
Colonna è il numero della colonna in cui cercare il valore ed è ricavato con la formula confronta che restituisce il numero di colonna dell'intervallo A2:F2 confrontandolo con l'intestazione delle colonne della tabella arancione.
Augurandoti buon anno, mi scuso se la spiegazione è solo abbozzata ma ci vorrebbe un romanzo (o quasi) per spiegarla dettagliatamente.
Se posso darti un consiglio prova a cercare su youtube i filmati di Gerardo Zuccalà, che spiega molto bene queste funzioni; sono per excel ma al 90% sono applicabili anche a calc.