Bonjour,
Tu peux te servir de l’
assistant de fonction, car même si celui-ci n’affiche pas le résultat de fonction matricielle, il va t’aider à sélectionner les bouts de formule cohérents, que tu pourra tester avec bien sûr une validation matricielle.
Dans l’exemple suivant, le texte "Nombre" est saisi en Incendie.D8
Ta formule de base :
Code : Tout sélectionner
=INDIRECT("Incendie."&ADRESSE(MIN(SI(Incendie.A1:Z30="Nombre";LIGNE(Incendie.A1:Z30)));EQUIV("Nombre";INDIRECT(MIN(SI(Incendie.A1:Z30="Nombre";LIGNE(Incendie.A1:Z30)))&":"&MIN(SI(Incendie.A1:Z30="Nombre";LIGNE(Incendie.A1:Z30))));0)))
renvoie #ND
Grâce à l’assistant, je sélectionne le contenu de INDIRECT, puis validation matricielle :
Code : Tout sélectionner
="Incendie."&ADRESSE(MIN(SI(Incendie.A1:Z30="Nombre";LIGNE(Incendie.A1:Z30)));EQUIV("Nombre";INDIRECT(MIN(SI(Incendie.A1:Z30="Nombre";LIGNE(Incendie.A1:Z30)))&":"&MIN(SI(Incendie.A1:Z30="Nombre";LIGNE(Incendie.A1:Z30))));0))
renvoie encore #ND
On continu à creuser, en sélectionnant la fonction ADRESSE, puis validation matricielle :
Code : Tout sélectionner
=ADRESSE(MIN(SI(Incendie.A4:Z33="Nombre";LIGNE(Incendie.A4:Z33)));EQUIV("Nombre";INDIRECT(MIN(SI(Incendie.A4:Z33="Nombre";LIGNE(Incendie.A4:Z33)))&":"&MIN(SI(Incendie.A4:Z33="Nombre";LIGNE(Incendie.A4:Z33))));0))
renvoie encore #ND
On continu, en sélectionnant le paramètre
ligne de ADRESSE, toujours avec l’assistant :
Là, on obtient le bon résultat, à savoir le chiffre 8 (car l'exemple concerne la cellule Incendie.D8)
On poursuit les investigations sur le paramètre
colonne de ADRESSE, toujours avec l’assistant :
AOO_forum1.png
Code : Tout sélectionner
=EQUIV("Nombre";INDIRECT(MIN(SI(Incendie.A4:Z33="Nombre";LIGNE(Incendie.A4:Z33)))&":"&MIN(SI(Incendie.A4:Z33="Nombre";LIGNE(Incendie.A4:Z33))));0)
encore et toujours l’erreur #ND
On teste le retour de la matrice donnée à EQUIV :
Code : Tout sélectionner
=MIN(SI(Incendie.A4:Z33="Nombre";LIGNE(Incendie.A4:Z33)))&":"&MIN(SI(Incendie.A4:Z33="Nombre";LIGNE(Incendie.A4:Z33)))
Et là, tu vois que le résultat est
8:8
Tu demande donc à EQUIV de chercher sur l’intégralité de la ligne 8 (car l'exemple concerne la cellule Incendie.D8) de la feuille courante, d’où l’erreur.
En plus d’indiquer le nom de la feuille, on peut également "borner" de la colonne A jusqu’à Z, la matrice de EQUIV devient :
Code : Tout sélectionner
=INDIRECT("Incendie.A"&MIN(SI(Incendie.A7:Z36="Nombre";LIGNE(Incendie.A7:Z36)))&":Z"&MIN(SI(Incendie.A7:Z36="Nombre";LIGNE(Incendie.A7:Z36))))
Je te laisse reconstruire la formule
Vous ne pouvez pas consulter les pièces jointes insérées à ce message.