Munkafüzet egy munkalapjának nyomtatása makróval.

[Bendegúz]

Sziasztok!

A következő problémára keresek megoldást - miután átdúrtam a Netet és végignyálaztam Andrew P. makrós könyvét ismét hozzátok fordulnék:

Adott egy munkafüzet, abban három munkalap.

Makróval elrejtem Munkalap2 és Munkalap3 lapokat.

Munkalap3 lapra - szintén makróval - kigyűjtök egy 3 oldalas listát, amit a Munkalap1-en elhelyezett gombbal szeretnék kinyomtatni.
Fájlba nyomtatáskor sajnos nem sikerült egy dokumentumba nyomtatni a három oldalt, de ez lenne a kisebbik probléma. A fő gond, hogy a Munkalap3 csak akkor hajlandó nyomtatódni, ha ő az aktív.

Meg lehet azt oldani valahogy, hogy rejtett lapot is ki lehessen nyomtatni?

Amit idáig kibogarásztam:

Kód: Egész kijelölése

Dim Printproperties(1) As New com.sun.star.beans.PropertyValue

	PrintProperties(0).Name="Name"
	printProperties(0).value= 1
	
	PrintProperties(1).Name="Wait"
	PrintProperties(1).Value=true
	
	thisComponent.Print(PrintProperties())

Ezt egy modulba téve nyomtat ugyan, de nem azt (és nem is igazán úgy) amit (ahogy) szeretném. Csak akkor működik jól, ha az a lap aktív amit nyomtatni szándékozom.

Segítségeteket előre is köszönöm!

[Zizi64]

Fájlba nyomtatáskor sajnos nem sikerült egy dokumentumba nyomtatni a három oldalt,

Pdf-be? Vagy valami (raszter/PostScript) nyomtatófájlba?
Ha Pdf-be: beépített export lehetőséggel; vagy virtuális nyomtatóval, mint pl. a PdfCreator?

Makróval elrejtem Munkalap2 és Munkalap3 lapokat.
a Munkalap3 csak akkor hajlandó nyomtatódni, ha ő az aktív.

Hogyan lesz aktív egy elrejtett munkalap?

A kérdések tisztázásáig egy hasonló téma:
http://forum.openoffice.org/en/forum/vi ... 25&t=10179

[antiuhu]

Üdv!

Csak egy tipp, ha adattartományként adod megy a nyomtatást akkor sem jó?
Talán ezzel:

Kód: Egész kijelölése

oSheet.getCellRangeByName("3Munkalapon_levő_adattartomány_neve")

Anti

[Zizi64]

A lényeg: semmi rögzített (makrórögzítővel felvett) kódrészlet ne legyen, semmi "diszpécser-használat", csak A Basic nyelv és az API függvények játszanak...

Kód: Egész kijelölése

REM  *****  BASIC  *****

Sub pdfsave

dim document as object
dim args2(1) as new com.sun.star.beans.PropertyValue
dim Arg(0) as new com.sun.star.beans.PropertyValue

'Tegyük aktívvá a harmadik munkalapot (annak ellenére, hogy az rejtett):	
	oSheet = ThisComponent.Sheets.getByName("Harmadik Munkalap")
	ThisComponent.CurrentController.setActiveSheet(oSheet)
		
'Vehetném a nyomtatandó terület koordinátáit egy cellából is, de most beírtam fixen:
    'MyPrintArea = oSheet.getCellRangeByName("Pdfterulet").string
	MyPrintArea = "A1:F150"

'Jelöljük ki a nyomtatandó területet:
	document = ThisComponent.CurrentController.Frame
	oRange = oSheet.getCellRangeByName(MyPrintArea)
	ThisComponent.CurrentController.Select(oRange)	

'Hová is mentsük a Pdf fájlt? Elérési útvonal és fájlnév meghatározása 
'(ugyanolyan néven, és ugyanoda akarom menteni, ahol a Calc fáljom van mentve):
'Ehhez először betöltjük a Tools könyvtárat (ha még nincs betöltve), 
'ami nagyon hasznos rutinokat tartalmaz például a dokumentum URL-jéből történő adatkinyeréshez
	If (Not GlobalScope.BasicLibraries.isLibraryLoaded("Tools")) Then
        GlobalScope.BasicLibraries.LoadLibrary("Tools")
    End If

