[Résolu] Compter les mots d'un fichier Calc

Houlala · Message par **Houlala** » 06 juin 2007 15:40

Bonjour,

Comment peut-on compter les mots d'un fichier Calc ?

Merci !

vinc-mai · Message par **vinc-mai** » 06 juin 2007 16:33

Qu'appelez-vous mot?

Dans fichier->propriétés->statistique, le nombre de cellules est affichée.
Par contre, pour un nombre de mots, je voie pas.
A moins de l'enregistrer au format texte (csv par exemple) puis d'utiliser un éditeur de texte pour compter. Par contre, il ne devrait pas faire la différence entre les mots et nombres.

Houlala · Message par **Houlala** » 06 juin 2007 16:49

Bonjour et merci,

Par mot j'entendais bien un assemblage de lettres, il peut y en avoir plusieurs par cellules et il peut y avoir des cellules vides.

La technique de sauver en texte CSV me convient bien. J'ai aussi essayé un utilitaire "anycount" prévu pour ça, mais il plante à chaque coup avec Calc.

Si quelqu'un connait un utilitaire semblable ou une macro qui fonctionne avec Calc, ça m'intéresse.

Jeff · Message par **Jeff** » 06 juin 2007 22:16

Bonsoir Houlala,

Question trés technique, et un peu vague...

Dans ce Post-it : Quelques exemples de fonctions dans Calc MichelXld donne une formule qui compte le nombre de "a" dans la cellule A1.
On pourrait l'adapter pour compter le nombre d'espace :

Code : Tout sélectionner

=NBCAR(A1)-NBCAR(SUBSTITUE(A1;" ";""))+1

J'ai rajouté +1 car logiquement, tu as un mot de plus que les espaces.
Si tu as des espaces accidentels, il faut utiliser auparavant une fonction SUPPRESPACE.

Maintenant, pour compter sur une feuille complète

A +

Jeff · Message par **Jeff** » 06 juin 2007 22:23

Jeff a écrit :Maintenant, pour compter sur une feuille complète

Tu peux apparemment passer par une fonction de matrice ; par exemple, pour compter les espaces + 1 (donc les mots) de la cellule A1, A2 et A3 :

Code : Tout sélectionner

=SOMME(NBCAR(A1:A3)-NBCAR(SUBSTITUE(A1:A3;" ";""))+1)

à valider matriciellement (à la place de taper Entrée à la fin de la formule, valide par Ctrl+Maj+Entrée), à ce moment là, Calc rajoute des accolades autour de ta formule.

A +

Houlala · Message par **Houlala** » 07 juin 2007 05:18

Génial, merci Jeff, ça marche parfaitement !!!

Jeff · Message par **Jeff** » 07 juin 2007 05:23

Content que cela te convienne

Pour rajouter la balise [Résolu] dans ton titre, c'est par ici

http://user.services.openoffice.org/fr/ ... html#18488

A +

Jeff · Message par **Jeff** » 07 juin 2007 05:29

Ah, j'oubliais : dans le Tutoriel sur les fonctions de matrice, mes recherches ont abouties au fait qu'une fonction matricielle ne peut agir que sur une plage de 128x128 cellules ; je ne sais pas si cette limite est toujours d'actualité...

A +

Houlala · Message par **Houlala** » 07 juin 2007 05:37

J'ai essayé sur une colonne de 3000 cellules et le compte était bon. Ok, je vais mettre [résolu], merci encore et bonne journée !

Jeff · Message par **Jeff** » 07 juin 2007 05:45

Je ne pense pas que ce soit la largeur ou la hauteur de ta plage qui compte, mais bien le nombre de cellules, soit 128x128= 16384 cellules.

Merci pour la balise qui facilitera les futures recherches

Vandeput · Message par **Vandeput** » 07 juin 2007 06:47

Bonjour,

Je m'y prends probablement fort mal, mais la formule de Jeff me renvoie une valeur erronée lorsqu'il y a des cellules vides dans la plage de comptage (voir pièce jointe).

