Apache OpenOffice: Foro oficial de la comunidad

Código: Seleccionar todo

oCelda.NumberFormat(acá el numerito)

Código: Seleccionar todo

REM  *****  BASIC  *****
Option Explicit

Const ICONO_STOP As Integer = 16
Const BOTON_ACEPTAR As Integer = 0

Sub VerFormato

	Dim oDoc As Object
	Dim oHoja As Object
	Dim ValorCelda As Double
	Dim CadenaFormatoNumero As String
	Dim Alineacion As String
	Dim FormatosNumeros As Object
	Dim IndiceFormato As Long
	Dim LocalSettings As New com.sun.star.lang.Locale

	On Error GoTo VER_ERROR
	oDoc = ThisComponent
	oHoja = oDoc.CurrentController.getActiveSheet()
	With oHoja
		ValorCelda = .getCellRangeByName("B1").getValue()
		CadenaFormatoNumero = .getCellRangeByName("B2").getString()
		Alineacion = .getCellRangeByName("B3").getString()
		With .getCellRangeByName("B4")
			' Asignamos el valor de B1
			.setValue(ValorCelda)
			' Negrita
			.CharWeight = com.sun.star.awt.FontWeight.BOLD
			' Horientación vertical Centrada
			.VertJustify = com.sun.star.table.CellVertJustify.CENTER
			' Horientación horizontal de acuerdo a lo seleccionado
			Select Case Alineacion
				Case "Izquierda"
					.HoriJustify = com.sun.star.table.CellHoriJustify.LEFT
				Case "Centrado"
					.HoriJustify = com.sun.star.table.CellHoriJustify.CENTER
				Case "Derecha"
					.HoriJustify = com.sun.star.table.CellHoriJustify.RIGHT
			End Select
			' MUY IMPORTANTE para asignar formatos: ¡Atención! País -> ESPAÑA
			With LocalSettings
				.Language = "es"
				.Country = "es"
			End With
			' Accedemos a los distintos formatos presentes en el documento
			FormatosNumeros = oDoc.NumberFormats
			' Consultamos si existe el que nosotros queremos
			IndiceFormato = FormatosNumeros.queryKey(CadenaFormatoNumero, LocalSettings, True)
			If IndiceFormato = -1 Then
				' Si no existe entonces lo añade a los existentes
				IndiceFormato = FormatosNumeros.addNew(CadenaFormatoNumero, LocalSettings)
			End If
			' Se asigna el formato adecuado
			.NumberFormat = IndiceFormato
		End With
	End With
	Exit Sub
VER_ERROR:
	MsgBox "Lo siento pero no puedo mostrar ese formato.", ICONO_STOP + BOTON_ACEPTAR, "¡Atención!"
End Sub

Código: Seleccionar todo

sub PonerColumna2Decimales(nColumna as long)
dim document   as object
dim dispatcher as object

document   = ThisComponent.CurrentController.Frame
dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")

dim args1(0) as new com.sun.star.beans.PropertyValue
args1(0).Name = "Sel"
args1(0).Value = false

dispatcher.executeDispatch(document, ".uno:GoToStart", "", 0, args1())

dim args2(1) as new com.sun.star.beans.PropertyValue
args2(0).Name = "By"
args2(0).Value = nColumna
args2(1).Name = "Sel"
args2(1).Value = false

dispatcher.executeDispatch(document, ".uno:GoRight", "", 0, args2())
dim args3(1) as new com.sun.star.beans.PropertyValue
args3(0).Name = "By"
args3(0).Value = 1
args3(1).Name = "Sel"
args3(1).Value = true

dispatcher.executeDispatch(document, ".uno:GoDownToEndOfData", "", 0, args3())
dispatcher.executeDispatch(document, ".uno:NumberFormatIncDecimals", "", 0, Array())
dispatcher.executeDispatch(document, ".uno:NumberFormatIncDecimals", "", 0, Array())
dispatcher.executeDispatch(document, ".uno:GoToStart", "", 0, args1())

end sub

Código: Seleccionar todo

Option Explicit

Sub Main
	Dim oDoc As Object ' Documento actual
	Dim oHoja As Object ' Hoja activa
	Dim oCelda As Object ' Celda en la cual voy a trabajar
	Dim CadenaFormatoNumero As String
	Dim FormatosNumeros As Object
	Dim IndiceFormato As Long
	Dim LocalSettings As New com.sun.star.lang.Locale
	
	oDoc = ThisComponent
	oHoja = oDoc.currentController.getActiveSheet()
	oCelda = oHoja.getCellRangeByName( "A1" )
	CadenaFormatoNumero = "###0,00"
	
	With LocalSettings
		.Language = "es"
		.Country = "es"
	End With
	
	' Accedemos a los distintos formatos presentes en el documento
	FormatosNumeros = oDoc.NumberFormats
	' Consultamos si existe el que nosotros queremos
	IndiceFormato = FormatosNumeros.queryKey(CadenaFormatoNumero, LocalSettings, True)
	If IndiceFormato = -1 Then
		' Si no existe entonces lo añade a los existentes
		IndiceFormato = FormatosNumeros.addNew(CadenaFormatoNumero, LocalSettings)
	End If
	' Se asigna el formato adecuado a la celda
	oCelda.NumberFormat = IndiceFormato
	
End Sub

Código: Seleccionar todo

Do While oCelda.Type <> EMPTY
      ' Aquí le asigno el formato que obtuve en el código anterior 
      oCelda.NumberFormat = IndiceFormato
      'Aumento el contador y paso de celda
      iContador = iContador + 1
      oCelda = oHoja.getCellRangeByName( "A"+iContador )
Loop