[Résolu] Retrouver une valeur a partir d'une colonne

Discussions à propos du tableur Calc.
Les questions sur les macros doivent être postées dans la section dédiée en dessous.

Modérateur : Vilains modOOs

Règles du forum
Cette section est uniquement dédiée au tableur Calc. Vous ne devez pas poster ici de questions sur les macros mais utiliser la section éponyme.
Pristio
Fraîchement OOthentifié
Messages : 5
Inscription : 27 mai 2019 18:59

[Résolu] Retrouver une valeur a partir d'une colonne

Message par Pristio »

Bonjour,

Ne sachant pas comment expliquer correctement, je vous fais par du tableau, ainsi qu'une capture pour imager les explications :D

Mon problème :
Je cherche une fonction, me permettant de placer dans la colonne C, la valeur de la cellule J, ou la cellule E (de la même ligne de J) est équivalent à la cellule A (de la même ligne de C).

Mes recherches :
J'ai regardé un peu, j'ai trouvé quelques pistes, comme le fait d'utiliser RECHERCHEV avec les matrices, mais je ne comprends pas comment utiliser correctement cette fonction (ni si c'est ma bonne fonction pour faire ça)


Je ne suis pas très doué niveau explication dans le style des tableurs :/ n'hésitez pas à me demander si besoin de suppléments.

Pouvez-vous m'aider sur la façon de procéder afin de réussir à récupérer les valeurs ?

Je vous remercie.
Capture.PNG
Pièces jointes
Recherche par colonne.ods
(10.38 Kio) Téléchargé 64 fois
Dernière modification par Pristio le 27 mai 2019 23:43, modifié 4 fois.
LibreOffice 6.2.4.2 (x64) - Windows 10
Avatar de l’utilisateur
micmac
RespOOnsable forum
RespOOnsable forum
Messages : 9222
Inscription : 28 août 2010 10:45

Re: Retrouver une valeur a partir d'une colonne

Message par micmac »

Bonjour et bienvenue,

Plutôt qu'une copie écran où les en-têtes de lignes et colonnes sont invisibles, fournissez à la place un fichier complet. Cela augmentera vos chances de réponse en évitant d'avoir à jouer aux devinettes.
Donnez un nom clair à ce fichier. Evitez "essai", "test" et autres "sans nom" dont nos tiroirs débordent....
Touche Ctrl de Windows = touche cmd⌘ sur Mac
Outils > Options sur Windows = OpenOffice > Préférences sur Mac
Pristio
Fraîchement OOthentifié
Messages : 5
Inscription : 27 mai 2019 18:59

Re: Retrouver une valeur a partir d'une colonne

Message par Pristio »

Je n'ai pas vu que j'avais caché les noms de ligne et colonne désolé. J'ai édité le message. Merci :)

EDIT :
J'ai trouvé une partie de la solution avec la formule :

Code : Tout sélectionner

=INDEX($J$1:$J$12;EQUIV(A1;$E$1:$E$12))
Par contre, j'ai tout de même un problème, car sur certaines lignes, il me met "#N/D", alors que je suis sensé avoir une valeur. Mais d'autres, pour la même formule, me donnent exactement ce que je veux
LibreOffice 6.2.4.2 (x64) - Windows 10
Avatar de l’utilisateur
Jean-Louis Cadeillan
GourOOu
GourOOu
Messages : 5732
Inscription : 03 janv. 2009 00:56

Re: Retrouver une valeur a partir d'une colonne

Message par Jean-Louis Cadeillan »

Bonsoir,
Le couple INDEX(EQUIV()) est une bonne solution, précise juste le troisième argument de EQUIV à 0 (correspondance exacte) :

Code : Tout sélectionner

=INDEX($J$1:$J$12;EQUIV(A1;$E$1:$E$12;0))
Tu auras encore #N/D, mais uniquement quand ta recherche par EQUIV() porte sur une valeur dans la colonne E qui n'existe pas (par exemple 0). Pour ce contrôle d'erreur, tu peux fignoler en mettant :

Code : Tout sélectionner

=SI(ESTNA(EQUIV(A1;$E$1:$E$12;0));"";INDEX($J$1:$J$12;EQUIV(A1;$E$1:$E$12;0)))
ou encore (sous LibO) :

Code : Tout sélectionner

=SIERREUR(INDEX($J$1:$J$12;EQUIV(A1;$E$1:$E$12;0));"")
Sinon, tu pouvais utiliser la fonction RECHERCHEV() (toujours en C1) :

Code : Tout sélectionner

=RECHERCHEV(A1;$E$1:$J$12;6;0)
6 indiquant la 6ème colonne de la matrice $E$1:$J$12 qui contient la valeur à retourner. Le dernier argument, 0, correspond aussi à une recherche sur valeur exacte, comme pour EQUIV() (voir aide intégrée F1). Comme pour INDEX(EQUIV()), tu peux aussi contrôler les erreurs, soit par :

Code : Tout sélectionner

=SI(ESTNA(RECHERCHEV(A1;$E$1:$J$12;6;0));"";RECHERCHEV(A1;$E$1:$J$12;6;0))
soit par :

Code : Tout sélectionner

=SIERREUR(RECHERCHEV(A1;$E$1:$J$12;6;0);"")
Cordialement,
Jean-Louis
LibO 7.6.5.2 (x64 avec Java 1.8.0_401) et AOO 4.1.15 (avec Java x32 1.8.0_381), Windows 7 Édition Intégrale 64 SP1
Pristio
Fraîchement OOthentifié
Messages : 5
Inscription : 27 mai 2019 18:59

Re: Retrouver une valeur a partir d'une colonne

Message par Pristio »

Un réponse complète :) merci à toi. ça marche très bien.
LibreOffice 6.2.4.2 (x64) - Windows 10
Répondre