'Aztán megnézzük, hogy az aktuális dokumentum rendelkezik-e URL-lel (el van-e mentve valahová),
'és az URL-ből kibogarásszuk az elérési útvonalat és a fájlnevet
    If (ThisComponent.hasLocation()) Then
	    sDocURL = ThisComponent.getURL()
	    sDoc = ConvertFromURL(sDocURL)
	    sPath = DirectoryNameoutofPath(sDocURL, "/")
	    sFile =  FileNameoutofPath(sDocURL, "/")

		fileName = sPath & "/" & left(sFile,instr(sFile,".")-1) & ".pdf"

'A PDF szűrő beállíítása a kijelölt területre	
		Arg(0).Name = "Selection"
		Arg(0).Value = oRange

		args2(0).Name = "FilterName"
		args2(0).Value = "calc_pdf_Export"
		args2(1).Name = "FilterData"
		args2(1).Value = Arg()

'És most maga Exportálás történik, aztán a vezérlést visszadjuk az első munkalapra:
		ThisComponent.storeToURL(fileName,args2())
		oSheet = ThisComponent.Sheets.getByName("Első Munkalap")
		ThisComponent.CurrentController.setActiveSheet(oSheet)
		Uzenet = "A 'Harmadik Munkalap' meghatározott területének" + Chr$(13) + "Pdf formátumba történő exportálása rendben megtörtént!"
		MsgBox(Uzenet,0,"Jó hír:")

	else
		oSheet = ThisComponent.Sheets.getByName("Első Munkalap")
		ThisComponent.CurrentController.setActiveSheet(oSheet)
		MsgBox("Ez egy újonnan létrehozott dokumentum, még nincs mentve!",0+16,"Baj van:")
    End If
	
End Sub

Nem tudom, hogy ilyesmire volt-e szükséged, vagy egész másra, én ezt az igényt olvastam ki a soraidból...
A kód fix munkalapnevekkel dolgozik:
"Első Munkalap": ahol a gomb van.
"Harmadik Munkalap" : ahol az exportálandó terület van

[Bendegúz]

Sziasztok!

"Pdf-be? Vagy valami (raszter/PostScript) nyomtatófájlba?"
Nem írtam de úgy csináltam, hogy a "PrintProperties(0).Name=" tagnak lehet az értéke a "FileName" - A. Pitonyak után szabadon . Ekkor a Value érték a létrehozandó fájl neve lesz és - nálam legalábbis - PDF-et állít elő, csak minden laphoz egy fájl. Lentebb írom, hogy miért...

"Hogyan lesz aktív egy elrejtett munkalap?"
Fogalmam sincs! Azt sem tudtam, hogy aktívnak kell lennie nyomtatáskor makrózás esetén... De azt meg tudom oldani, hogy megjelenítem, aktívvá teszem, nyomtatom és újra elrejtem. Lényeg, hogy amelyik munkalap csak összesítés miatt van, annak feleslegesen nem kell látszódnia. Nekem ez így szimpatikus.

Még valami:
Visszaolvasva rádöbbentem, hogy sajnos nem voltam teljesen pontos a témaindító hozzászólásomban, mert kihagytam azt az apró - de nem elhanyagolható - részletet, hogy a három oldalas lista nem egyszerre, egymás alatt jelenik meg (mert akkor ugye ki is nyomtatódik szépen), hanem egy For ciklus hozza azt létre feltételek alapján (hasonló lenne mint a Writer körlevél, csak pont a körleveles módszert akarom lecserélni egyetlen Calc Munkafüzetre)

Tehát pontosítva:
- Ciklussal kigyűjtök egy oldalt egy hosszabb listából a Munkalap3-ra.
- Kinyomtatom a kész oldalt
- Aztán újra gyűjtök
- Nyomtatok
- Gyűjtök
- Nyomtatok

Ezt nem tudtam úgy megoldani, hogy a három kigyűjtés után egy nyomtatás legyen és ebből egy fájl. De ez nem is lenne akkora probléma, mert majd nyomtatom simán nyomtatóra, vagy oldalanként 1 PDF-be.

Elnézést a pontatlan megfogalmazásért.

Amit küldtetek mindjárt megnézem és köszönöm, hogy foglalkoztok vele!

