Apache OpenOffice: Foro oficial de la comunidad

mauricio escribió:O sea... ¿lo que quieres es "contar" las celdas?

xiseme escribió:Ah! bueno, tratándose de contar podemos hacer una variación ...

Código: Seleccionar todo

Function CONTARCOLOR(CeldaColor As String, RangoSuma As String) As Double
'Variante de la función SUMARCOLOR de FORNELASA pasando los parámetros como texto entre comillas.
'Ej  CONTARCOLOR("B5";"E2:F42")  No olvidar las comillas 
Dim oRango As Object
Dim oCelda As Double
Dim c As Integer
Dim f As Integer
Dim oCuenta as Integer
oCuenta=0	'inicializamos variable
oRango = ThisComponent.CurrentController.ActiveSheet
oCelda = oRango.GetCellRangeByName(CeldaColor).CellBackColor
oRango = oRango.GetCellRangeByName(RangoSuma)
For c = 0 to oRango.Columns.Count - 1
	For f = 0 to oRango.Rows.Count - 1
		If 	oRango.GetCellByPosition(c,f).CellBackColor = oCelda Then
			oCuenta = oCuenta + 1
		End If
	Next
Next
CONTARCOLOR = oCuenta
End Function

Claro que los criterios que se han usado para dar color a las celdas, también podrían emplearse para contarlas [o lo que sea]

xiseme escribió:Herramientas → Macros → Organizar macros → OOo
Aquí dos posibilidades

1.- Función disponible para todo AOO/LibO
Click en la flecha > de "Mis Macros" → Standard y en la parte derecha de la ventana "Nuevo" aparecerá "Module1" ponle el nombre a tu gusto. Aparecerá la ventana de Basic. Pega ahí el código anterior y guarda.

2.- Función estará disponible solo para el archivo NombreDeLaHoja
Click en la flecha > de NombreDeLaHoja → Standard ...igual que en lo anterior.

Esto pondrá a tu disposición la función CONTARCOLOR que tiene dos parámetros. El primero es la una dirección de celda con el color de fondo de referencia, el segundo la dirección del rango que queremos evaluar. Funcionará como cualquier otra función de AOO.

RMG escribió:Hola,

Mi sugerencia. Visita este enlace, te ayudará bastante en el tema de las macros.

http://user.services.openoffice.org/es/ ... 1545#p4404

Saludos

xiseme escribió:La función está sin pulir. Entre otras cosas habría que añadirle un control de errores.

Creo que para salir del paso, basta con ignorar los errores y recalcular con Ctrl+Shifft+F9. Ten en cuenta que si la fórmula está 200 veces en tu hoja seguramente habrá que ignorarlos 200 veces.

Esto te permitirá hacer un conteo de las celdas coloreadas por rangos, sin muchas más pretensiones.
No es idóneo; tan poco idóneo como manejar datos "por colores". En todo caso se debieran emplear las condiciones/criterios que se siguen para "colorear" plasmándolas en una o varias fórmulas.

• Celdas precedentes y celdas dependientes
  Celda precedente: Aquella celda que participa en el resultado de una fórmula. Un precedente directo es una celda que se utiliza directamente en la fórmula. Un precedente indirecto es una celda que es utilizada por otra celda que se utiliza directamente en la fórmula.
  Celda dependiente: Aquella cuyo resultado depende de otra celda. La celda también puede ser dependiente directo o indirecto.
  Ejemplo: Si C1 = A1 + B1, entonces A1 y B1 son celdas precedentes de C1, y C1 es una celda dependiente de A1 y B1.
  

pero a veces me desactualiza los datos

nuki escribió: Según cambio cosas en una hoja del archivo en los otros se modifican las sumas

• > Long en lugar de Double
  > Un nuevo parámetro String para especificar la hoja donde tiene que sumar los rangos
  > He añadido la sentencia With que aumenta la velocidad de ejecución
  > He modificado el nombre de las hojas para que no haya confusión con las columnas

Function CONTARCOLOR(CeldaColor As String, RangoSuma As String, NombreHoja As String) As Long
'Variante de la función SUMARCOLOR de FORNELASA pasando los parámetros como texto entre comillas.
'Ej  CONTARCOLOR("B5";"E2:F42";"NOMBRE_HOJA")  No olvidar las comillas 
Dim oHoja As Object
Dim oRango As Object
Dim oCelda As Long
Dim c As Integer
Dim f As Integer
Dim oCuenta as Long

	oCuenta = 0   'inicializamos variable
	oHoja = ThisComponent.getSheets.getByName(NombreHoja)
	With oHoja
		oCelda = .GetCellRangeByName(CeldaColor).CellBackColor
		oRango = .GetCellRangeByName(RangoSuma)
		With oRango
			For c = 0 to .Columns.Count - 1
	   			For f = 0 to .Rows.Count - 1
	      			If .GetCellByPosition(c,f).CellBackColor = oCelda Then
	         			oCuenta = oCuenta + 1
	      			End If
	   			Next
			Next
		End With	'oRango
	End With	'oHoja

	CONTARCOLOR = oCuenta
End Function

• =CONTARCOLOR("Z36";"U38:AA43";"NOMBRE-DE-LA-HOJA-NUEVA-O-NUEVO-NOMBRE-DE-LA-HOJA")

• =CONTARCOLOR("Z36";"U38:AA43";$B$5)

Function CONTARCOLOR(CeldaColor As String, RangoSuma As String, NombreHoja As String) As Long
'Variante de la función SUMARCOLOR de FORNELASA pasando los parámetros como texto entre comillas.
'Ej  CONTARCOLOR("B5";"E2:F42";"NOMBRE_HOJA")  No olvidar las comillas 
Dim oHoja As Object
Dim oRango As Object
Dim oCelda As Long
Dim c As Integer
Dim f As Integer
Dim oCuenta as Long
	
	On Error Goto TRATAR_ERROR
	oCuenta = 0   'inicializamos variable
	oHoja = ThisComponent.getSheets.getByName(NombreHoja)
	With oHoja
		oCelda = .GetCellRangeByName(CeldaColor).CellBackColor
		oRango = .GetCellRangeByName(RangoSuma)
		With oRango
			For c = 0 to .Columns.Count - 1
	   			For f = 0 to .Rows.Count - 1
	      			If .GetCellByPosition(c,f).CellBackColor = oCelda Then
	         			oCuenta = oCuenta + 1
	      			End If
	   			Next
			Next
		End With
	End With

	CONTARCOLOR = oCuenta
	Exit Function

TRATAR_ERROR:
	CONTARCOLOR = -1
End Function

Neftali R escribió: ↑Mar Mar 29, 2022 3:38 pm Ya vi el problema, no es un formato hecho manualmente, es un formato condicional, ya que ese es el caso, deberías hacer una tabla espejo que haga la misma verificación que el formato condicional (ejemplo: Hoja1.B3=Hoja1.A3 | Hoja1.C3=Hoja1.A3 y así) ese condicional te va a soltar un 1 si la comparación es verdadera y un 0 si la comparación es falsa, así que en lugar de contar por color, estarías contando los 1 en la tabla espejo.

Creo que sería más fácil explicarlo con un ejemplo.
Resultados quiniela3-2 con tabla espejo.ods

También podríamos hacer que el macro vea el color del formato condicional en lugar del color de la celda, en si misma, que es lo que hace el macro, pero eso sería innecesariamente complicado, siempre es mejor hacer las cosas lo más simples posible.