[Résolu][Writer] Cloner un champ liste de saisie existant

[Aurélien73]

Nous avons supprimé par macro qui est inutile dans le titre puisque vous postez en section macros.

Bonjour à tous,

Je reviens vers vous pour une un problème sur les champs utilisateurs / listbox et leur gestion par macro.

L'idée :
Je souhaite intégrer un champ utilisateur existant (textfield ou listbox) à la position du curseur (dans un tableau)

Pas de souci pour le textfield, en revanche je galère avec la liste de choix.

Si l'un d'entre vous a une idée lumineuse

Je vous joints le fichier test

Test.odt

Bon week-end

[Dolev]

Bonjour,

Une listbox est un contrôle qui s'insère sur l'objet DrawPrage du document.
On l'emploie dans un formulaire.
Donc, je ne comprends pas ce que tu cherches à faire.

Pourquoi ne pas utiliser la fonction InputBox ?

[Aurélien73]

@Dolev

Je souhaite insérer un champ de type liste de saisie existant via une macro à l'emplacement du curseur

J'ai réussi pour un champ utilisateur classique mais je sèche sur la liste de saisie.

Voir mon exemple en pièce jointe.

[Dolev]

mais je sèche sur la liste de saisie

Alors pourquoi parler de listbox dans ton titre ?
Un titre clair permet de faciliter les recherches.

Voir mon exemple en pièce jointe.

Ton exemple n'est pas très parlant.
L'insertion doit se faire à quel endroit dans le document ?
Que doit contenir la liste ?
D'où vont venir les données ?

Il faudrait être un peu plus clair.

[Aurélien73]

@Dolev

Désolé je vais essayer d'être plus clair...

Pour l'insertion, je veux qu'en appuyant sur le bouton correspondant "Insérer Champ" ou "Insérer liste" cela l'insère à l'endroit indiqué quand on positionne le curseur dans la deuxième colonne
"Positionnez le curseur dans la colonne à droite et cliquez sur le bouton pour insérer le champ correspondant"



Le bouton / macro "Insérer Champ" fonctionne. Cela insère bien le Champ dont la valeur est Test.

En revanche je n'arrive pas insérer la liste de saisie de la même façon à ce même endroit.
En espérant avoir été plus clair.

J'ai changé dans le titre listbox par liste de saisie.

[Dolev]

En revanche je n'arrive pas insérer la liste de saisie de la même façon à ce même endroit.
En espérant avoir été plus clair.

Même endroit ne veut rien dire puisque tu cliques sur un bouton.
Et tu ne réponds pas à toutes mes questions.

La liste de saisie s'appelle via le service DropDown
Exemple :

Code : Tout sélectionner

Sub insertChampListe()
	sElems() = Array("Objet 1", "Objet 2")
	oDoc = ThisComponent
	oChamp = oDoc.createInstance("com.sun.star.text.textfield.DropDown")
	With oChamp
		.Name = "MaListe"
		.Items = sElems
		.SelectedItem = "Objet 1"
	End with
	oCursor = oDoc.Text.CreateTextCursor
	oCursor.GoToEnd(False)   
	oDoc.text.insertTextContent(oCursor, oChamp, False)   
End Sub

J'ai changé dans le titre listbox par liste de saisie.

Non, le titre se change dans le 1er message si tu veux qu'il soit visible.

[Aurélien73]

@Dolev
Merci pour ton code.
Mais cela ne correspond pas à mes attentes. Je ne parviens peut-être pas à m'expliquer clairement.

Ton code créé la liste de saisie.

Ce que je souhaite est insérer une liste de saisie déjà existante comme dans mon modèle dont le nom est MaListe

Quant au positionnement, je veux l'insérer à l'endroit où se trouve le curseur qui sera dans un tableau (en 2eme colonne dans mon exemple)

[Dolev]

Mon code insère une liste de saisie.
Ta demande est donc de remplacer ou de compléter une liste de saisie existante, ce qui est encore autre chose.

Je passe mon tour.
Bon courage.

[Aurélien73]

@Dolev

Merci d'avoir essayé de comprendre.
Je vais remodifier le titre pour être encore plus précis...

[zeguedon]

Bonsoir,

Ce que je souhaite est insérer une liste de saisie déjà existante comme dans mon modèle dont le nom est MaListe

Tu ne peux pas insérer une liste déjà existante puisqu'elle est déjà insérée
a) soit tu cherches à la déplacer
b) soit tu cherches à la cloner
et l'insérer à la position du curseur dans une cellule du tableau.
Merci de préciser les points a ou b
@+

[Aurélien73]

@zeguedon

D'accord.
Donc je cherche à la clôner (b)

[zeguedon]

Merci,

Code : Tout sélectionner

REM  *****  BASIC  *****

Option Explicit

Private oItems() As Variant
Private oSelectedItem As String
Private oDoc As Object
Const oTextfieldName = "MaListe" 'ATTENTION sensible à la CaSSe

Sub RecupChamp
Dim lesChamps As Object
Dim unChamp As Object
oDoc = thiscomponent
lesChamps = oDoc.TextFields.createEnumeration
Do While lesChamps.hasMoreElements
unChamp = lesChamps.NextElement
'xray unChamp
if unChamp.supportsService("com.sun.star.text.textfield.DropDown") then
	if unChamp.Name = oTextfieldName Then
		'xray unChamp
		oItems() = unChamp.Items
		oSelectedItem = unChamp.SelectedItem
	end if
end if
loop
End Sub

Sub InsertChamp 'Connecter le bouton ici
Dim oChamp As Object
Dim curseurVisible As Object
Dim monTexte As Object
Dim monCurseur As Object
RecupChamp
'Dolev and Aurélien73 Inside
'https://forum.openoffice.org/fr/forum/viewtopic.php?f=8&t=63799&p=349235#p349172
oChamp = oDoc.createInstance("com.sun.star.text.textfield.DropDown")
With oChamp
	.Name = oTextfieldName
	.Items = oItems()
	.SelectedItem = oSelectedItem
End with
curseurVisible = oDoc.CurrentController.ViewCursor   
if curseurVisible.Text.ImplementationName = "SwXCell" Then   
	monTexte = CurseurVisible.Text
	monCurseur = monTexte.createTextCursor
	moncurseur.gotoRange(CurseurVisible.End,False)   
	monTexte.insertTextContent(monCurseur, oChamp, False)
end If
end sub

@+
Dolev te donnait la solution qu'il fallait inclure à ton propre code. Et pour récupérer le contenu de ton champ liste tu pouvais t'inspirer du code que te donnait Jurassic Pork dans ton précédent fil

[Aurélien73]

Au top @zeguedon
Effectivement, je n'avais pas vu cela comme çà, je cherchais autrement
Un grand merci en tous cas

[zeguedon]

Bonjour Aurélien73,

Du coup ton titre ne reflète pas réellement le contenu du sujet. J'opterai plutôt pour :
Cloner un champ liste existant
car il s'agit bien de récupérer tout le contenu d'un champ liste existant pour le recréer ailleurs.
@+