Megj.:
Zizi64! A makrórögzítőt a kezdeti szárnypróbálgatások után elhagytam és - tanácsodra - rágyúrtam az API-k ra. Nem vagyok nagymester, de a rögzítés helyett már magam írom a moduljaimat. Külön köszönet az útmutatásért!

[Zizi64]

Akkor tulajdonképpen jó lesz neked a példarutin, csak a kimeneti fájlnevet kell dinamikusan generálnod (vagy az eredeti fájl nevének ciklusonkénti kiegészítésével, vagy egy előre betárolt tömbből a ciklusváltozó segítségével).

Nyilván a ciklusváltozód értékét paraméterként át kell adnod ez esetben a rutinnak, hogy tudja, melyik kimeneti fájlnevet kell használnia. (A ciklusod ugye háromszor meg fogja híni ezt a rutint, tudatnod kell valahogy a rutinnal, hogy "hol is tartunk").
...Vagy eleve a kívánt fájlnevet adod át a rutinnak egy String változóban.

[Bendegúz]

Szia!

Igen jó lett a rutin, hozza szépen a PDF fájlokat, a nevek dinamikusan generálva!
Meghagytam a nyomtatás részt is, úgyhogy most löki nyomtatóra és PDF-be is.

Sajnos nyomtatás előtt a munkalapot nem elég csak aktívvá tenni, meg is kell jeleníteni, így a nyomtatás idejére a munkalap látszódik, de a végén újra isVisible = FALSE.
Úgy gondolom jó lesz így, még finomítok rajta de tudom használni!

Köszönet érte!

[Zizi64]

Sajnos nyomtatás előtt a munkalapot nem elég csak aktívvá tenni, meg is kell jeleníteni, így a nyomtatás idejére a munkalap látszódik, de a végén újra isVisible = FALSE.

A Beállításoknál a "Csak a kijelölt munkalapok nyomtatása" opció megváltoztatásával már próbálkoztál?


Kíváncsi lennék a kódodra. (úgy általában is, hogy a fórumon legyen egy efféle minta a többi érdeklődő, próbálkozó számára; és amiatt is, hátha tudok hozzátenni olyan funkciót, amivel nem kell láthatóvá tenni a munkalapot a nyomtatás idejére)

[Bendegúz]

Igazad van be volt jelölve a "Csak a kiválasztott munkalap nyomtatása", de talán jobb is így, mert kibukott ez a "hiba", és tudtam kezelni.

Melyik kódra gondolsz? A témához kapcsolódó kód az az amit adtál, csak átalakítom úgy, hogy mentés és nyomtatás is működjön.

Magában a munkafüzetben jelenleg 41 modul van, és egymást hívogatják ahol erre szükség van. Ebben már a tőled kapott másolós-beillesztős rész is szerepel.

A témához kapcsolódó modul kódja perpillanat így néz ki (még jelenleg sem végleges, de ez látszik is rajta):

Kód: Egész kijelölése

'A nyomtatás meghívása:
Call UjMappa (ThisComponent.Sheets.GetByName(UTIKL).getCellRangeByName("FT2").string & "_" & ThisComponent.Sheets.GetByName(UTIKL).getCellRangeByName("FU2").string)

'Nyomtatás funkció indítása
Function Nyomtatas (Munkalap, Datum, Nev) 'Munkalap neve, egy sorszám, és egy név. Ez lesz a PDF fájl neve.

Dim document as object
Dim PrintProperties(1) as new com.sun.star.beans.PropertyValue
Dim Arg(0) as new com.sun.star.beans.PropertyValue

	'Tegyük aktívvá a harmadik munkalapot (annak ellenére, hogy az rejtett):   
	oSheet = ThisComponent.Sheets.getByName(Munkalap)
	oSheet.isVisible = TRUE 'A nyomtatás idejére megjelenítve, utána elrejtve
	ThisComponent.CurrentController.setActiveSheet(oSheet)

    
    'Kiküldés alapértelmezett nyomtatóra
    'Nem végzek ellenőrzést a nyomtatóval és annak állapotával kapcsolatban, ha nem nyomtat az az ő baja... A PDF-ek úgyis mennek!
	PrintProperties(0).Name="Name"
	PrintProperties(0).value= 1
	
	PrintProperties(1).Name="Wait"
	PrintProperties(1).Value=true
	
	thisComponent.Print(PrintProperties())
	
	