Il me semble que le +1 dans la formule compte également les cellules vides pour une unité.

Je propose une autre formule qui renvoie le bon résultat, mais qui reste à vérifier !

http://user.services.openoffice.org/fr/ ... 084250.age

PS 1 : j'ai à nouveau une extension bizarre, peut-être faudra-t-il la remplacer par .ods
PS 2 : j'ai décalé le tableau d'une ligne et d'une colonne en oubliant d'adapter les formules en texte.
Il faut donc y remplacer A1:C8 par B2:D9

Jeff · Message par **Jeff** » 07 juin 2007 18:04

Salut André,

Vandeput a écrit :la formule de Jeff me renvoie une valeur erronée lorsqu'il y a des cellules vides dans la plage

+1

j'ai pas pensé aux cellules vides

Vandeput a écrit :PS 1 : j'ai à nouveau une extension bizarre, peut-être faudra-t-il la remplacer par .ods

Tu devrai contacter en MP Bidouille ou C-Stephan pour connaitre l'origine de ce problème.
Pour les utilisateur de Firefox, faire simplement Ouvrir avec puis sélectionner soffice.exe (généralement dans ProgramFiles->OOo2.2->Program), Calc s'ouvre alors automatiquement.

Encore une modification simpose, s'il n'y a qu'un mot, un espace est compté, comment penses-tu que l'on pourrait faire ?

A +

Vandeput · Message par **Vandeput** » 07 juin 2007 18:23

Bonsoir Jeff,

Il me semble que la formule que j'ai proposée sous ma pièce jointe renvoie le bon résultat.
Pour moi "le compte est bon".

A moins que tu aies trouvé autre chose qui ne fonctionne pas.

Jeff · Message par **Jeff** » 07 juin 2007 18:44

C'est rien, c'est les yeux...

Vandeput · Message par **Vandeput** » 08 juin 2007 04:47

Bonjour,

C'est toute la différence entre "voir" et "regarder".

Il reste néanmoins deux problèmes :
- un espace devant ou derrière une chaîne de caractères
- un espace dans une cellule sans texte
Dans les deux cas, la formule compte un mot en plus.

Pour le premier problème j'ai trouvé une solution :
=SOMME(NBCAR(SUPPRESPACE(B2:D9))-NBCAR(SUBSTITUE(B2:D9;" ";"")))+NBVAL(B2:D9)

Pour le second, pas (encore).

Vandeput · Message par **Vandeput** » 08 juin 2007 07:09

Et voilà :

=SOMME(NBCAR(SUPPRESPACE(B2:D9))-NBCAR(SUBSTITUE(B2:D9;" ";"")))+NBVAL(B2:D9)-NB.SI(B2:D9;" ")
formule matricielle.

Le dernier point non résolu : plusieurs espaces sans chaîne de caractère dans une cellule.

Vandeput · Message par **Vandeput** » 08 juin 2007 14:28

Re,

=SOMME(NBCAR(SUPPRESPACE(B2:D9))-NBCAR(SUBSTITUE(B2:D9;" ";""))+(NBCAR(SUBSTITUE(B2:D9;" ";""))>0))
formule matricielle (à valider par Ctrl+Maj+Entrée)

Dernier problème résolu, ... je l'espère.

Edition :
Une chaine de caractères provenant d'un format est comptabilisé suivant sa valeur et non suivant son format.
Exemple : =AUJOURDHUI() au Format personnalisé JJJ JJ MMM AA sera comptabilisé pour une chaine,
par contre : =TEXTE(AUJOURDHUI;"JJJ JJ MMM AA") sera comptabilisé pour quatre chaines.

Vandeput · Message par **Vandeput** » 09 juin 2007 12:44

Re,

Dernier petit correctif (je l'espère).

Pour ne pas devoir valider en matricielle, remplacer dans la formule proposée sous mon denier post, SOMME par SOMMEPROD.