[Résolu] Retrouver une valeur a partir d'une colonne

Discussions à propos du tableur Calc.
Les questions sur les macros doivent être postées dans la section dédiée en dessous.

Modérateur: Vilains modOOs

Règles du forum
Cette section est uniquement dédiée au tableur Calc. Vous ne devez pas poster ici de questions sur les macros mais utiliser la section éponyme.

[Résolu] Retrouver une valeur a partir d'une colonne

Messagepar Pristio » 27 Mai 2019 18:16

Bonjour,

Ne sachant pas comment expliquer correctement, je vous fais par du tableau, ainsi qu'une capture pour imager les explications :D

Mon problème :
Je cherche une fonction, me permettant de placer dans la colonne C, la valeur de la cellule J, ou la cellule E (de la même ligne de J) est équivalent à la cellule A (de la même ligne de C).

Mes recherches :
J'ai regardé un peu, j'ai trouvé quelques pistes, comme le fait d'utiliser RECHERCHEV avec les matrices, mais je ne comprends pas comment utiliser correctement cette fonction (ni si c'est ma bonne fonction pour faire ça)


Je ne suis pas très doué niveau explication dans le style des tableurs :/ n'hésitez pas à me demander si besoin de suppléments.

Pouvez-vous m'aider sur la façon de procéder afin de réussir à récupérer les valeurs ?

Je vous remercie.
Capture.PNG
Pièces jointes
Recherche par colonne.ods
(10.38 Kio) Téléchargé 17 fois
Dernière édition par Pristio le 27 Mai 2019 22:43, édité 4 fois.
LibreOffice 6.2.4.2 (x64) - Windows 10
Pristio
Fraîchement OOthentifié
 
Message(s) : 5
Inscrit le : 27 Mai 2019 17:59

Re: Retrouver une valeur a partir d'une colonne

Messagepar micmac » 27 Mai 2019 18:18

Bonjour et bienvenue,

Plutôt qu'une copie écran où les en-têtes de lignes et colonnes sont invisibles, fournissez à la place un fichier complet. Cela augmentera vos chances de réponse en évitant d'avoir à jouer aux devinettes.
Donnez un nom clair à ce fichier. Evitez "essai", "test" et autres "sans nom" dont nos tiroirs débordent....
Avatar de l’utilisateur
micmac
RespOOnsable forum
RespOOnsable forum
 
Message(s) : 6032
Inscrit le : 28 Août 2010 09:45

Re: Retrouver une valeur a partir d'une colonne

Messagepar Pristio » 27 Mai 2019 18:30

Je n'ai pas vu que j'avais caché les noms de ligne et colonne désolé. J'ai édité le message. Merci :)

EDIT :
J'ai trouvé une partie de la solution avec la formule :

Code : Tout sélectionner   AgrandirRéduire
=INDEX($J$1:$J$12;EQUIV(A1;$E$1:$E$12))


Par contre, j'ai tout de même un problème, car sur certaines lignes, il me met "#N/D", alors que je suis sensé avoir une valeur. Mais d'autres, pour la même formule, me donnent exactement ce que je veux
LibreOffice 6.2.4.2 (x64) - Windows 10
Pristio
Fraîchement OOthentifié
 
Message(s) : 5
Inscrit le : 27 Mai 2019 17:59

Re: Retrouver une valeur a partir d'une colonne

Messagepar Jean-Louis Cadeillan » 27 Mai 2019 20:56

Bonsoir,
Le couple INDEX(EQUIV()) est une bonne solution, précise juste le troisième argument de EQUIV à 0 (correspondance exacte) :
Code : Tout sélectionner   AgrandirRéduire
=INDEX($J$1:$J$12;EQUIV(A1;$E$1:$E$12;0))
Tu auras encore #N/D, mais uniquement quand ta recherche par EQUIV() porte sur une valeur dans la colonne E qui n'existe pas (par exemple 0). Pour ce contrôle d'erreur, tu peux fignoler en mettant :
Code : Tout sélectionner   AgrandirRéduire
=SI(ESTNA(EQUIV(A1;$E$1:$E$12;0));"";INDEX($J$1:$J$12;EQUIV(A1;$E$1:$E$12;0)))
ou encore (sous LibO) :
Code : Tout sélectionner   AgrandirRéduire
=SIERREUR(INDEX($J$1:$J$12;EQUIV(A1;$E$1:$E$12;0));"")

Sinon, tu pouvais utiliser la fonction RECHERCHEV() (toujours en C1) :
Code : Tout sélectionner   AgrandirRéduire
=RECHERCHEV(A1;$E$1:$J$12;6;0)
6 indiquant la 6ème colonne de la matrice $E$1:$J$12 qui contient la valeur à retourner. Le dernier argument, 0, correspond aussi à une recherche sur valeur exacte, comme pour EQUIV() (voir aide intégrée F1). Comme pour INDEX(EQUIV()), tu peux aussi contrôler les erreurs, soit par :
Code : Tout sélectionner   AgrandirRéduire
=SI(ESTNA(RECHERCHEV(A1;$E$1:$J$12;6;0));"";RECHERCHEV(A1;$E$1:$J$12;6;0))
soit par :
Code : Tout sélectionner   AgrandirRéduire
=SIERREUR(RECHERCHEV(A1;$E$1:$J$12;6;0);"")
Cordialement,
Jean-Louis
LibO 6.2.6.2 (x64 avec Java 1.8.0_221) et AOO 4.1.6 (avec Java x32 1.8.0_201), Windows 7 Édition Intégrale 64 SP1, (Domicile)
LibO 5.4.1.2 (x86) sous Ubuntu LTS 16.04.1, noyau 4.4.0-93 et Xfce 4.12, Java (x86) 1.8.0_131 (Travail) [obligation de version]
Avatar de l’utilisateur
Jean-Louis Cadeillan
ManitOOu
ManitOOu
 
Message(s) : 4443
Inscrit le : 03 Jan 2009 00:56

Re: Retrouver une valeur a partir d'une colonne

Messagepar Pristio » 27 Mai 2019 22:43

Un réponse complète :) merci à toi. ça marche très bien.
LibreOffice 6.2.4.2 (x64) - Windows 10
Pristio
Fraîchement OOthentifié
 
Message(s) : 5
Inscrit le : 27 Mai 2019 17:59


Retour vers Tableur

Qui est en ligne ?

Utilisateur(s) parcourant ce forum : Aucun utilisateur inscrit et 44 invité(s)