[Résolu] Calcul points foot, en fonction du résultat

Discussions à propos du tableur Calc.
Les questions sur les macros doivent être postées dans la section dédiée en dessous.

Modérateur: Vilains modOOs

Règles du forum
Cette section est uniquement dédiée au tableur Calc. Vous ne devez pas poster ici de questions sur les macros mais utiliser la section éponyme.

[Résolu] Calcul points foot, en fonction du résultat

Messagepar Monox » 26 Juil 2018 17:06

Bonjour à tous,

Je suis en galère pour me faciliter la vie ...

J'ai un tableau, référençant tous les matchs de mes équipes.
J'aimerais que quand je rentre mes résultats, un résultat me calcul automatiquement le nombre de point total.

Voici un exemple de mon tableau :
Sans titre.png
Sans titre.png (7.57 Kio) Consulté 125 fois


Donc j'aimerais que D2 = 0points, E2=1points, F2 = 3 points

Le tout serait additionné dans ma cellule O2. Qui est actuellement remplie manuellement.

Merci d'avance, en espérant avoir posté dans la bonne rubrique ...
Monox
Dernière édition par Monox le 26 Juil 2018 23:27, édité 1 fois.
OpenOffice 4.1.4 sous Windows 10
Monox
Fraîchement OOthentifié
 
Message(s) : 4
Inscrit le : 26 Juil 2018 16:17

Re: Calcul points foot, en fonction du résultat

Messagepar micmac » 26 Juil 2018 19:00

Bonjour,

Image
Comment joindre un fichier au format ODF
Veillez également à dépersonnaliser votre fichier.
Donnez un nom clair à ce fichier. Evitez "essai", "test" et autres dont nos tiroirs débordent...
Avatar de l’utilisateur
micmac
RespOOnsable forum
RespOOnsable forum
 
Message(s) : 5256
Inscrit le : 28 Août 2010 09:45

Re: Calcul points foot, en fonction du résultat

Messagepar Monox » 26 Juil 2018 19:26

Voilà !
Pièces jointes
Tableau de gestion LV.ods
(25.23 Kio) Téléchargé 7 fois
OpenOffice 4.1.4 sous Windows 10
Monox
Fraîchement OOthentifié
 
Message(s) : 4
Inscrit le : 26 Juil 2018 16:17

Re: Calcul points foot, en fonction du résultat

Messagepar Jean-Louis Cadeillan » 26 Juil 2018 20:31

Bonsoir,
Si je suppose qu'il n'y a pas plus de 9 buts marqués pour une équipe dans un match, on peut proposer la formule suivante, matricielle, en O44 :
Code : Tout sélectionner   AgrandirRéduire
=SOMME(SI(GAUCHE(D44:M44)>DROITE(D44:M44);3;SI(GAUCHE(D44:M44)=DROITE(D44:M44);1;0)))
validée par Maj+Ctrl+Entrée
Dans le fichier joint, j'ai mis une formule de simulation de match de D44 à M44 pour vérifier la formule... ce qui fait beaucoup de buts :mrgreen: ... pour changer les matchs, Maj+Ctrl+F9...
 Ajout : Pour un cas plus général quel que soit le nombre de buts, on pourrait utiliser cette formule :
Code : Tout sélectionner   AgrandirRéduire
=SOMME(SI(CNUM(STXT(D44:M44;1;TROUVE("-";D44:M44)-1))>CNUM(DROITE(D44:M44;NBCAR(D44:M44)-TROUVE("-";D44:M44)));3;SI(CNUM(STXT(D44:M44;1;TROUVE("-";D44:M44)-1))=CNUM(DROITE(D44:M44;NBCAR(D44:M44)-TROUVE("-";D44:M44)));1;0)))
formule matricielle validée aussi par Maj+Ctrl+Entrée 

Cordialement,
Jean-Louis
Pièces jointes
Monox_20180726_JLC01.ods
(29.93 Kio) Téléchargé 6 fois
LibreOffice 6.1.1.2 (x64) et Apache OpenOffice 4.1.5, Windows 7 Édition Intégrale 64 SP1, Java (x64) 1.8.0_181 (Domicile)
LibreOffice 5.4.1.2 (x86) sous Linux Karoshi 5.0 (Ubuntu LTS 16.04.1, noyau 4.4.0-93) et Xfce 4.12, Java (x86) 1.8.0_131 (Travail)
Avatar de l’utilisateur
Jean-Louis Cadeillan
ManitOOu
ManitOOu
 