'********************************************	
	'Exportálás PDF-be
'******************************************** 	
	'Az UTIKE munkalap ezen területe lesz exportálva (ezen a lapon van az a bizonyos lista, ami dinamikusan változik)
	
	MyPrintArea = "A1:O51"
	
	'Jelöljük ki a nyomtatandó területet:
	document = ThisComponent.CurrentController.Frame
	oRange = oSheet.getCellRangeByName(MyPrintArea)
	ThisComponent.CurrentController.Select(oRange)
    
		'PDF-ek mentése a PDFMentUtvonal mappába/év_hónap néven. PDFMentUtvonal globális változó, UjMappa modulban kap értéket
		fileName = PDFMentUtvonal & "/" & Datum & "_" & Nev & ".pdf"


'A PDF szűrő beállíítása a kijelölt területre
  
      Arg(0).Name = "Selection"
      Arg(0).Value = oRange

      PrintProperties(0).Name = "FilterName"
      PrintProperties(0).Value = "calc_pdf_Export"
      PrintProperties(1).Name = "FilterData"
      PrintProperties(1).Value = Arg()

'És most maga az Exportálás történik.
      ThisComponent.storeToURL(fileName,PrintProperties())
      
'Ezt a részt kivettem, mert egy másik modulban teszem ki a KÉSZ üzenetet!
      'Uzenet = "A 'Harmadik Munkalap' meghatározott területének" + Chr$(13) + "Pdf formátumba történő exportálása rendben megtörtént!"
      'MsgBox(Uzenet,0,"Jó hír:")

   'else
      
'Ez meg nem fog kelleni, mert nyomtatás előtt modulból le fogom menteni a munkafüzetet.
      'MsgBox("Ez egy újonnan létrehozott dokumentum, még nincs mentve!",0+16,"Baj van:")
    
    'End If
	
End Function


Function UjMappa (MappaNeve)

	'Először betöltjük a Tools könyvtárat (ha még nincs betöltve),
	'ami nagyon hasznos rutinokat tartalmaz például a dokumentum URL-jéből történő adatkinyeréshez
    
    If (Not GlobalScope.BasicLibraries.isLibraryLoaded("Tools")) Then
    
        GlobalScope.BasicLibraries.LoadLibrary("Tools")
    
    End If
    
		sDocURL = ThisComponent.getURL()
		sPath = DirectoryNameoutofPath(sDocURL, "/")
		PDFMentUtvonal = sPath & "/" & MappaNeve 'PDFMenuUtvonal Globális változó!
			
		MkDir PDFMentUtvonal
    
End Function

Ez így önmagában nem működik, de a kód szerkezete azért látszik.
Még nem a végleges állapot!

[Bendegúz]

Szia Zizi64!

A végleges kód két hívható függvényként került be a makróba:

Kód: Egész kijelölése

Function Nyomtatas(Munkalap, HivoLap)

'*******************************************************************************************************************
'MEGOLDÁSRA VÁRÓ FELADAT:
'HA A BEÁLLÍTÁSOK - CALC - NYOMTATÁS - CSAK A KIVÁLSZTOTT MUNKALAPOK NYOMTATÁSA NINCS BEJELÖLVE, NEKIÁLL AZ ÖSSZES
'MUNKALAPOT KINYOMTATNI. HA MEG BE VAN JELÖLVE, AKKOR MEG MEG KELL JELENÍTENI NYOMTATÁS ELŐTT, NEM ELÉG AKTÍVVÁ TENNI
'ÉRDEKES, HOGY A PDF NYOMTATÁSÁRA NEM ENNYIRE KÉNYES, AZT HOZZA SZÉPEN!
'*******************************************************************************************************************
Dim PrintProperties(1) As New com.sun.star.beans.PropertyValue
Dim oSheet As Object

