[Résolu][Calc] Filtre de caractère joker dans un champ

[Phane]

Bonjour

Après quelques moins "d'abstinence" je me replonge dans les macros libreOffice et je crois bien avoir perdu quelques trucs en cours de route...

Je travaille actuellement sur les filtres et je cherche à isoler dans une liste volumineuse ( 53.000 lignes) les lignes qui comportent des caractères problématiques ( &,/,*)

Mon filtre fonctionne pour / et &

Code : Tout sélectionner

With champsFiltre(0)					'Parametre le 1er critère de filtre
	.Field = 0                  		        'Filtre la colonne A 
	.Operator = com.sun.star.sheet.FilterOperator.EQUAL
	.IsNumeric = false          		        'Utilise une chaîne et non un nombre.
	.StringValue = ".*/.*"				'Valeur a chercher n'importe ou dans le champ
End With

mais je n'arrive pas à chercher les * ... forcément. Je pense que ce que je recherche ( .StringValue = ".***." ) n'est pas bon, sans savoir par quoi le remplacer

Merci d'avance

[Bidouille]

Pour être aidé efficacement par les bénévoles et surtout leur faire gagner du temps, veuillez fournir les éléments suivants :

1. insérer dans le corps du message le code de la macro exposant le problème
2. joindre un document explicatif intégrant cette macro avec les données de départ (feuille1) et le résultat à obtenir (feuille2)
3. fournir un mode pas-à-pas permettant de reproduire ce qui a été fait ou ce que vous cherchez à faire pour arriver au problème
4. ajouter des copies écran (situation avant / après) si cela permet de mieux comprendre

Merci de publier ces informations à la suite.

Et avec autant de messages à votre compteur, corrigez aussi votre titre avant la claque.

[Phane]

@bidouille : OK j'ai honte ....

Voici le code complet pour ce filtre et un fichier exemple

Code : Tout sélectionner

option explicit

'===============================================================
Sub Filtre_PP_Caracteres
'===============================================================
'Récupère les lignes avec des caractères parasites
'---------------------------------------------------------------
Dim mafeuille as object
Dim monFiltre as object, pointresu as object, ZoneImport as object
Dim champsFiltre(2) as New com.sun.star.sheet.TableFilterField
Dim y as long
'---------------------------------------------------------------
Mafeuille =  Thiscomponent.sheets.getbyname("Test")				' Feuille source	
ZoneImport = Mafeuille.getCellRangeByposition(0,0,0,5)	 		'zone à filtrer
pointResu =  Mafeuille.Getcellbyposition(2,0)	

	'paramètres personnalisés du filtre 
	With champsFiltre(0)					'Parametre le 1er critère de filtre
		.Field = 0                  		'Filtre la colonne A 
		.Operator = com.sun.star.sheet.FilterOperator.EQUAL
		.IsNumeric = false          		'Utilise une chaîne et non un nombre.
		.StringValue = ".*/.*"				'Valeur a chercher n'importe ou dans le champ
   	End With
    
    With champsFiltre(1)					'Parametre le 1er critère de filtre
		.Connection = com.sun.star.sheet.FilterConnection.OR
		.Field = 0                  		'Filtre la colonne A 
		.Operator = com.sun.star.sheet.FilterOperator.EQUAL
		.IsNumeric = false          		'Utilise une chaîne et non un nombre.
		.StringValue = ".*&.*"		  			 'Valeur a chercher
   End With
    
    With champsFiltre(2)					'Parametre le 1er critère de filtre
    	.Connection = com.sun.star.sheet.FilterConnection.OR
		.Field = 0                  		'Filtre la colonne A 
		.Operator = com.sun.star.sheet.FilterOperator.EQUAL
		.IsNumeric = false          		'Utilise une chaîne et non un nombre.
		.StringValue = ".***."  				'Valeur a chercher
    End With
    	
	MonFiltre = ZoneImport.createFilterDescriptor(True)
		
	With MonFiltre
		.CopyOutputData = True		
		.ContainsHeader = true		
		.outputposition = pointResu.CellAddress
		.UseRegularExpressions = true
		.FilterFields = champsFiltre()
	End with
	
	ZoneImport.filter(MonFiltre)		'Appliquer le filtre
	
	
End sub

[Churay]

Bonjour,

Le caractère * est presque toujours un pb...

Je travaille actuellement sur les filtres et je cherche à isoler dans une liste volumineuse ( 53.000 lignes) les lignes qui comportent des caractères problématiques ( &,/,*)

S'il n'y a rien de confidentiel, je suis preneur du fichier pour tester à l'ancienne. Avec la liste des caractères à rechercher.
5 000 lignes donneraient déjà une idée.

Si c'est confidentiel, je suis toujours preneur, mais il t'appartient de le rendre anonyme.

[Jeff]

Bonjour,

Fais un essai en remplaçant :

Code : Tout sélectionner

.StringValue = ".***."                  'Valeur a chercher

Par :

Code : Tout sélectionner

.StringValue = ".*\*.*"                  'Valeur a chercher

A +

[Phane]

Ohhh Jeff, comme j'aimerais prendre le temps de partager une petite mousse pour cette solution qui fonctionne avec mes données

@churay :Les données sont plutôt sensibles mais j'aurais faire l'effort de les rendre anonymes sans la solution de Jeff. Merci en tout cas de cette (tres) gentille proposition

Merci à tous

[Jeff]

La solution est dans l’aide F1 :

expr_reg.png

[Churay]

J'ai recopié ton exemple, jusqu'à la ligne 50 034 :

• - jusqu'à 250 lignes, le filtre est instantané,
  - à 260 je n'ai pas la patience d'attendre... Je crains sérieusement pour 50 000 lignes...

Une simple macro de balayage, met

• - 1 mn 15 s pour copier les chaînes en colonne C des 50 033 lignes à tester...
  - 2 mn à 2 mn 30 s pour changer la couleur de fond des cellules contenant les caractères recherchés sur les 50 033 lignes à tester...