Message(s) : 3872
Inscrit le : 03 Jan 2009 00:56

Re: Calcul points foot, en fonction du résultat

Messagepar Monox » 26 Juil 2018 21:53

J'ai essayé ... Sans succès, ca me donne une valeur erronée. Pourtant sur ton document, tout fonctionne parfaitement ! Il y a aucun paramétrage à faire pour appliquer ce genre de formules ?

Je vais voir ça demain, plus à tête reposée...

Merci en tout cas !
OpenOffice 4.1.4 sous Windows 10
Monox
Fraîchement OOthentifié
 
Message(s) : 4
Inscrit le : 26 Juil 2018 16:17

Re: Calcul points foot, en fonction du résultat

Messagepar Jean-Louis Cadeillan » 26 Juil 2018 22:33

Monox a écrit:ça me donne une valeur erronée
sans doute parce que bêtement :oops: je n'avais pas testé le cas où certains matches n'ont pas encore eu lieu (quand la cellule du score est vide) : mes formules traitaient ce cas comme un match nul.
Voici le correctif :
Formule 1 en O4:
Code : Tout sélectionner   AgrandirRéduire
=SOMME(SI(D4:M4="";0;SI(GAUCHE(D4:M4)>DROITE(D4:M4);3;SI(GAUCHE(D4:M4)=DROITE(D4:M4);1;0))))
Comme tu peux le voir, on rajoute un test SI(D4:M4="";0; lorsque la cellule est vide.
Formule 2 en O5:
Code : Tout sélectionner   AgrandirRéduire
=SOMME(SI(D4:M4="";0;SI(CNUM(STXT(D4:M4;1;TROUVE("-";D4:M4)-1))>CNUM(DROITE(D4:M4;NBCAR(D4:M4)-TROUVE("-";D4:M4)));3;SI(CNUM(STXT(D4:M4;1;TROUVE("-";D4:M4)-1))=CNUM(DROITE(D4:M4;NBCAR(D4:M4)-TROUVE("-";D4:M4)));1;0))))
même ajout au début de la formule.
Les deux formules donnent le même total de points tant qu'une équipe de marque pas plus de 9 buts, après seule la formule 2 est juste. Il te faudra choisir l'une ou l'autre car pour l'instant, bien sûr, le total des points de la Légion Viking est doublé (vu qu'il y a deux formules par série de matches).
Voir ci-joint,
Cordialement,
Jean-Louis
Pièces jointes
Monox_20180726_JLC02.ods
(29.52 Kio) Téléchargé 5 fois
LibreOffice 6.1.1.2 (x64) et Apache OpenOffice 4.1.5, Windows 7 Édition Intégrale 64 SP1, Java (x64) 1.8.0_181 (Domicile)
LibreOffice 5.4.1.2 (x86) sous Linux Karoshi 5.0 (Ubuntu LTS 16.04.1, noyau 4.4.0-93) et Xfce 4.12, Java (x86) 1.8.0_131 (Travail)
Avatar de l’utilisateur
Jean-Louis Cadeillan
ManitOOu
ManitOOu
 
Message(s) : 3872
Inscrit le : 03 Jan 2009 00:56

Re: Calcul points foot, en fonction du résultat

Messagepar Monox » 26 Juil 2018 23:26

Je te remercie grandement Jean-Louis !

Mon problème est donc résolu :)

Manque plus qu'à trouver comment trier mes lignes à ma convenance, en continuant de les coupler par deux ^^

Merci beaucoup en tout cas !!
OpenOffice 4.1.4 sous Windows 10
Monox
Fraîchement OOthentifié
 
Message(s) : 4
Inscrit le : 26 Juil 2018 16:17


Retour vers Tableur

Qui est en ligne ?

Utilisateur(s) parcourant ce forum : Google [Bot], ledébutant et 11 invité(s)