[Résolu] Impossible d'ouvrir un XML : Erreur générale d'E/S

[Panzenlair]

Bonjour,

Je viens d'installer la dernière version d'OpenOffice (v 4.1.6) et il m'est impossible d'ouvrir le fichier dont le détail est ci-dessous.
OpenOffice m'envoie une erreur "Erreur générale d'E/S" alors que l'ouverture du même fichier dans Excel ne pose aucun problème.

Auriez-vous, s'il vous plait, une solution à me proposer?

<?xml version="1.0"?>
<payments>
<payment>
<purpose>CD</purpose>
<amount>12.95</amount>
<tax>19.1234</tax>
<maturity>2008-03-01</maturity>
</payment>
<payment>
<purpose>DVD</purpose>
<amount>19.95</amount>
<tax>19.4321</tax>
<maturity>2008-03-02</maturity>
</payment>
<payment>
<purpose>Clothes</purpose>
<amount>99.95</amount>
<tax>18.5678</tax>
<maturity>2008-03-03</maturity>
</payment>
<payment>
<purpose>Book</purpose>
<amount>9.49</amount>
<tax>18.9876</tax>
<maturity>2008-03-04</maturity>
</payment>
</payments>

[tintin]

Bonjour et bienvenue,

En préliminaire :
Si vous avez parcouru le forum avant de poser votre question vous n'avez pas pu manquer cette information : OpenOffice et LibreOffice ne sont pas de clones de MS Office.
Je vous invite à lire attentivement et appliquer les Conseils : Utilisation de Writer / Word applicables pour Calc / Excel.

Le document .doc (ou .xls), une fois ouvert par AOO ou LibO, il faut impérativement

1. l'Enregistrer sous immédiatement au format natif soit .odt (ou .ods),
2. le fermer (par sa croix de fermeture).
3. Puis ouvrir le document .odt (ou .ods) correspondant qui a été créé,
   s'il doit être modifié et travaillé.[/size]
4. Enregistrer les modifications sous ce format
5. C'est seulement après qu'il est possible de l'enregistrer sous un autre format (.doc ou .xls)

[Panzenlair]

Bonjour,

Je vous remercie pour votre réponse mais le fichier dont je vous ai présenté le détail ci-dessus est une simple fichier texte (plat) qui ne provient ni de Word, ni d'Excel. je l'ai simplement créé avec une extension xml.

[jeanmimi]

Bonjour,

Auriez-vous, s'il vous plait, une solution à me proposer?

Joindre le fichier .fodt pour le tester?

[Panzenlair]

J'ai pris mon fichier .xml contenant les informations ci-dessus, je l'ai renommé en .fodt mais je n'arrive toujours pas à l'ouvrir dans calc
Les règles de ce forum ne m'autorisent pas joindre le fichier à mon message

[jeanmimi]

le fichier dont je vous ai présenté le détail ci-dessus est une simple fichier texte (plat)

Un fichier .fodt s'ouvre plutôt avec Texte dans ma configuration, pas avec Calc.

Les règles de ce forum ne m'autorisent pas joindre le fichier à mon message

Dans cecas, il faut zipper le fichier car le forum accepte les fichiers.zip

[Panzenlair]

Désolé mais le fichier ne s'ouvre ni avec texte ni avec calc.

Je vous remercie pour votre aide mais je remarque que je suis dans une impasse. Je vais donc continuer à utiliser Excel et Word qui tous deux ouvrent facilement mon fichier txt plat.

[jeanmimi]

Je vais donc continuer à utiliser Excel et Word qui tous deux ouvrent facilement mon fichier txt

Vous avez raison et d'ailleurs je n'avais pas compris pourquoi changer de logiciel si vous êtes satisfait de ceux que vous utilisez.

[micmac]

Bonjour,

Il vous reste à cocher l'icône et ajouter manuellement au début du titre de votre premier message la balise [Résolu] (avec un R majuscule et sans oublier le e accentué, le tout entre crochets).

[Panzenlair]

Sauf que mon problème avec OpenOffice n'a pas été résolu

[micmac]

Pour moi, cet qui est écrit

Je vais donc continuer à utiliser Excel et Word qui tous deux ouvrent facilement mon fichier txt plat

signifie que votre parti est pris et donc que le sujet est clos.

[Panzenlair]

Sujet clos

[micmac]

Bis repetita.
Quand un problème est résolu il est d'usage de cocher l'icône et d'ajouter manuellement au début du titre de votre premier message la balise [Résolu] (avec un R majuscule et sans oublier le e accentué, le tout entre crochets).



