[Résolu] Utilisation de nb.si et ajout d'une condition.

[antoine076]

Bonjour,

Je dois faire une synthèse statistique de différentes feuilles (une par mois) contenant des tableaux.
Chaque feuille est relative à un mois et comporte 3 colonnes:
1ere colonne: 2 valeurs possibles achat/vente
2ème colonne: 2 valeurs possibles comptant/crédit
3ème colonne: un montant en €

Habituellement j'utilise la fonction nb.si pour faire des statistiques globales (nombre de ventes, nombre d'achat, etc...) [par ex =NB.SI('092018'.$a$2:'092018'.$a$365;"vente")]
J'aimerais trouver une formule appliquée à la feuille entière pour déterminer le nombre de ventes à crédit, le nombre de ventes comptant, le nombre d'achats à crédit, le nombre d' achats comptant.
une formule du genre pour les ventes à crédit:
si la case de la 1ere colonne indique une vente alors calculer le nombre de case contenant crédit dans la 2ème colonne.
ça semble simple mais je coince en utilisant nb.si ...

Merci pour votre aide en espérant avoir été suffisamment clair.

[micmac]

Bonjour et bienvenue,


Comment joindre un fichier au format ODF
Veillez également à dépersonnaliser votre fichier.
Donnez un nom clair à ce fichier. Evitez "essai", "test" et autres dont nos tiroirs débordent...

[OOotremer971]

Bonjour,

Tu peux orienter tes recherches vers la fonction NB.SI.ENS() :

Fonction NB.SI.ENS

Renvoie le nombre de cellules qui correspond aux critères dans des plages multiples.
Syntaxe

Code : Tout sélectionner

NB.SI.ENS(plage_1;critère_1[;plage2;critère2[;...]])

plage_1 - argument requis. C'est une plage de cellules, un nom d'une plage nommée ou une étiquette d'une colonne ou d'une ligne contenant les valeurs pour compter et rechercher le critère correspondant.

Critère1 - argument requis. Une expression de chaîne représentant une condition logique ou une référence de cellule à une telle expression de chaîne. L'expression peut contenir du texte, des nombres, des expressions régulières ou des caractères génériques ( si activé dans les options de calcul).

Plage2 – Facultatif. Plage2 et tous les arguments suivants ont la même signification que Plage1.

critère2 – facultatif. Critère2 et tous les autres ont la même signification que critère1.

[njhub]

Bonjour antoine076,

essayez avec les formules suivantes dans des cellules différentes, par exemple

En D1

Code : Tout sélectionner

=NB.SI.ENS('092018'.$A$2:'092018'.$A$365;"vente";'092018'.$B$2:'092018'.$B$365;"comptant")&" ventes comptant"

En D2

Code : Tout sélectionner

=NB.SI.ENS('092018'.$A$2:'092018'.$A$365;"achat";'092018'.$B$2:'092018'.$B$365;"comptant")&" achats comptant"

En D3

Code : Tout sélectionner

=NB.SI.ENS('092018'.$A$2:'092018'.$A$365;"vente";'092018'.$B$2:'092018'.$B$365;"crédit")&" ventes crédit"

En D4

Code : Tout sélectionner

=NB.SI.ENS('092018'.$A$2:'092018'.$A$365;"achat";'092018'.$B$2:'092018'.$B$365;"crédit")&" achats crédit"

[antoine076]

Merci à vous deux pour les réponses.
J'ai opté pour la solution de njhub et ça marche parfaitement!