[Solved] Open Basic IDE via macro

[Gerhard1234]

I am searching for the Basic command to open up the macro editor and to load a specific module in it.
----------------------------------------
The way to transfer the arguments to the BasicIDEAppear service seem to have changed. Especially the document name
needs to be given in a differen way, than it was before.

Following is the correct code, verified with LibreOffice Writer 4.3.5.2 the currently stable Version from http://www.libreoffice.org

Code: Select all

   dim aArgs(5) as New com.sun.star.beans.PropertyValue
   aArgs(0).Name="Document": aArgs(0).Value=ThisComponent.GetURL
   aArgs(1).Name="LibName": aArgs(1).Value="Standard"
   aArgs(2).Name="Name": aArgs(2).Value="Module1"
   aArgs(3).Name="Line": aArgs(3).Value=10
   aArgs(4).Name="Type": aArgs(4).Value="Module" 'may be Dialog or Module
   oFrame = CreateUnoService("com.sun.star.frame.Frame")
   oDispatchHelper = createUnoService("com.sun.star.frame.DispatchHelper")
   oTemp = oDispatchHelper.ExecuteDispatch(oFrame, ".uno:BasicIDEAppear" ,"" ,0 ,aArgs())

This code will open the Basic IDE, load the Standard library from the current document, open Module1 and
position the blinking cursor in line #10 to start editing there. Just that there is no misunderstanding: "The order
of the PropertyValues in the array do not make a difference." Following is an attachment document to
demonstrate this solution.

BasicIDEAppear.odt

Libreoffice writer document to demonstrate solution to open the Basic maro editor and display code in this document.

(32.83 KiB) Downloaded 235 times

Thanks alot, to all envolved!

P.S. I leave the other tipps in here for further reading.
----------------------------------------
Reading the answers, following is my conclusion:

The correct command to open up the IDE seems to be the following

Code: Select all

oTemp = oDispatchHelper.ExecuteDispatch(oFrame, ".uno:BasicIDEAppear" ,"" ,0 ,aOptions())

but for some reason this seems not to work any more.

There is a workaround to generate an error in a subroutine inside of the module to open, which opens the IDE
and a message box with an errormessage. The following code is an example for that.

Code: Select all

Sub OpenIDE
	thisComponent.makeError
End Sub

----------------------------------------
Thanks for you help!

[Zizi64]

Do you want to load a Library into the memory?

Code: Select all

if GlobalScope.BasicLibraries.hasByName("Name_of_Library") then
	if  Not GlobalScope.BasicLibraries.isLibraryLoaded("Name_of_Library") Then
		GlobalScope.BasicLibraries.LoadLibrary("Name_of_Library")
	End if 
End if

[hanya]

See: viewtopic.php?f=20&t=14849
"Document" option can be URL for a document if you want to open some macro stored in target document.

[hanya]

The correct command to open up the IDE seems to be the following

Code: Select all

oTemp = oDispatchHelper.ExecuteDispatch(oFrame, ".uno:BasicIDEAppear" ,"" ,0 ,aOptions())

but for some reason this seems not to work any more.

As I wrote:

"Document" option can be URL for a document if you want to open some macro stored in target document.

[Gerhard1234]

The correct command to open up the IDE seems to be the following

Code: Select all

oTemp = oDispatchHelper.ExecuteDispatch(oFrame, ".uno:BasicIDEAppear" ,"" ,0 ,aOptions())

but for some reason this seems not to work any more.

As I wrote:

"Document" option can be URL for a document if you want to open some macro stored in target document.

Sorry, I did not get your hint about the URL-format of the document name ...

[B Marcelly]

It means that you can simplify the code given in the above link.
Here I open the IDE in Module1 of library Standard of the document which runs the macro.
I have modified the presentation for easier reading.

Code: Select all

    sub sOpenMacroEditor
       dim aOptions(4) as New com.sun.star.beans.PropertyValue
       aOptions(0).Name="LibName"
       aOptions(0).Value="Standard"  ' Name of library
       aOptions(1).Name="Name"
       aOptions(1).Value="Module1"   ' Name from Module or Dialog
       aOptions(2).Name="Line"
       aOptions(2).Value=440 ' Position the cursor at this line number in the module
       aOptions(3).Name="Type"
       aOptions(3).Value="Module"   ' Module or Dialog
       aOptions(4).Name="Document"
       aOptions(4).Value= ThisComponent.URL  ' indicate the URL of the document
       oFrame = CreateUnoService("com.sun.star.frame.Frame")
       oDispatchHelper = createUnoService("com.sun.star.frame.DispatchHelper")
       oTemp = oDispatchHelper.ExecuteDispatch(oFrame, ".uno:BasicIDEAppear" ,"" ,0 ,aOptions())
    end sub