[Résolu] Calcul points foot, en fonction du résultat

Discussions à propos du tableur Calc.
Les questions sur les macros doivent être postées dans la section dédiée en dessous.

Modérateur : Vilains modOOs

Règles du forum
Cette section est uniquement dédiée au tableur Calc. Vous ne devez pas poster ici de questions sur les macros mais utiliser la section éponyme.
Monox
Fraîchement OOthentifié
Messages : 4
Inscription : 26 juil. 2018 17:17

[Résolu] Calcul points foot, en fonction du résultat

Message par Monox »

Bonjour à tous,

Je suis en galère pour me faciliter la vie ...

J'ai un tableau, référençant tous les matchs de mes équipes.
J'aimerais que quand je rentre mes résultats, un résultat me calcul automatiquement le nombre de point total.

Voici un exemple de mon tableau :
Sans titre.png
Sans titre.png (7.57 Kio) Consulté 453 fois
Donc j'aimerais que D2 = 0points, E2=1points, F2 = 3 points

Le tout serait additionné dans ma cellule O2. Qui est actuellement remplie manuellement.

Merci d'avance, en espérant avoir posté dans la bonne rubrique ...
Monox
Dernière modification par Monox le 27 juil. 2018 00:27, modifié 1 fois.
OpenOffice 4.1.4 sous Windows 10
Avatar de l’utilisateur
micmac
RespOOnsable forum
RespOOnsable forum
Messages : 9224
Inscription : 28 août 2010 10:45

Re: Calcul points foot, en fonction du résultat

Message par micmac »

Bonjour,

Image
Comment joindre un fichier au format ODF
Veillez également à dépersonnaliser votre fichier.
Donnez un nom clair à ce fichier. Evitez "essai", "test" et autres dont nos tiroirs débordent...
Touche Ctrl de Windows = touche cmd⌘ sur Mac
Outils > Options sur Windows = OpenOffice > Préférences sur Mac
Monox
Fraîchement OOthentifié
Messages : 4
Inscription : 26 juil. 2018 17:17

Re: Calcul points foot, en fonction du résultat

Message par Monox »

Voilà !
Pièces jointes
Tableau de gestion LV.ods
(25.23 Kio) Téléchargé 26 fois
OpenOffice 4.1.4 sous Windows 10
Avatar de l’utilisateur
Jean-Louis Cadeillan
GourOOu
GourOOu
Messages : 5732
Inscription : 03 janv. 2009 00:56

Re: Calcul points foot, en fonction du résultat

Message par Jean-Louis Cadeillan »

Bonsoir,
Si je suppose qu'il n'y a pas plus de 9 buts marqués pour une équipe dans un match, on peut proposer la formule suivante, matricielle, en O44 :

Code : Tout sélectionner

=SOMME(SI(GAUCHE(D44:M44)>DROITE(D44:M44);3;SI(GAUCHE(D44:M44)=DROITE(D44:M44);1;0)))
validée par Maj+Ctrl+Entrée
Dans le fichier joint, j'ai mis une formule de simulation de match de D44 à M44 pour vérifier la formule... ce qui fait beaucoup de buts :mrgreen: ... pour changer les matchs, Maj+Ctrl+F9...
 Ajout : Pour un cas plus général quel que soit le nombre de buts, on pourrait utiliser cette formule :

Code : Tout sélectionner

=SOMME(SI(CNUM(STXT(D44:M44;1;TROUVE("-";D44:M44)-1))>CNUM(DROITE(D44:M44;NBCAR(D44:M44)-TROUVE("-";D44:M44)));3;SI(CNUM(STXT(D44:M44;1;TROUVE("-";D44:M44)-1))=CNUM(DROITE(D44:M44;NBCAR(D44:M44)-TROUVE("-";D44:M44)));1;0)))
formule matricielle validée aussi par Maj+Ctrl+Entrée 
Cordialement,
Jean-Louis
Pièces jointes
Monox_20180726_JLC01.ods
(29.93 Kio) Téléchargé 18 fois
LibO 7.6.5.2 (x64 avec Java 1.8.0_401) et AOO 4.1.15 (avec Java x32 1.8.0_381), Windows 7 Édition Intégrale 64 SP1
Monox
Fraîchement OOthentifié
Messages : 4
Inscription : 26 juil. 2018 17:17

Re: Calcul points foot, en fonction du résultat

Message par Monox »

J'ai essayé ... Sans succès, ca me donne une valeur erronée. Pourtant sur ton document, tout fonctionne parfaitement ! Il y a aucun paramétrage à faire pour appliquer ce genre de formules ?

Je vais voir ça demain, plus à tête reposée...

Merci en tout cas !
OpenOffice 4.1.4 sous Windows 10
Avatar de l’utilisateur
Jean-Louis Cadeillan
GourOOu
GourOOu
Messages : 5732
Inscription : 03 janv. 2009 00:56

Re: Calcul points foot, en fonction du résultat

Message par Jean-Louis Cadeillan »

Monox a écrit :ça me donne une valeur erronée
sans doute parce que bêtement :oops: je n'avais pas testé le cas où certains matches n'ont pas encore eu lieu (quand la cellule du score est vide) : mes formules traitaient ce cas comme un match nul.
Voici le correctif :
Formule 1 en O4:

Code : Tout sélectionner

=SOMME(SI(D4:M4="";0;SI(GAUCHE(D4:M4)>DROITE(D4:M4);3;SI(GAUCHE(D4:M4)=DROITE(D4:M4);1;0))))
Comme tu peux le voir, on rajoute un test SI(D4:M4="";0; lorsque la cellule est vide.
Formule 2 en O5:

Code : Tout sélectionner

=SOMME(SI(D4:M4="";0;SI(CNUM(STXT(D4:M4;1;TROUVE("-";D4:M4)-1))>CNUM(DROITE(D4:M4;NBCAR(D4:M4)-TROUVE("-";D4:M4)));3;SI(CNUM(STXT(D4:M4;1;TROUVE("-";D4:M4)-1))=CNUM(DROITE(D4:M4;NBCAR(D4:M4)-TROUVE("-";D4:M4)));1;0))))
même ajout au début de la formule.
Les deux formules donnent le même total de points tant qu'une équipe de marque pas plus de 9 buts, après seule la formule 2 est juste. Il te faudra choisir l'une ou l'autre car pour l'instant, bien sûr, le total des points de la Légion Viking est doublé (vu qu'il y a deux formules par série de matches).
Voir ci-joint,
Cordialement,
Jean-Louis
Pièces jointes
Monox_20180726_JLC02.ods
(29.52 Kio) Téléchargé 23 fois
LibO 7.6.5.2 (x64 avec Java 1.8.0_401) et AOO 4.1.15 (avec Java x32 1.8.0_381), Windows 7 Édition Intégrale 64 SP1
Monox
Fraîchement OOthentifié
Messages : 4
Inscription : 26 juil. 2018 17:17

Re: Calcul points foot, en fonction du résultat

Message par Monox »

Je te remercie grandement Jean-Louis !

Mon problème est donc résolu :)

Manque plus qu'à trouver comment trier mes lignes à ma convenance, en continuant de les coupler par deux ^^

Merci beaucoup en tout cas !!
OpenOffice 4.1.4 sous Windows 10
Répondre