Página 1 de 1
[RESUELTO] Ayuda con Macro
Publicado: Mié Sep 04, 2013 2:10 pm
por fgili
Hola, bueno sigo avanzando con mi primera base de datos . . . .
he incluido estos codigos y funcionan correctamente, pero lo que deseo es que
la ventana se abra en un tamaño determinado asi queda mas centrad el form y que no tenga ningun tipo de barra de herramientas
con esta macro que dejo abajo desaparece la barra de menu de arriba pero no la del pie.
Código: Seleccionar todo
=======================================
Full Screen
==========================================
Sub PantallaCompleta(Event As Object)
Dim oFrame As Object
Dim oDispatchHelper
oFrame=Event.Source.Parent.Parent.CurrentController.Frame
oDispatchHelper=CreateUnoService("com.sun.star.frame.DispatchHelper")
oDispatchHelper.ExecuteDispatch(oFrame,".uno:FullScreen","",0,Array())
End Sub
===========================================
Ocultar menus
=========================================
Sub sBotonOcultarBarraMenu(Event As Object)
Dim oForm As Object
Dim oLayMan As Object
oForm=Event.Source.Model.Parent
oLayMan=oForm.Parent.Parent.CurrentController.Frame.LayoutManager
oLayMan.HideElement("private:resource/menubar/menubar")
End Sub
Muchas Gracias de nuevo
Re: Ayuda con Macro
Publicado: Mié Sep 04, 2013 8:42 pm
por SLV-es
Supongo que te refieres a la barra de estado.
Quizás esta macro para Calc te dé una pista:
http://wiki.open-office.es/Macros_en_Ba ... 3.B3rmulas
Si funciona tal como está o mejorada, espero que lo compartas en el foro
Re: Ayuda con Macro
Publicado: Jue Sep 05, 2013 12:38 pm
por fgili
Hla, he probado el codigo pero me da error, en la promera linea
Sub Barra_Visible(cBarra As String, Optional lVisible As Boolean)
claro y como ni idea de programación, imposible que pueda saber coo arreglarlo
estoy buscando algun codigo que ya funcione para pegar directamente
Ya posteare cuando encuentre uno que funcione ok
Gracias!!!!
Re: Ayuda con Macro
Publicado: Dom Sep 08, 2013 5:01 pm
por RMG
Hola,
Esto elimina todas las barras de menús, es una adaptación de parte de la extensión ORBSwitchBoard.
Código: Seleccionar todo
Sub AlCargarOcultarBarrasMenus(Allowed As Variant)
Dim oFrame As Object
Dim Layout As Object
Dim I As Integer
Dim strURL As String
If IsMissing(Allowed) Or Not IsArray(Allowed) Then Allowed=Array()
BubbleSort(Allowed)'llamada a la funcion BubbleShort
oFrame = ThisComponent.CurrentController.Frame
Layout=oFrame.LayoutManager
For I=0 To UBound(Layout.Elements)
strURL=Layout.Elements(I).ResourceURL
If BinSearch(strURL,Allowed)>=0 Then 'llamada a la funcion BinSearch
Layout.showElement(strURL)
Else
Layout.hideElement(strURL)
End If
Next I
End Sub
Function BinSearch(Item As String,Items As Variant) As Integer
Dim Low As Integer
Dim High As Integer
Dim N As Integer
Dim Middle As Integer
BinSearch=-1 REM No encontrado
N=UBound(Items)+1
If N<=1 Then Exit Function
Low=0
High=N-1
While(Low<=High)
Middle=(Low+High)/2
If Items(Middle) > Item Then
High=Middle-1
ElseIf Items(Middle) < Item Then
Low=Middle+1
Else
BinSearch=Middle : Exit Function
End If
Wend
End Function
Function BubbleSort(Items As Variant) As Boolean
Dim I As Integer
Dim J As Integer
Dim Tmp As Variant
For I=0 To UBound(Items)
For J=UBound(Items) To I+1 Step -1
If Items(J-1) > Items(J) Then
Tmp=Items(J-1)
Items(J-1)=Items(J)
Items(J)=Tmp
End If
Next J
Next I
End Function
Saludos
Re: Ayuda con Macro
Publicado: Dom Sep 08, 2013 10:05 pm
por fgili
Funciona OK, gracias!!!!