Objektumváltozó adatának kiírása txt-be

Adatbázis kezelő

Objektumváltozó adatának kiírása txt-be

HozzászólásSzerző: pihix » 2008. június 21., szombat 10:56

Sziasztok!

Egy tábla adott mezőinek tartamát szeretném txt file-ba kiírni!
Az access-be hasonló kérdésre ezt a javaslatot találtam:
Dim db As Database
Dim tdf As TableDef
Set db = DBEngine(0)(0)
For Each tdf In db.TableDefs
If Left(tdf.Name, 4) <> "MSys" Then
DoCmd.TransferText acExportDelim, "", tdf.Name, "C:\\\\" & tdf.Name & ".txt", False, ""
End If
Next tdf

Az OOo Basic-ben addig a hibaüzenetig jutottam, hogy objektumváltozót kellene meghatározni
de a set utasítás leírásánál szűkszavu példát találok:
Dim oDoc As Object
Set oDoc = objektum (itt az objekum nevére nem bírtam rájönni, már próbáltam hivatkozni a lekérdező tábla nevére valamint az űlapnavigátorban található megnevezésekre de mindig ugyanaz a hibaüzenet jön vissza és ezen nem tudok túljutni!?!?!?!?!)
Az objektum nevét honnan lehet megállípítani? Feltéve ha ez lenne a megoldás iránya
És ezután következne az adott mező hivatozása amit a txt-be szeretnék kiírni.

Segítségeteket előre is köszönöm
Üdv:
Pihix
pihix
 
Hozzászólások: 1
Csatlakozott: 2008. június 21., szombat 10:16

Re: Objektumváltozó adatának kiírása txt-be

HozzászólásSzerző: g_123_wert » 2008. december 19., péntek 15:42

Szia!

Én azt látom, hogy csak lekérdezésen keresztül megy a dolog.
A leírás itt található:
http://wiki.services.openoffice.org/wiki/Documentation/BASIC_Guide/Database_Access

Téged az Iteration of Tables rész érdekel.

Egy másik post során létrehoztam egy adatbázist és átírtam az Iteration of Tables részben szereplő makrót, hogy egy tábla mezőjéből az adatoka t kiírja szövegfájlba.
A kód a következő:
Kód: Egész kijelölése   KinyitásÖsszecsukás
REM  *****  BASIC  *****

Sub Main

Dim DatabaseContext As Object
Dim DataSource As Object
Dim Connection As Object
Dim InteractionHandler as Object
Dim Statement As Object
Dim ResultSet As Object
Dim FileNo As Integer
Dim CurrentLine As String
Dim Filename As String

Filename = "c:\data.txt"            ' Fájl neve
FileNo = Freefile               ' Szabad fájlsorszám

DatabaseContext = createUnoService("com.sun.star.sdb.DatabaseContext")
DataSource = DatabaseContext.getByName("csalad") 'A regisztrált adatforrás neve

If Not DataSource.IsPasswordRequired Then
  Connection = DataSource.GetConnection("","")
Else
  InteractionHandler = createUnoService("com.sun.star.sdb.InteractionHandler")
  Connection = DataSource.ConnectWithCompletion(InteractionHandler)
End If

Statement = Connection.createStatement()
ResultSet = Statement.executeQuery("SELECT ""szulnev"" FROM ""emberek""") ' A lekérdezés futtatása


If Not IsNull(ResultSet) Then ' Ha van adat
  Open Filename For Output As #FileNo   'Megynyitni felűlírásra...
  While ResultSet.next
    Print #FileNo, ResultSet.getString(1) '..és beleírni az értékeket
  Wend
End If

Close #FileNo   'fájl lezárása

end sub


Hangsúlyozom, hogy regisztrált adatforrás nálam a csalad és így működik. Nem regisztrált adatforrásnál nem tudom megy e?
Csatolom az adatbázis fájlt.
Csatolmányok
csalad.odb
(4.5 KiB) 71 alkalommal.
Ms Windows XP • 3.0.X • Ubuntu 7.x
Avatar
g_123_wert
Önkéntesek
 
Hozzászólások: 71
Csatlakozott: 2008. február 29., péntek 21:58


Vissza: Base

Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 1 vendég

cron