Cordialement

[Dude]

Est-ce que tu t'es donné la peine d'installer les filtres XSLT ?

[Panzenlair]

Bonjour,
Je me suis effectivement donné la peine de suivre scrupuleusement ce qui est marqué sur la page https://wiki.openoffice.org/wiki/Docume ... ML_ou_XSLT

[Dude]

La documentation est réalisée bénévolement.
La page que tu cites est avec un statut "Projet".
Sa source est indiquée au début.
Si tu l'as suivie et qu'il y a des erreurs rencontrées, je t'invite à l'enrichir en ce sens.

[Jeff]

Bonjour à tous,

Je me suis effectivement donné la peine de suivre scrupuleusement ce qui est marqué sur la page https://wiki.openoffice.org/wiki/Docume ... ML_ou_XSLT

Dans ce sujet, il est stipulé :

(Cette page est la traduction du fil Create XSLT filters for import and export dans le forum anglais Apache OpenOffice)

Dans le fil d’origine :

The XSLT import filter looks mostly like the original one. So let's focus on the crucial difference. For changing the handling of "purpose" I changed this lines:

Traduction automatique :

Le filtre d'importation XSLT ressemble le plus souvent au filtre d'origine. Alors concentrons-nous sur la différence cruciale. Pour changer le traitement de "purpose", j'ai modifié les lignes suivantes (...)

Ce qui donne le filtre d’import suivant (copie du code de hol.sten sur le forum En) :

