[Résolu] NB.SI / Recherche de plusieurs critères sur une...

Discussions à propos du tableur Calc.
Les questions sur les macros doivent être postées dans la section dédiée en dessous.

Modérateur : Vilains modOOs

Règles du forum
Cette section est uniquement dédiée au tableur Calc. Vous ne devez pas poster ici de questions sur les macros mais utiliser la section éponyme.
Avatar de l’utilisateur
Fredox
Membre OOrganisé
Membre OOrganisé
Messages : 83
Inscription : 28 oct. 2006 15:55

[Résolu] NB.SI / Recherche de plusieurs critères sur une...

Message par Fredox »

Bonjour,
J'aimerai savoir si il est possible de faire une recherche avec le fonction NB.SI afin de compter plusieurs critères differents sur une seule plage ?

Ainsi sur ma plage A1:F1, j'aimerais savoir combien de fois sont écris "Moi" ou "Toi" cumulés sans distinction.

Comme:

Code : Tout sélectionner

=NB.SI(A1:F1;"Moi" ou "Toi")
C'est possible ? Merci
Dernière modification par micmac le 15 nov. 2011 23:41, modifié 2 fois.
Raison : [Résolu] doit être accompagné de la coche
Open Office 3.3.0 sous Windows 7
Continu de bricoler sous Calc (mais en net progrès)
Avatar de l’utilisateur
Jean-Louis Cadeillan
GourOOu
GourOOu
Messages : 5732
Inscription : 03 janv. 2009 00:56

Re: NB.SI / Recherche de plusieurs critères sur une seule pl

Message par Jean-Louis Cadeillan »

Bonsoir,
Oui, on peut utiliser NB.SI() en matriciel (valider par Ctrl+Maj+Entrée) :

Code : Tout sélectionner

=NB.SI((A1:F1="Moi")+(A1:F1="Toi");1)
Remarque : dans le fichier joint, de A1 à F1, les formules ne sont là que pour faire varier aléatoirement les Moi et les Toi (Ctrl+Maj+F9 pour relancer)
Cordialement
Jean-Louis
Pièces jointes
Fredox_01.ods
NB.SI () multicritères
(7.76 Kio) Téléchargé 588 fois
LibO 7.6.5.2 (x64 avec Java 1.8.0_401) et AOO 4.1.15 (avec Java x32 1.8.0_381), Windows 7 Édition Intégrale 64 SP1
Avatar de l’utilisateur
Fredox
Membre OOrganisé
Membre OOrganisé
Messages : 83
Inscription : 28 oct. 2006 15:55

Re: NB.SI / Recherche de plusieurs critères sur une seule pl

Message par Fredox »

Merci Jean-Louis, en fait j'avais déja mis en pratique cette solution (j'ai oublier de le préciser).
En fait je voulais savoir si il y avait un moyen plus simple qui constiste à ne pas ressaisir à chaques fois la zone de recherche car sur ma formule j'aurais 15 textes differents à chercher pour la meme plage de recherche.

Mais sinon c'est bien ca quand meme.
Open Office 3.3.0 sous Windows 7
Continu de bricoler sous Calc (mais en net progrès)
Avatar de l’utilisateur
Jean-Louis Cadeillan
GourOOu
GourOOu
Messages : 5732
Inscription : 03 janv. 2009 00:56

Re: [Résolu] NB.SI / Recherche de plusieurs critères sur une

Message par Jean-Louis Cadeillan »

A ce moment-là, mets tes textes à rechercher dans une plage, nommée par exemple MesTextes et utilise SOMMEPROD() :

Code : Tout sélectionner

=SOMMEPROD(A1:F1=MesTextes)
Note : tu peux remplacer, dans la formule, MesTextes par {"Toi"; "Moi";etc.}
A+
Jean-Louis
LibO 7.6.5.2 (x64 avec Java 1.8.0_401) et AOO 4.1.15 (avec Java x32 1.8.0_381), Windows 7 Édition Intégrale 64 SP1
Avatar de l’utilisateur
gerard24
ManitOOu
ManitOOu
Messages : 3160
Inscription : 06 juil. 2008 19:08
Localisation : dans le Périgord

Re: [Résolu] NB.SI / Recherche de plusieurs critères sur une

Message par gerard24 »

Bonjour,
Jean-Louis Cadeillan a écrit :A ce moment-là, mets tes textes à rechercher dans une plage, nommée par exemple MesTextes et utilise SOMMEPROD() :

Code : Tout sélectionner

=SOMMEPROD(A1:F1=MesTextes)
Attention avec cette formule, si la plage de recherche est en ligne (comme ici A1:F1) la plage de critères (mestextes) doit être en colonnne.
Et inversement, avec une plage de recherche en colonne, la plage critère doit être en ligne.
Sauf à utiliser TRANSPOSE.

