[RESUELTO] Funcion CELDA

Discute sobre la aplicación de hojas de cálculo
Responder
mmittelbach
Mensajes: 21
Registrado: Jue Sep 03, 2020 11:37 pm

[RESUELTO] Funcion CELDA

Mensaje por mmittelbach »

Hola gente buenos días.
He buscado en el foro la forma de listar todas la hojas de una planilla, porque quiero crear hipervinculos a dichas hojas, pero no he encontrado exactamente lo que busco.
he probado con la funcion CELDA (=CELDA("NOMBREDEARCHIVO";'X:\dr\prueba.ods'#$Hoja1.D2)) tal cual lo explica la ayuda, pero no entiendo porque donde pone "nombredearchivo", pongo el nombre del archivo y me tira un error (no se si lo pongo bien).
Apelo a la buena voluntad para ver si alguien me indica o bien como se ponen los datos de la funcion celda o bien me indica como puedo listar todas las hojas del libro en una sola hoja. muchas gracias a todos
Última edición por mmittelbach el Sab Feb 06, 2021 3:26 am, editado 2 veces en total.
Libre Office 6.0.7.3. en Linux Mint 19.3
mriosv
Mensajes: 2334
Registrado: Sab Dic 27, 2008 1:12 am
Ubicación: Galiza (España)

Re: Funcion CELDA

Mensaje por mriosv »

Te paso un fichero con algunos ejemplos de como usarla.
Ten en cuenta que el parámetro entre comillas es siempre en inglés.

Código: Seleccionar todo

=CELDA("filename")
'file:///C:/Users/MARV/Downloads/_Test/FunctionsExtractFileName.ods'#$Sheet1

=MID(CELDA("filename");2;HALLAR("'#";CELDA("filename"))-2)
file:///C:/Users/MARV/Downloads/_Test/FunctionsExtractFileName.ods

=MID(CELDA("filename");2;HALLAR("/[^/]+'#";CELDA("filename"))-1)
file:///C:/Users/MARV/Downloads/_Test/

=MID(CELDA("filename");ENCONTRAR("#$";CELDA("filename"))+2;LARGO(CELDA("filename")))
Sheet1

=MID(CELDA("filename");HALLAR("/[^/]+'#";CELDA("filename"))+1;HALLAR("'#";CELDA("filename"))-HALLAR("/[^/]+'#";CELDA("filename"))-1)
FunctionsExtractFileName.ods

=MID(CELDA("filename");HALLAR("/[^/]+'#";CELDA("filename"))+1;HALLAR("'#";CELDA("filename"))-HALLAR("/[^/]+'#";CELDA("filename"))-5)
FunctionsExtractFileName

=REEMPLAZAR(REEMPLAZAR(CELDA("filename");ENCONTRAR(".";CELDA("filename");1);(LARGO(CELDA("filename"))-ENCONTRAR(".";CELDA("filename");1)+1);"");1;HALLAR("/[^/]*$";CELDA("filename"));"")
FunctionsExtractFileName

=EXP.REG(CELDA("filename");"[^/]+(?='#\$)")
FunctionsExtractFileName.ods
Adjuntos
FunctionsExtractFileName.ods
(17.25 KiB) Descargado 112 veces
Puedes usar "Subir adjunto" en Respuesta rápida - Editor Completo - Pestaña Subir adjunto
Apache OpenOffice 4, LibreOffice (Win10x64)
mmittelbach
Mensajes: 21
Registrado: Jue Sep 03, 2020 11:37 pm

Re: Funcion CELDA [SOLUCIONADO]

Mensaje por mmittelbach »

MUCHISIMAS GRACIAS mriosv.
La verdad es que el help de la función no fué muy entendible para mi.
Voy a practicar con la planilla que me enviaste.
Muchas gracias!.
Libre Office 6.0.7.3. en Linux Mint 19.3
Responder