[Résolu][Basic] Titre de la fenêtre Ouvrir fichier

[mgc99]

Bonjour à tous,
J'ai récupérer sur internet une macro ChooseAFileName que j'ai modifier à ma sauce.

Code : Tout sélectionner

Function ChooseAFileName(nom) As String
  Dim vFileDialog         'FilePicker service instance
  Dim vFileAccess         'SimpleFileAccess service instance
  Dim iAccept as Integer  'Response to the FilePicker
  Dim sInitPath as String 'Hold the initial path
  'Note: The following services MUST be called in the following order
  'or Basic will not remove the FileDialog Service
  vFileDialog = CreateUnoService("com.sun.star.ui.dialogs.FilePicker")
  vFileAccess = CreateUnoService("com.sun.star.ucb.SimpleFileAccess")
  'Set the initial path here!
'  sInitPath = ConvertToUrl(CurDir)
'  If vFileAccess.Exists(sInitPath) Then
'    vFileDialog.SetDisplayDirectory(sInitPath)
'  End If
  vFileDialog.appendFilter("Textes txt", "*.txt")
  vFileDialog.appendFilter("Tous", "*.*")
  vFileDialog.appendFilter("OXO sub", "*.sub")
  vFileDialog.appendFilter("OXO ver", "*.ver")
 
  if nom = "Ouvrir OXO.sub" then 
    vFileDialog.CurrentFilter = "OXO sub"
  else
    if nom = "Ouvrir OXO.ver" then
      vFileDialog.CurrentFilter = "OXO ver"
    else
    vFileDialog.CurrentFilter = "Textes txt"
    endif
  endif
  vFileDialog.Title = nom
  
  iAccept = vFileDialog.Execute()       'Run the file chooser dialog
  If iAccept = 1 Then                   'What was the return value?
    ChooseAFileName = vFileDialog.Files(0) 'Set file name if it was not canceled
  End If
  vFileDialog.Dispose()                 'Dispose of the dialog
End Function

Cette fonction est parfaite mais depuis que je suis passé sous windows 10 64bit V.1803, je constate que le titre de la fenestre "Ouvrir" reste à "Ouvrir" alors qu'avec win XP je pouvais modifier ce titre. "vFileDialog.Title = nom" dans le code.

Quelqu'un sait-il ce qu'il faut changer dans le code pour que l'on puisse modifier le titre de la fenestre ouvrir ?

Merci pour les réponses

Salut à la prochaine
Michel

PS j'utilise OpenOffice 4.1.5

[Jurassic Pork]

hello,
je ne sais pas si c'est un bug mais effectivement le problème est présent avec A.O.O 4.1.5 sous windows 10. Avec LibreOffice 5.4.4.2 sous windows 10 je n'ai pas le problème.
En rajoutant quelques instructions à ta macro cela semble faire disparaître le problème :

Code : Tout sélectionner

  vFileDialog = CreateUnoService("com.sun.star.ui.dialogs.FilePicker")
  Dim DialogTyp(0)
   DialogTyp(0) = com.sun.star.ui.dialogs.TemplateDescription.FILEOPEN_SIMPLE
   vFileDialog.initialize(DialogTyp())
   vFileAccess = CreateUnoService("com.sun.star.ucb.SimpleFileAccess")

Ami calmant, J.P

[Dude]

Rapport de bogue 96720 et fixé pour la prochaine 4.2.0
Le contournement est effectivement d'initialiser les constantes du service FilePicker.

[mgc99]

Salut et merci pour les réponses.
Le code fonctionne parfaitement

Salut à la prochaine
Michel