A+
OOodidacte
LibreOffice 6.4.5 sous Windows 10.
pour télécharger LibreOffice
Avatar de l’utilisateur
Fredox
Membre OOrganisé
Membre OOrganisé
Messages : 83
Inscription : 28 oct. 2006 15:55

Re: [Résolu] NB.SI / Recherche de plusieurs critères sur une

Message par Fredox »

Superbe !!! :super:
Mes critères étant en colonne, je suis ravi ! :aie:

Merciiii
Open Office 3.3.0 sous Windows 7
Continu de bricoler sous Calc (mais en net progrès)
Avatar de l’utilisateur
Fredox
Membre OOrganisé
Membre OOrganisé
Messages : 83
Inscription : 28 oct. 2006 15:55

Re: [Résolu] NB.SI / Recherche de plusieurs critères sur une

Message par Fredox »

Arfff !
Problème, mon PC du boulot étant sous OpenOffice 3.0.0, la formule ne fonctionne pas - Mon premier critere est bien pris en compte, les autres non.

Code : Tout sélectionner

=SOMMEPROD(A1:F1=S22:S29)
Seul S22 est comptabilisé (alors que sur OOO v3.3.0 cela fonctionne parfaitement).

De plus impossible pour moi de la faire fonctionnée ainsi:

Code : Tout sélectionner

=SOMMEPROD(A1:F1=S22;S23;S24;S25;S26;S27;S28;S29)
Même en version 3.3.0

Simplement problème de compatibilité pour la première solution ?
Je me suis tromper de formule pour la seconde ?


Je peu mettre mon PC du boulot à jour, mais je vais partager ce document et tout mes colègues ne seront pas à jour.
Merci
Open Office 3.3.0 sous Windows 7
Continu de bricoler sous Calc (mais en net progrès)
Jeff
GourOOu
GourOOu
Messages : 9608
Inscription : 18 sept. 2006 11:40
Localisation : France

Re: [Résolu] NB.SI / Recherche de plusieurs critères sur une

Message par Jeff »

Bonjour,

Tu as bien pris en compte le message de Gérard au sujet de la transposition ?

Je pense que tu devrai nous joindre un fichier-test pour les tests :)
Avatar de l’utilisateur
Fredox
Membre OOrganisé
Membre OOrganisé
Messages : 83
Inscription : 28 oct. 2006 15:55

Re: [Résolu] NB.SI / Recherche de plusieurs critères sur une

Message par Fredox »

J'ai mis ce que j'ai testé.
Dans la case jaune, pas de soucis sous OOO v3.3.0 mais ne fonstionne pas sous OOO v3.0.0
Dans la rose ce que j'ai cru comprendre mais ne fonctionne pas du tout

Pour TRANSPOSE je ne l'ai pas utiliser car la plage est en ligne et les critères en colonne.

Merci
Pièces jointes
Zsais.ods
Fichier joint
(7.51 Kio) Téléchargé 225 fois
Open Office 3.3.0 sous Windows 7
Continu de bricoler sous Calc (mais en net progrès)
Avatar de l’utilisateur
Jean-Louis Cadeillan
GourOOu
GourOOu
Messages : 5732
Inscription : 03 janv. 2009 00:56

Re: [Résolu] NB.SI / Recherche de plusieurs critères sur une

Message par Jean-Louis Cadeillan »

Fredox a écrit :Simplement problème de compatibilité pour la première solution ?
Oui
Fredox a écrit :Je me suis trompé de formule pour la seconde ?
Oui
Une solution avec une somme matricielle qui marche sous OOo 3.0.0 :

Code : Tout sélectionner

