Buscar el texto de una fila

Discute sobre la aplicación de hojas de cálculo
Responder
Avatar de Usuario
electrico
Mensajes: 62
Registrado: Lun Ene 14, 2013 5:58 pm
Ubicación: España

Buscar el texto de una fila

Mensaje por electrico »

Buenas !

Me dirijo a vosotros con la esperanza de que me ayudeis con el tema este que voy a intentar explicaros
tengo una tabla de 274 columnas x 7500 filas con datos de texto cada fila contiene una sola celda con datos y quisiera tener una columna final donde se reflejaran el dato de texto de cada fila

no se si me he explicado bien
pero dejo un archivo porsi sirve de algo Tener en cuenta que tiene 274 columnas
Adjuntos
Saber el texto de una fila.ods
(125.45 KiB) Descargado 115 veces
!La VERDAD y la REALIDAD no son lo mismo! Verdades hay tantas como observadores de la misma realidad
No confundas lo URGENTE con lo IMPORTANTE. Por lo tanto:
PON ATENCION a lo REALMENTE IMPORTANTE
Avatar de Usuario
PepeOooSevilla
Mensajes: 1480
Registrado: Sab Abr 04, 2009 6:10 pm
Ubicación: Sevilla (España)

Re: Buscar el texto de una fila

Mensaje por PepeOooSevilla »

Hola.
Adjunto una posible solución, para 30 filas (vale igual para x filas), usando expresiones regulares. Esto quiere decir que tienes que tener activado en Herramientas > Opciones > Libreoffice Calc > Calcular > Apartado Cálculos generales > Permitir expresiones regulares en las fórmulas.

En la celda JQ9 y rellenando hacia abajo:

Código: Seleccionar todo

=INDICE(B9:JO9;COINCIDIR(".*";B9:JO9;0))
Saludos cordiales.
Adjuntos
Saber el texto de una fila_electrico_v2.ods
LibreOffice Calc. Sólo 30 filas
(17.41 KiB) Descargado 115 veces
LibreOffice 6.4.6. Windows 10. Java 8 rev. 261 (64 bits)
Por favor, utiliza el Foro para tus consultas, no los mensajes privados
Si usas OpenOffice/LibreOffice trabaja y guarda en ODT, ODS, ODP, ... Y haz copias de seguridad.
Avatar de Usuario
electrico
Mensajes: 62
Registrado: Lun Ene 14, 2013 5:58 pm
Ubicación: España

Re: Buscar el texto de una fila

Mensaje por electrico »

Muchas gracias por la rapida respuesta

Pido perdon por mi ignorancia , pero despues de leer la ayuada sobre las funciones Indice() y coincidir() no alcanzo a comprender como funciona
la formula que has mandado, de la misma forma que no entiendo pq funciona solo para los primeros 30 dias y no para el resto , Tengo activado el parametro de configuracion que has mencianado en la respuesta

¿Podrias explicar con un poco mas de detalle como funciona la formula y decirme como adaptarla a mis necesidates de muchisimas filas?

Muchisimas gracias de antemano!!!
!La VERDAD y la REALIDAD no son lo mismo! Verdades hay tantas como observadores de la misma realidad
No confundas lo URGENTE con lo IMPORTANTE. Por lo tanto:
PON ATENCION a lo REALMENTE IMPORTANTE
Snake
Mensajes: 1
Registrado: Vie Abr 20, 2018 8:41 pm

Re: Buscar el texto de una fila

Mensaje por Snake »

Hola:

Puedes utilizar también en JQ9

Código: Seleccionar todo

=INDICE(B9:JO9,COINCIDIR(VERDADERO,B9:JO9<>"",0))
Esta es una fórmula matricial (ctrl+sifth+enter)

y si quieres saber en que celda esta el texto, puedes usar en JR9

Código: Seleccionar todo

=DIRECCION(9,COINCIDIR(JQ9,B9:JO9,0)+1,4)

Mi separador de argumentos es la "," cámbialo si utilizas otro.

Saludos.
Windows 2010
Avatar de Usuario
PepeOooSevilla
Mensajes: 1480
Registrado: Sab Abr 04, 2009 6:10 pm
Ubicación: Sevilla (España)

Re: Buscar el texto de una fila

Mensaje por PepeOooSevilla »

Hola.
electrico escribió:... las funciones Indice() y coincidir() no alcanzo a comprender ...
Intentaré explicarlo con un ejemplo:
  • 1º. Función INDICE (usada como en la fórmula de la respuesta anterior). Supongamos el rango A1:E1 de cinco celdas con los valores siguientes:
    A1 = España, B1 = Portugal, C1 = Francia, D1 = México y E1 = Argentina

    Si en F1 escribo ...

    Código: Seleccionar todo

    =INDICE(A1:E1;3)
    =INDICE(Rango_de_celdas; Posición_en_el_rango)
    
    ... Se mostrará Francia ya que este es el valor que se encuentra en la celda que ocupa la posición 3 del rango A1:E1. Es decir, dada una posición me devuelve un valor.
  • 2º. Función COINCIDIR (usada como en la fórmula de la respuesta anterior).

    Si en G1 escribo ...

    Código: Seleccionar todo

    =COINCIDIR("Francia";A1:E1;0)
    =COINCIDIR(Qué_busco;Rango_de_celdas;Tipo_de_coincidencia)
    
    ... Se mostrará 3 ya que esta es la posición en que se encuentra la celda del rango A1:E1 cuyo valor coincide exactamente con Francia. Es decir, dado un valor me devuelve una posición.
  • 3º. La fórmula ...

    Código: Seleccionar todo

    =INDICE(B9:JO9;COINCIDIR(".*";B9:JO9;0))
    ... Devuelve el valor que se encuentra en la celda que ocupa la posición COINCIDIR(".*";B9:JO9;0)) del rango B9:JO9, porque a priori no sé en qué posición se encuentra lo que busco.
electrico escribió:... funciona solo para los primeros 30 dias y no para el resto ...
  • 4º. Funciona para las 7500 filas o todas las que sean, sólo tienes que copiar/rellenar la fórmula hacia abajo. El hecho de "recortar" a 30 filas es por el peso del archivo. El que subiste ocupa 125,45 Kb y el que yo subí 17,41 Kb. No es necesario subir el archivo completo, con unas cuantas filas de ejemplo es suficiente.
Saludos cordiales.
LibreOffice 6.4.6. Windows 10. Java 8 rev. 261 (64 bits)
Por favor, utiliza el Foro para tus consultas, no los mensajes privados
Si usas OpenOffice/LibreOffice trabaja y guarda en ODT, ODS, ODP, ... Y haz copias de seguridad.
Responder