Code : Tout sélectionner

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
  <office:document-content xmlns:office="urn:oasis:names:tc:opendocument:xmlns:office:1.0" xmlns:style="urn:oasis:names:tc:opendocument:xmlns:style:1.0" xmlns:text="urn:oasis:names:tc:opendocument:xmlns:text:1.0" xmlns:table="urn:oasis:names:tc:opendocument:xmlns:table:1.0" xmlns:draw="urn:oasis:names:tc:opendocument:xmlns:drawing:1.0" xmlns:fo="urn:oasis:names:tc:opendocument:xmlns:xsl-fo-compatible:1.0" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:dc="http://purl.org/dc/elements/1.1/" xmlns:meta="urn:oasis:names:tc:opendocument:xmlns:meta:1.0" xmlns:number="urn:oasis:names:tc:opendocument:xmlns:datastyle:1.0" xmlns:svg="urn:oasis:names:tc:opendocument:xmlns:svg-compatible:1.0" xmlns:chart="urn:oasis:names:tc:opendocument:xmlns:chart:1.0" xmlns:dr3d="urn:oasis:names:tc:opendocument:xmlns:dr3d:1.0" xmlns:math="http://www.w3.org/1998/Math/MathML" xmlns:form="urn:oasis:names:tc:opendocument:xmlns:form:1.0" xmlns:script="urn:oasis:names:tc:opendocument:xmlns:script:1.0" xmlns:ooo="http://openoffice.org/2004/office" xmlns:ooow="http://openoffice.org/2004/writer" xmlns:oooc="http://openoffice.org/2004/calc" xmlns:dom="http://www.w3.org/2001/xml-events" xmlns:xforms="http://www.w3.org/2002/xforms" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" office:version="1.0">

   <office:automatic-styles>

    <!-- Column styles (co1: column with 6 cm width, co1: column with 3 cm width) -->
    <style:style style:name="co1" style:family="table-column">
     <style:table-column-properties fo:break-before="auto" style:column-width="6.000cm"/>
    </style:style>
    <style:style style:name="co2" style:family="table-column">
     <style:table-column-properties fo:break-before="auto" style:column-width="3.000cm"/>
    </style:style>

    <!-- Number format styles (N36: date with DD.MM.YYYY, N107: float with 0,0000) -->
    <number:date-style style:name="N36" number:automatic-order="true">
     <number:day number:style="long"/>
     <number:text>.</number:text>
     <number:month number:style="long"/>
     <number:text>.</number:text>
     <number:year number:style="long"/>
    </number:date-style>
    <number:number-style style:name="N107">
     <number:number number:decimal-places="4" number:min-integer-digits="1"/>
    </number:number-style>

    <!-- Cell styles (ce1: right aligned, ce2: float with 4 decimal places, ce3: date) -->
    <style:style style:name="ce1" style:family="table-cell" style:parent-style-name="Default">
     <style:table-cell-properties style:text-align-source="fix" style:repeat-content="false"/>
     <style:paragraph-properties fo:text-align="end"/>
    </style:style>
    <style:style style:name="ce2" style:family="table-cell" style:parent-style-name="Default" style:data-style-name="N107"/>
    <style:style style:name="ce3" style:family="table-cell" style:parent-style-name="Default" style:data-style-name="N36"/>

   </office:automatic-styles>

   <office:body>
    <office:spreadsheet>
     <table:table>

      <!-- Format the first 4 columns of the table -->
      <table:table-column table:style-name="co1" table:default-cell-style-name="Default"/>
      <table:table-column table:style-name="co2" table:default-cell-style-name="Default"/>
      <table:table-column table:style-name="co2" table:default-cell-style-name="ce2"/>
      <table:table-column table:style-name="co2" table:default-cell-style-name="ce3"/>

      <!-- Insert column labels, first label with default style, the remaining 3 labels right aligned -->
      <table:table-row>
       <table:table-cell><text:p>Purpose</text:p></table:table-cell>
       <table:table-cell table:style-name="ce1" office:value-type="string"><text:p>Amount</text:p></table:table-cell>
       <table:table-cell table:style-name="ce1" office:value-type="string"><text:p>Tax</text:p></table:table-cell>
       <table:table-cell table:style-name="ce1" office:value-type="string"><text:p>Maturity</text:p></table:table-cell>
      </table:table-row>

      <!-- Process XML input: Insert one row for each payment -->
      <xsl:for-each select="payments/payment">
       <table:table-row>

        <!-- Insert string payment purpose -->
        <xsl:choose>
         <xsl:when test="@purpose">
          <table:table-cell>
           <text:p><xsl:value-of select="@purpose"/></text:p>
          </table:table-cell>
         </xsl:when>
         <xsl:when test="purpose">
          <table:table-cell>
           <text:p><xsl:value-of select="purpose"/></text:p>
          </table:table-cell>
         </xsl:when>
         <xsl:otherwise>
          <table:table-cell>
           <text:p/>
          </table:table-cell>
         </xsl:otherwise>
        </xsl:choose>

        <!-- Insert float payment amount -->
        <xsl:choose>
         <xsl:when test="@amount">
          <table:table-cell office:value-type="float">
           <xsl:attribute name="office:value"><xsl:value-of select="@amount"/></xsl:attribute>
           <text:p><xsl:value-of select="@amount"/></text:p>
          </table:table-cell>
         </xsl:when>
         <xsl:when test="amount">
          <table:table-cell office:value-type="float">
           <xsl:attribute name="office:value"><xsl:value-of select="amount"/></xsl:attribute>
           <text:p><xsl:value-of select="amount"/></text:p>
          </table:table-cell>
         </xsl:when>
         <xsl:otherwise>
          <table:table-cell>
           <text:p/>
          </table:table-cell>
         </xsl:otherwise>
        </xsl:choose>

        <!-- Insert float payment tax -->
        <xsl:choose>
         <xsl:when test="@tax">
          <table:table-cell office:value-type="float">
           <xsl:attribute name="office:value"><xsl:value-of select="@tax"/></xsl:attribute>
           <text:p><xsl:value-of select="@tax"/></text:p>
          </table:table-cell>
         </xsl:when>
         <xsl:when test="tax">
          <table:table-cell office:value-type="float">
           <xsl:attribute name="office:value"><xsl:value-of select="tax"/></xsl:attribute>
           <text:p><xsl:value-of select="tax"/></text:p>
          </table:table-cell>
         </xsl:when>
         <xsl:otherwise>
          <table:table-cell>
           <text:p/>
          </table:table-cell>
         </xsl:otherwise>
        </xsl:choose>

        <!-- Insert date payment maturity -->
        <xsl:choose>
         <xsl:when test="@maturity">
          <table:table-cell office:value-type="date">
           <xsl:attribute name="office:date-value"><xsl:value-of select="@maturity"/></xsl:attribute>
           <text:p><xsl:value-of select="@maturity"/></text:p>
          </table:table-cell>
         </xsl:when>
         <xsl:when test="maturity">
          <table:table-cell office:value-type="date">
           <xsl:attribute name="office:date-value"><xsl:value-of select="maturity"/></xsl:attribute>
           <text:p><xsl:value-of select="maturity"/></text:p>
          </table:table-cell>
         </xsl:when>
         <xsl:otherwise>
          <table:table-cell>
           <text:p/>
          </table:table-cell>
         </xsl:otherwise>
        </xsl:choose>

       </table:table-row>
      </xsl:for-each>
     </table:table>
    </office:spreadsheet>
   </office:body>
  </office:document-content>
</xsl:template>
</xsl:stylesheet>

Qui fonctionne :

AOO_forum.png

A +