'Munkalap = annak a munkalapnak a neve, ahol a nyomtatásra váró dokumentum van (nálam ez egy sablon, amit egy FOR ciklus írogat tele)	
'TRUE = Ezt mint értéket adja át a munkalap megjelenítő függvénynek

	Call LapOnOff (Munkalap, TRUE) 'Bekapcsolja a nyomtatvány sablonját tartalmazó munkalapot

    'Kiküldés alapértelmezett nyomtatóra
	PrintProperties(0).Name="Name"
	PrintProperties(0).value= 1

	PrintProperties(1).Name="Wait"
	PrintProperties(1).Value=True

	thisComponent.Print(PrintProperties())

	'Igazából olyan gyorsan történik a megjelenítés-relytés, hogy észre sem lehet venni!
	Call LapOnOff (HivoLap, TRUE) 'Visszaadja a vezérlést a nyomtatást meghívó lapnak
	Call LapOnOff (Munkalap, FALSE) 'Elrejti a sablon lapot

End Function



Function NyomtatasPDF (Munkalap, HivoLap, Tartomany, Datum, Nev) 'Ezen dolgozik, ez hívta, ezt kell nyomtatni, dátum stringben (201302), személy neve. Ez lesz a fájl neve.

On Error GoTo HIBA

Dim document As Object
Dim PrintProperties(1) As New com.sun.star.beans.PropertyValue
Dim Arg(0) As New com.sun.star.beans.PropertyValue

	Call LapOnOff (Munkalap, TRUE)
	
'********************************************
	'Exportálás PDF-be
'********************************************

	'Az UTIKE munkalap ezen területe lesz exportálva
	MyPrintArea = Tartomany

	'Műveleti munkalap kiválasztása
	oSheet = ThisComponent.Sheets.getByName(Munkalap)

	'Jelöljük ki a nyomtatandó területet:
	document = ThisComponent.CurrentController.Frame
	oRange = oSheet.getCellRangeByName(MyPrintArea)
	ThisComponent.CurrentController.Select(oRange)

		'PDF-ek mentése a PDFMentUt mappába/év_hónap néven
		fileName = PDFMentUt & "/" & Datum & "_" & Nev & ".pdf"

'A PDF szűrő beállíítása a kijelölt területre

      Arg(0).Name = "Selection"
      Arg(0).Value = oRange

      PrintProperties(0).Name = "FilterName"
      PrintProperties(0).Value = "calc_pdf_Export"
      PrintProperties(1).Name = "FilterData"
      PrintProperties(1).Value = Arg()

	'És most maga Exportálás történik.
	ThisComponent.storeToURL(fileName,PrintProperties())

	'Igazából olyan gyorsan történik a megjelenítés-relytés, hogy észre sem lehet venni!

	Call LapOnOff (HivoLap, TRUE) 'Visszaadja a vezérlést a nyomtatást meghívó lapnak
	Call LapOnOff (Munkalap, FALSE) 'Elrejti a sablon lapot

Exit Function

HIBA:
	
	Call LapOnOff (HivoLap, TRUE) 'Visszaadja a vezérlést a nyomtatást meghívó lapnak
	Call LapOnOff (Munkalap, FALSE) 'Elrejti a sablon lapot
	
	'Az ERR hibakód alapjá történő hibakezelés itt nem igazán lényeges
	MsgBox "Nem tudtamm létrehozni a PDF fájlokat! A lemez írásvédett, vagy megtelt!",0,"Lemezírás hiba!"

	IO_hiba = True

End Function

És a LapOnOFF függvény, ami ki-be kapcsolja a lapok megjelenítését

Kód: Egész kijelölése

Function LapOnOff(LapNeve, Muvelet)

	'Csak akkor legyen aktív a munkalap, ha látható is!
	If Muvelet = TRUE Then

		'Tegyük aktívvá a munkalapot (annak ellenére, hogy az rejtett):
		oSheet = ThisComponent.Sheets.getByName(LapNeve)
			
		'Meg is jelenítem a munkalapot!
		oSheet.isVisible = Muvelet
		
		ThisComponent.CurrentController.setActiveSheet(oSheet)

	End If	

	If Muvelet = FALSE Then

		'Tegyük aktívvá a munkalapot (annak ellenére, hogy az rejtett):
		oSheet = ThisComponent.Sheets.getByName(LapNeve)

		'Meg is jelenítem a munkalapot!
		oSheet.isVisible = Muvelet

	End If

End Function

Köszönöm még egyszer a mintakódot, sokat segített!

[Zizi64]

Köszönöm a kódot a később érkezők nevében is!

(Én magam is ilyenekből szedtem össze a ma meglévő AOO/LO makró-tudásomat - igaz, jobbára az angol fórumokon.)