[Résolu] Report Formatage vers cellule résultat

[Fran]

re bonjour,

j'ai l'impression d'avoir déjà envoyé mon post, mais je ne le vois pas....donc je recommence.

Est-il possible que la cellule dont le contenu est la valeur d'une cellule d'une autre feuille (data) s'affuble du même formatage (couleur, police,...) que la cellule où le résultat été trouvé dans la feuille data?

Merci d'avance.

[Jeff]

Bonjour,

Le plus simple me semble de créer les styles identiques aux contenus.

A +

[Fran]

Si je comprends bien, dans le tableau toutes les cellule formatées ont un style défini.
C'est le fait que ce soit un style, qui fait que cela se reportera sur l'autre feuille?

[Jeff]

J’ai été un peu succinct...

J’ai créé des styles qui se nomment à l’identique du contenu des cellules ; du coup, la fonction STYLE récupère le contenu de la cellule et applique le style éponyme.

Les cellules restent au format "Par défaut" (sauf application de MFC)

Le tuto sur le formatage conditionnel :
http://www.openoffice.org/fr/Documentat ... es_mfc.pdf

A +

[Fran]

Merci pour la réponse.
Mais, ici (dans mon grand tableau différent de l'exemple pris pour la question précédente) il ne peut y avoir de formatage conditionnel étant donné qu'une même valeur de cellule peut avoir 2 formatages différents.
Donc au final j'ai sélectionné toutes les cellules de format identique et j'ai appliqué le style que j'ai crée avant en fonction de ce que j'avais formaté avant.
Même en faisant cela, où toutes les cellules ont un style, le style ne s'affiche pas dans le résultat.
Donc ce n'est pas le fait d'avoir un style qui fait que le formatage est reporté.
Par contre je ne sais pas utiliser la fonction dont vous parlez, je vais regarder cela de plus près.
A suivre...

[Jeff]

j'ai sélectionné toutes les cellules de format identique et j'ai appliqué le style

Très bonne nouvelle que tu sois passé par les styles

En installant une extension, tu peux récupérer le nom du style via STYLE.CELLULE (fonction fournie avec COUTSTYLE), puis passer ce nom dans la fonction STYLE, suis ce post pour télécharger l'extension :
https://forum.openoffice.org/fr/forum/v ... 72#p316572

A +

[Jeff]

Je poste à part pour plus de lisibilité...

mon grand tableau différent de l'exemple pris pour la question précédente

Un nouveau fichier joint aurait alors été souhaitable ... Donc ci-joint un exemple basé sur ton classeur précédent

En valeur.C8 :

• Tu récupérais la valeur voulue avec la formule :

  Code : Tout sélectionner

  =INDEX(data.B2:G5;EQUIV(C6;data.A2:A5;0);EQUIV(C7;data.B1:G1;0)) 

Une fois l’extension installée, celle-ci ajoute une fonction STYLE.CELLULE :

AOO_forum1.png

• Pour récupérer le style de la cellule, on utilise cette nouvelle fonction avec la formule de recherche déjà établie :

  Code : Tout sélectionner

  =STYLE.CELLULE(INDEX(data.B2:G5;EQUIV(C6;data.A2:A5;0);EQUIV(C7;data.B1:G1;0))) 

Pour appliquer le style récupéré, on passe le tout par la fonction éponyme :

• Code : Tout sélectionner

  =STYLE(STYLE.CELLULE(INDEX(data.B2:G5;EQUIV(C6;data.A2:A5;0);EQUIV(C7;data.B1:G1;0)))) 

  La fonction style appliquée ainsi nous donne le style à la cellule contenant cette formule, et renvoie une valeur 0 non désirée, pour supprimer cette valeur 0, on englobe alors le tout dans une fonction T :

  Code : Tout sélectionner

  =T(STYLE(STYLE.CELLULE(INDEX(data.B2:G5;EQUIV(C6;data.A2:A5;0);EQUIV(C7;data.B1:G1;0)))))

  Les cellules de départ (celle dont ont veut récupérer le style) sont du texte, on concatène la première formule de recherche avec cette formule finale, à l’aide de l’opérateur & :

  Code : Tout sélectionner

  =INDEX(data.B2:G5;EQUIV(C6;data.A2:A5;0);EQUIV(C7;data.B1:G1;0))&T(STYLE(STYLE.CELLULE(INDEX(data.B2:G5;EQUIV(C6;data.A2:A5;0);EQUIV(C7;data.B1:G1;0))))) 

  AOO_forum.png

A +

[Fran]

Bonjour!
Merci vraiment pour cette solution très bien expliquée, j'ai appris bcp de choses!!!
Cela fonctionne nickel !!
A bientôt
F