=SOMME(A1:F1=S22;A1:F1=S23;A1:F1=S24;A1:F1=S25;A1:F1=S26;A1:F1=S27;A1:F1=S28;A1:F1=S29)
...c'est plus lourd...
 Ajout : Pour ton fichier (je ne l'avais pas ouvert), ce serait :

Code : Tout sélectionner

=SOMME(A1:F1=I4;A1:F1=I5;A1:F1=I6;A1:F1=I7;A1:F1=I8;A1:F1=I9)
 
A+
Jean-Louis
LibO 7.6.5.2 (x64 avec Java 1.8.0_401) et AOO 4.1.15 (avec Java x32 1.8.0_381), Windows 7 Édition Intégrale 64 SP1
Avatar de l’utilisateur
gerard24
ManitOOu
ManitOOu
Messages : 3160
Inscription : 06 juil. 2008 19:08
Localisation : dans le Périgord

Re: [Résolu] NB.SI / Recherche de plusieurs critères sur une

Message par gerard24 »

Je n'ai plus d'ancienne version mais essayes :

Code : Tout sélectionner

=SOMMEPROD(NB.SI(A1:F1;I4:I9))
ou

Code : Tout sélectionner

=SOMME(NB.SI(A1:F1;I4:I9))
en matricielle.

ou encore :

Code : Tout sélectionner

=SOMMEPROD(ESTNUM(EQUIV(A1:F1;I4:I9;0)))
Dernière modification par gerard24 le 16 nov. 2011 20:14, modifié 1 fois.
OOodidacte
LibreOffice 6.4.5 sous Windows 10.
pour télécharger LibreOffice
Avatar de l’utilisateur
Fredox
Membre OOrganisé
Membre OOrganisé
Messages : 83
Inscription : 28 oct. 2006 15:55

Re: [Résolu] NB.SI / Recherche de plusieurs critères sur une

Message par Fredox »

Code : Tout sélectionner

=SOMME(A1:F1=I4;A1:F1=I5;A1:F1=I6;A1:F1=I7;A1:F1=I8;A1:F1=I9) 
Aie Aie Aie, désoler Jean-Louis, je te remercie mais cela ne fonctionne pas (il ne compte rien), comme visiblement tu utilise Libre Office, cela viens peut-être de là.

Merci quand même :(
Open Office 3.3.0 sous Windows 7
Continu de bricoler sous Calc (mais en net progrès)
Avatar de l’utilisateur
Fredox
Membre OOrganisé
Membre OOrganisé
Messages : 83
Inscription : 28 oct. 2006 15:55

Re: [Résolu] NB.SI / Recherche de plusieurs critères sur une

Message par Fredox »

Merci Gérard,

Code : Tout sélectionner

=SOMMEPROD(NB.SI(A1:F1;I4:I9))
fonctionne parfaitement sous OOo v3.0.0 :bravo:
Superbe, voila ma vie simplifiée (si si)

Merci Gérard, Merci Jean-Louis.
Open Office 3.3.0 sous Windows 7
Continu de bricoler sous Calc (mais en net progrès)
Avatar de l’utilisateur
gerard24
ManitOOu
ManitOOu
Messages : 3160
Inscription : 06 juil. 2008 19:08
Localisation : dans le Périgord

Re: [Résolu] NB.SI / Recherche de plusieurs critères sur une

Message par gerard24 »

Fredox a écrit :

Code : Tout sélectionner

=SOMME(A1:F1=I4;A1:F1=I5;A1:F1=I6;A1:F1=I7;A1:F1=I8;A1:F1=I9) 
Aie Aie Aie, désoler Jean-Louis, je te remercie mais cela ne fonctionne pas (il ne compte rien), comme visiblement tu utilise Libre Office, cela viens peut-être de là.
Comme l'a souligné Jean-Louis, cette formule est matricielle. Elle doit donc être validée par Ctrl+Maj+Entrée.
OOodidacte
LibreOffice 6.4.5 sous Windows 10.
pour télécharger LibreOffice
Avatar de l’utilisateur
Fredox
Membre OOrganisé
Membre OOrganisé
Messages : 83
Inscription : 28 oct. 2006 15:55

Re: [Résolu] NB.SI / Recherche de plusieurs critères sur une

Message par Fredox »

OK.
Merci.
Open Office 3.3.0 sous Windows 7
Continu de bricoler sous Calc (mais en net progrès)
AS-THOMAS
NOOuvel adepte
NOOuvel adepte
Messages : 20
Inscription : 05 avr. 2017 17:08

Re: [Résolu] NB.SI / Recherche de plusieurs critères sur une

Message par AS-THOMAS »

Bonjour,

Je souhaite que Calc me donne le nombre de valeurs comprises entre deux valeurs.

Si j'ai en valeurs : 6/8/5/9/6/8/4/7/3/2/1/5/9/6/8/7/6/3/2/5. En comptant à la main j'ai 13 valeurs comprises entre 5 et 8 (en incluant le 5 et le 8).

Savez vous s'il est possible de remplacer le critère par une plage dans la formule NB.SI ?

Merci d'avance !

Cordialement,
Version : Libre office (r??seau entreprise) 4.1.4.2
Windows 7 - PC portable HP probook 4540s
Avatar de l’utilisateur
Oukcha
RespOOnsable modération
RespOOnsable modération
Messages : 3929
Inscription : 06 oct. 2008 10:03

Re: [Résolu] NB.SI / Recherche de plusieurs critères sur une

Message par Oukcha »

Bonjour,

Nous nous devons de verrouiller ce fil de discussion. Nous vous rappelons les règles de ce forum et notamment la n° 7
Un sujet = le problème d'une seule personne

Comme vous avez pu le lire, ce sujet est désormais résolu. Si vous avez également ce problème, c'est que ce dernier est différent. Votre configuration n'est peut être pas la même que celle de l'auteur de ce fil.

Dans ce cas et pour des raisons de lisibilité sur ce forum, nous vous demandons de créer une nouvelle question en rappelant que vous avez le même problème que dans ce fil.

Merci de votre collaboration.
                                        
Pour tout savoir sur le fonctionnement de ce forum :arrow: À lire avant tout ! Image
Verrouillé