[Résolu][Calc]cibler derniere cellule par nom

[Whiteneck]

Bonjour

Je cherche à cibler la dernière cellule renseignée dans une zone.
J'y arrive en déterminant la zone par sa position mai plus par son nom.
Je ne sais pas d'où vient mon erreur.

Si j'écris ceci ça fonctionne :

Code : Tout sélectionner

oZone = oFeuille.getCellRangeByPosition(1,10,1,20) 'Zone de destination

Mais je voudrais le remplacer par cela :

Code : Tout sélectionner

oZone = oFeuille.getCellRangeByName("Cellule_deb","Cellule_fin") 'Zone de destination

Ce que j'ai fait :

Code : Tout sélectionner

Sub Dernierecellule
Dim oDoc, ofeuille, Cellule as Object
Dim oZone as Variant
Dim LigneVide, colon as long

oDoc = ThisComponent
oFeuille = oDoc.CurrentController.ActiveSheet
oFeuille = thiscomponent.Sheets.getByName("Nature") 	'Feuille source

colon = oFeuille.getCellRangeByName("Cellule_deb").CellAddress.Column

oZone = oFeuille.getCellRangeByPosition(1,10,1,20) 'Zone de destination
'C'est ici que ça coince !
'oZone = oFeuille.getCellRangeByName("Cellule_deb","Cellule_fin") 'Zone de destination

LigneVide = oZone.QueryEmptyCells.RangeAddresses(0).StartRow
Cellule = oFeuille.getCellByPosition(colon, LigneVide-1)

Msgbox(Cellule.string)
end sub

Merci de votre aide

[Piaf]

Bonjour
Tu peux tester

Code : Tout sélectionner

Sub Dernierecellule
Dim oDoc, ofeuille, Cellule as Object
Dim oZone as Variant
Dim LigneVide, colon as long
Dim deb as String, fin as String
	oDoc = ThisComponent
	oFeuille = oDoc.CurrentController.ActiveSheet
	oFeuille = thiscomponent.Sheets.getByName("Nature") 	'Feuille source
	colon = oFeuille.getCellRangeByName("Cellule_deb").CellAddress.Column
	deb = Split(oFeuille.getCellRangeByName("Cellule_deb").AbsoluteName,".")(1)
	fin = Split(oFeuille.getCellRangeByName("Cellule_fin").AbsoluteName,".")(1)
	oZone = oFeuille.getCellRangeByName(deb & ":" & fin) 'Zone de destination
	LigneVide = oZone.QueryEmptyCells.RangeAddresses(0).StartRow
	Cellule = oFeuille.getCellByPosition(colon, LigneVide-1)
	Msgbox(Cellule.string)
end sub

A+

[Whiteneck]

Merci beaucoup piaf (encore une fois), ça fonctionne très bien.

[Churay]

Bonjour,

Un peu tardivement...

mais on peut faire un peu plus court....

Code : Tout sélectionner

Sub DerCell
Dim oDoc, ofeuille, Cellule as Object
Dim oZone as Variant
Dim LigneVide
Dim deb AS Long, fin  AS Long, Col AS Long
	oDoc = ThisComponent
	oFeuille = thiscomponent.Sheets.getByName("Nature")    'Feuille source
	col = oFeuille.getCellRangeByName("Cellule_deb").CellAddress.Column
	deb = oFeuille.getCellRangeByName("Cellule_deb").CellAddress.Row
	fin = oFeuille.getCellRangeByName("Cellule_fin").CellAddress.Row
	oZone = oFeuille.getCellRangeByPosition(Col,  deb, Col, fin) 'Zone de destination
	LigneVide = oZone.QueryEmptyCells.RangeAddresses(0).StartRow
	Cellule = oFeuille.getCellByPosition(col, LigneVide-1)
	Msgbox(Cellule.string, 32, "La dernière Cellule contient")
end sub

[Whiteneck]

Un peu tardivement... Merci