[SOLVED] Code to execute next Tab

[Jjs2060]

Is there code I could put at the end of a macro that will execute the next Tab position?

[Arineckaig]

Nothing simple as it would probably require the macro to be pre-programmed with an array of form controls listed in tab order.

[Villeroy]

Nothing simple as it would probably require the macro to be pre-programmed with an array of form controls listed in tab order.

objForm.getControlModels() returns an array of control models in tab order but you have to weed out the labels, hidden controls and may be some other controls.

Code: Select all

Sub test_getTabControls()
f = thiscomponent.drawpage.forms.getbyindex(0)
a() = getTabControls(f)
dim s$
for each m in a()
	s = s & m.Name & Chr(10)
next
msgbox s
End Sub

Function getTabControls(f)
REM return array of controls that can be tabbed into
Dim a()
for each m in f.getControlModels()
	if m.PropertySetInfo.hasPropertyByName("Tabstop") then
		if isEmpty(m.Tabstop) or m.Tabstop = True then
			if m.Enabled and m.EnableVisible then bas_PushArray(a(), m)
		endif
	endif
next
getTabControls = a()
End Function

'very simple routine appending some element to an array which can be undimensioned (LBound > UBound)
Sub bas_PushArray(xArray(),vNextElement)
Dim iUB%,iLB%
	iLB = lBound(xArray())
	iUB = uBound(xArray())
	If iLB > iUB then
		iUB = iLB
		redim xArray(iLB To iUB)
	else
		iUB = iUB +1
		redim preserve xArray(iLB To iUB)
	endif
	xArray(iUB) = vNextElement
End Sub

[Jjs2060]

Thanks.