[RESUELTO] Problema con SUMAR.SI

[nuria99]

Hola, buenos días,
Tengo una hoja de calculo que quiero que me calcule en una celda la suma de unas cantidades si se cumplen unas condiciones, por ejemplo si una columna que contiene fechas (B3:B6), estas están dentro del tercer trimestre, quiero que me sume la columna de saldos (C3:C6) las que cumplan la condición.
Si tengo la siguiente tabla
A B
1 FECHA SALDO
2 01/02/2017 1000
3 01/05/2017 2000
4 01/08/2017 3000
5 01/11/2017 4000

1º TRIMESTRE = SUMAR.SI(A2:A5;"<01/04/2017";B2:B5), RESULTADO 1000, BIEN
2º TRIMESTRE =SUMAR.SI(A2:A5;">01/04/2017 and <01/07/2017";B2:B5). RESULTADO 0, cuando debería de ser 2000 (*)
3º TRIMESTRE
4º TRIMESTRE

(*) No da error, pero el resultado no es correcto, imagino que será la formula que no esta bien.
Gracias
Un saludo

[fornelasa]

Una posible opción de muchas:

Código: Seleccionar todo

=SUMAR.SI(A2:A5;">"&FECHA(2017;4;1);B2:B5)-SUMAR.SI(A2:A5;">"&FECHA(2017;7;1);B2:B5)

Tal vez debas de cambiar el separador de argumento ; por ,
Saludos, Federico.

[nuria99]

Buenas Federico,
Ahora me da error (509), SUMAR.SI(A2:A5;">"&FECHA(2017,40,1) ;B2:B5) -SUMAR.SI(A2:A5"<"&FECHA(2017,70,1)B2:B5),
No se podría poner la doble condición con un Y.
Gracias.
Un saludo

[fornelasa]

Ahora me da error (509), SUMAR.SI(A2:A5;">"&FECHA(2017,40,1) ;B2:B5) -SUMAR.SI(A2:A5"<"&FECHA(2017,70,1)B2:B5),

¡pues claro!, con lo que hiciste por supuesto que dará error, usas la , además de ;

No se podría poner la doble condición con un Y.

¡ni idea!, creo que no se puede.

Y no, no da error, aquí tres formas de hacerlo.

Saludos, Federico.

[mriosv]

Tres opciones.

Código: Seleccionar todo

=SUMA.PRODUCTO(TEXTO($A$2:$A$5;"Q")="T1";$B$2:$B$5)

=SUMAR.SIS(B2:B5;A2:A5;">=01-01-2017";A2:A5;"<=31-03-2017")

=SUMA.PRODUCTO(B2:B5;A2:A5>=FECHANUMERO("1-1-2017");A2:A5<=FECHANUMERO("31-3-2017"))

SUMA.PRODUCTO() es especialmente util con condiciones multiples y complejas, pues es mas flexible en la forma de comprobar, aunque como se ve en la tercera formula necesitamos convertir la fecha texto a su valor numerico para la correcta comparación.

[gamusinox]

Ahora me da error (509), SUMAR.SI(A2:A5;">"&FECHA(2017,40,1) ;B2:B5) -SUMAR.SI(A2:A5"<"&FECHA(2017,70,1)B2:B5),

¡pues claro!, con lo que hiciste por supuesto que dará error, usas la , además de ;

No se podría poner la doble condición con un Y.

¡ni idea!, creo que no se puede.

Y no, no da error, aquí tres formas de hacerlo.

Saludos, Federico.

Efectivamente la función SUMAR.SI no permite utilizar funciones complejas (y , o...) como condición.

Otra posible solución además de las ya aportadas sería la siguiente fórmula matricial (he utilizado como base para el ejemplo el archivo fechas.ods subido por el compañero fornelasa):
=SUMA(SI(REDONDEAR.MAS(MES($A$2:$A$27)/3)=G2;$B$2:$B$27))

• Recuerda que una vez escrita la fórmula debes pulsar CTRL+MAY+ENTER

• REDONDEAR.MAS(MES($A$2:$A$27)/3)=G2 comprueba el trimestre al que pertenece cada una de las fechas del rango A2:A27 y lo compara con el valor de la celda G2 (trimestre 1). En los casos en los que se cumple la condición almacena en una matriz el sueldo correspondiente

• Finalmente suma todos los sueldos de la matriz generada en el paso anterior

Saludos

[nuria99]

Gracias por vuestras aportaciones, me han servido de mucha ayuda.
Un saludo.

[fornelasa]

ok bien , recuerda marcar el tema como resuelto, aquí nos dicen como hacerlo:
https://forum.openoffice.org/es/forum/v ... f=3&t=2668
Saludos, Federico.