Draw - Basic - Shapes

[Philip Duggins]

How can I create and modify a shape - for example a "Flowchart: Process" shape - with a macro written in Basic?

[Philip Duggins]

Thank you!

[Charlie Young]

How can I create and modify a shape - for example a "Flowchart: Process" shape - with a macro written in Basic?

Just for starters, this puts such a shape at the top left. One also would like to manipulate the position, fill, line styles, etc.

Code: Select all

Sub InsertProcessShape
	Dim oDoc As Object
	Dim oDrawPage As Object
	Dim oShape As Object
	Dim shapeGeometry(0) as new com.sun.star.beans.PropertyValue
	Dim oSize As new com.sun.star.awt.Size
	
	oSize.width = 3000
	oSize.height = 1000
	
	oDoc = ThisComponent
	odrawPage = oDoc.DrawPages(0)
	oShape = oDoc.createInstance("com.sun.star.drawing.CustomShape")
	shapeGeometry(0).Name = "Type"
	shapeGeometry(0).Value = "flowchart-process"
	oDrawPage.add(oShape)
	oShape.CustomShapeGeometry = shapeGeometry
	oShape.Size = oSize
End Sub

[Philip Duggins]

Yes, I definitely would like to be able to manipulate its properties - in particular, position and the text it has in it. I thought the code

Code: Select all

   shapeGeometry(0).Value = "flowchart-process"

would insert text in the shape, but it didn't - it remained blank.

Thank you!

[Villeroy]

http://sourceforge.net/projects/ooomacr ... r%20Tools/

[Charlie Young]

Yes, I definitely would like to be able to manipulate its properties - in particular, position and the text it has in it. I thought the code

Code: Select all

   shapeGeometry(0).Value = "flowchart-process"

would insert text in the shape, but it didn't - it remained blank.

Thank you!

The shapeGeometry.Value is the type of CustomShape. To see what these are, it is probably easiest to draw one manually and inspect it with MRI or xRay, as It isn't always obvious. For example, for a decision shape, the CustomShapeGeometry type is "diamond."

But to go a bit further, this version of the macro centers the shape on the page, sets the fill to NONE, gives it a thicker line, and puts some text in it:

Code: Select all

Sub InsertProcessShape
	Dim oDoc As Object
	Dim oDrawPage As Object
	Dim oShape As Object
	Dim shapeGeometry(0) as new com.sun.star.beans.PropertyValue
	Dim oSize As new com.sun.star.awt.Size
	Dim ShapePos As new com.sun.star.awt.Point
	
	oSize.width = 4000
	oSize.height = 2000
	
	oDoc = ThisComponent
	oDrawPage = oDoc.DrawPages(0)
	oShape = oDoc.createInstance("com.sun.star.drawing.CustomShape")
	shapeGeometry(0).Name = "Type"
	shapeGeometry(0).Value = "flowchart-process"
	oDrawPage.add(oShape)
	oShape.CustomShapeGeometry = shapeGeometry
	oShape.Size = oSize
	ShapePos.X = (oDrawPage.width - oSize.width) \ 2
	ShapePos.Y = (oDrawPage.height - oSize.height) \ 2
	oShape.setPosition(ShapePos)
	oShape.FillStyle = com.sun.star.drawing.FillStyle.NONE
	oShape.LineWidth = 50
	oShape.String = "Spin wheels" & Chr(10) & "(loop forever)"
End Sub

And yes, see Villeroys link.