[Résolu][Basic]Transparence image

[Gerfaud]

Bonjour,

J'ai besoin de rendre transparentes les parties blanches d'une image.
Je cherche le code en basic.
J'ai identifié la commande utilisateur pour faire cela : Tools -> color replacer
qui ouvre un dialogue comportant les arguments pour faire le changement (couleur de depart, tolerance, couleur d'arrivée, alpha)
L'exploration de l'object image m'a permis de trouver la propriété Graphic
mais les propriétés de graphic sont en lecture seule.
J'ai identifié la commande du diptacher pour déclencher le dialogue "color deplacer": .uno:BmpMask
mais je ne sais pas comment remplir les argument en basic.
J'ai aussi identifier l'interface basic qui semble permettre de faire le changement :
com::sun::XGraphicTransformer
J'ai identifié la fonction dans cette interface : colorChange(….).
Cette fonction prend les mêmes arguments que ceux du dialogue "color replacer".
Mais je ne trouve pas cette fonction dans les methodes des objects que j'ai identifiés.

Dans quel object se trouve cette fonction ?
Ou, quel est la fonction basic équivalente à la fonction colorChange de l'interface XGraphicTransformer et de quel objet dépend-t-elle ?

Merci de vos réponses

Cordialement

Ci-joint un fichier avec un bouton pour déclencher la modification

[Gerfaud]

Bonjour,

Je continue de chercher un moyen de rendre le blanc d'une image transparent mais en basic.
Je suis médecin et je travaille sur un utilitaire de signature d'ordonnance sur libreOffice.
Il s'agit pour moi de mettre en forme la signature manuscrite d'un groupe de médecins qui travaillent en téléconsultation.
La plupart d'entre eux ne connaissent pas libreOffice et je veux donc limiter leurs interventions.
Je souhaite que leur premier usage de libreOffice soit très simple.
LibreOffice est très peu connu dans le monde de la santé libérale.

Mon fichier joint à évolué.
Il y a maintenant un bouton pour afficher le dialogue "color replacer" (menu Tools)
qui renvoi le dialogue de l'interface utilisateur et une boite de dialogue personnalisée pour valider.
Mais Il est nécessaire de cocher une des case-à-cocher pour que la manip fonctionne (c'est là que le code manque). Je voudrais pouvoir traiter le document sans l'intervention de l'utilisateur final.

Dans la macro ExploreDoc du document joint j'ai naïvement fait des essais pour associer l'interface XGraphicTransformer à mon object formImage.Graphic en utilisant la methode queryInterface :
formImage.Graphic.queryInterface("com.sun.star.graphic.XGraphicTransformer")
Basic ne rouspète pas mais je ne vois pas les méthodes de la nouvelle interface dans mon "nouvel" object (qui ne semble, en fait, ne pas avoir changé).

Je bidouille mais je ne comprends pas encore le mécanisme d'utilisation et d'accès aux "Xinterfaces". La documentation est très énigmatique avec des lapalissades qui ne permettent pas de savoir comment mettre en pratique ces notions.

Quelqu'un a-t-il des éléments pour m'aider à progresser ?

Cordialement

[Hubert Lambert]

Bonjour,

Apparemment, il existe bien un service GraphicTransformer, mais qui n'est pas accessible via l'API.
Du coup, je ne vois pas d'autre solution que de bricoler un peu pour accéder aux éléments du dialogue "Remplacement de couleurs", en rendant ce dernier invisible pour limiter l'impression d'une "main invisible" contrôlant l'interface.
Le code :

Code : Tout sélectionner

dim continue

sub main
    doc = thiscomponent
    controleur = doc.CurrentController
    frame = controleur.Frame
    ' sélectionner la signature
    drawpage = doc.DrawPages(0)
    for n = 0 to drawpage.Count -1
        if drawpage(n).Name = "signature" then
            controleur.select(drawpage(n))
            exit for
        end if
    next n
    ' afficher le dialogue de remplacement de couleur    
    dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")
    dispatcher.executeDispatch(frame, ".uno:BmpMask", "", 0, array())
    ' obtenir le dialogue ouvert
    dlg_colorreplace = obtTopDialogueParID("DockingColorReplace")
    dlg_colorreplace.setVisible(False)
    ' cocher la première case à cocher
    roles = com.sun.star.accessibility.AccessibleRole
    cbx = obtObjetParRoleEtID(dlg_colorreplace, roles.CHECK_BOX, "cbx1")
    cbx.doAccessibleAction(0)
    ' adapter la tolérance
    tolerance = obtObjetParRoleEtID(dlg_colorreplace, roles.TEXT, "tol1")
    tolerance.setText("20")
    ' exécuter le remplacement
    dispatcher.executeDispatch(frame, ".uno:BmpMaskExec", "", 0, array())
     ' fermer le dialogue et désélectionner l'image
    dispatcher.executeDispatch(frame, ".uno:BmpMask", "", 0, array())
    controleur.select(rien)
end sub

function obtTopDialogueParID(ID)
    doc = thiscomponent
    tk = doc.CurrentController.ComponentWindow.Toolkit
    for n = 0 to tk.TopWindowCount -1
        topwindow = tk.getTopWindow(n)
        if topwindow.AccessibleContext.AccessibleID = ID then
            obtTopDialogueParID = topwindow
            exit function
        end if
    next n
end function

function obtObjetParRoleEtID(racine, role, ID)
    continue = True
    ac = racine.AccessibleContext
    if ac.AccessibleRole = role then
        if ac.AccessibleID = ID then
            obtObjetParRoleEtID = ac
            continue = False
        end if
    else
        for n = 0 to ac.AccessibleChildCount-1
            if continue = False then
                exit for
            end if
            ac1 = obtObjetParRoleEtID(ac.getAccessibleChild(n), role, ID)
            obtObjetParRoleEtID = ac1
        next n
    end if
end function

Et le fichier exemple :

mettreLeBlancEnTransparent_V2.odg

Valable pour LibreOffice uniquement.
Cordialement.

[luky-luke]

Bonjour
Hubert Lambert

Valable pour LibreOffice uniquement.

Valable que pour LibreOffice version 6.x.x
Sur la 5.3 et la 5.4 la propriété AccessibleID n’existe pas, il n'y a que la propriété AccessibleName qui permet d'avoir accès à la boite de dialogue via la fonction obtTopDialogueParID(ID) mais ça bute sur la fonction obtObjetParRoleEtID(racine, role, ID)
Super boulot en tout cas , j'ai encore appris un truc ce soir
Cordialement
Luke

[Gerfaud]

Bonjour,

Un immense merci.
L'accès aux dialogues de l'interface utilisateur m'ouvre en plus des perspectives insoupçonnées !
Je repars en exploration de ce que vous venez de me faire découvrir.

Cordialement