[Résolu]Recherche une valeur dans plusieurs tableaux

[kylejake]

Bonjour
Des jours de recherche sur les forum sans trouver la solution qui fonctionne.
J'ai fais plusieurs essais dans "essai formule" aucune ne fonctionne car elles sont fausses ou des erreurs de transcription.

J'ai plusieurs petits tableaux avec des résultats.
Je veux retrouver la valeur exacte correspondante pour l'inscrire dans un autre tableau.
Par exemple je recherche la valeur de "NED" dans les 3 tableaux.

Merci pour votre aide

Kylejake

[yclik]

Bonjour
si limité à 3 tableaux

Code : Tout sélectionner

=SI(ESTERREUR(RECHERCHEV(Q5;$A$5:$D$7;4;0));SI(ESTERREUR(RECHERCHEV(Q5;$F$5:$I$7;4;0));SI(ESTERREUR(RECHERCHEV(Q5;$K$5:$N$7;4;0));"";RECHERCHEV(Q5;$K$5:$N$7;4;0));RECHERCHEV(Q5;$F$5:$I$7;4;0));RECHERCHEV(Q5;$A$5:$D$7;4;0))

attention certains espace en trop comme "FRA "

cela serait plus simple avec RECHERCHEV d'avoir les tableaux l'un en dessous de l'autre, quitte à les recopier avec liaison sur un autre onglet.

[Jeff]

Bonjour à tous,

Un peu plus court mais plus complexe, en B23 :

Code : Tout sélectionner

=RECHERCHEV(A23;DECALER($A$1;MAX(LIGNE(A5:N7)*(A5:N7=$A$23))-1;MAX(COLONNE(A5:N7)*(A5:N7=$A$23))-1;;4);4)

À valider matriciellement pat Ctrl + Maj + Entrer

La plage est fabriquée avec DECALER (voir tuto)

Ce qui donne pour R5 :

Code : Tout sélectionner

=RECHERCHEV(Q5;DECALER($A$1;MAX(LIGNE($A$5:$N$7)*($A$5:$N$7=Q5))-1;MAX(COLONNE($A$5:$N$7)*($A$5:$N$7=Q5))-1;;4);4;0)

À valider par Ctrl + Maj + Entrer, à étirer vers le bas en pressant CTRL

Capture d’écran du 2020-01-28 12-51-21.png

Pas-à-pas fourni dans le fichier joint

attention certains espace en trop comme "FRA "

ou "ENG "


A +

[gerard24]

Bonjour,

La recherche portant sur une valeur unique,
et
la valeur a retourner étant numérique,

on peut détourner la fonction SOMME.SI de son but initial :

Code : Tout sélectionner

=SOMME.SI($A$5:$K$7;Q5;$D$5:$N$7)

*noter le décalage en colonnes des plages critère et somme.

A+

[Jeff]

on peut détourner la fonction SOMME.SI

Ou adapter à SOMMEPROD :

Code : Tout sélectionner

=SOMMEPROD($A$5:$K$7=Q5;$D$5:$N$7)

Avec le même décalage en colonnes des plages critère et somme

[kylejake]

Bonjour, Yclik,Jeff,Gérard 24

Merci de vos interventions.

Il y aura au maximum 12 petit tableaux + 1 récapitulatif.
Je pense qu'il y aura 4 tableaux en horizontal et 3 en vertical avec des espaces d' une colonne et une ligne
Je ne sais pas encore si le récap se fera sur la même feuille ou sur une autre

Sur la formule de Yclik et Gérard 24, tout serait OK sauf pour ENG et FRA, je ne sais pas pourquoi !
Sur la formule de Jeff, dans ma retranscription ,recopier ou copier/coller, la valeur n’apparaît pas ou ### ou la formule (= recherchev.....), là aussi je ne ais pas pourquoi !

Merci

[Jeff]

tout serait OK sauf pour ENG et FRA, je ne sais pas pourquoi !

Parce que tu lis en diagonale les réponses qui te sont faites

[kylejake]

J'ai effacé ENG et FRA, puis formater la cellule, et tout fonctionne à merveille.
Sauf la formule de Jeff, peut être un problème de format !
Tout est OK pour moi encore merci à tout les trois.

Cordialement

Kylejake