[Solved] Open a file with http authentication with a macro

[dillydal]

I have written a macro to open an xml file which is protected by http authentication in calc -

Code: Select all

dim sURL as string 
dim oArgs(0) As New com.sun.star.beans.PropertyValue
dim oDocStatus as object
dim oihandler 
oihandler = createUnoService("com.sun.star.task.InteractionHandler")
sURL = "http://127.0.0.1:8080/requests/status.xml"
oArgs(0).Name = "InteractionHandler"
oArgs(0).Value = oihandler
oDocStatus = StarDesktop.loadComponentFromURL(sURL, "_default", 0, oArgs)

This works fine except that each time I run it -

I have to key in my user name / password in an Authentication Required window
I have to click OK on the subsequent "Text Import" window.
How could I improve this macro to avoid repetitively doing these actions? (removing http authentication from the xml page is not possible)

[Mr.Dandy]

Hello,

Did you try to pass user and password directly in the URL?

[dillydal]

Do you mean http://username:password@127.0.0.1:8080 ... status.xml ?

No, it doesn't work. In fact it causes libreoffice to crash. However, the above URL does automatically log in when I paste it in Google Chrome.

[Villeroy]

StarBasic is a simple API caller for this office suite. Downloading data via http behind a log-in would be easy to do without any office suite at all, using any of the well established, fully featured programming languages.

[dillydal]

Do you mean UNO doesn't not provide an "non-interactive http authentication" service?
What about the "Text Import" window? Is there a way specify the default import settings when opening a file?

[hanya]

You need custom interaction handler for the authentication.

Code: Select all

Sub AuthenticationTest
  dim sURL as string
  dim oArgs(0) As New com.sun.star.beans.PropertyValue
  dim oDocStatus as object
  dim oihandler
  oihandler = CreateUnoListener("InteractionHandler_", "com.sun.star.task.XInteractionHandler")
  sURL = "http://127.0.0.1:8080/requests/status.xml"
  oArgs(0).Name = "InteractionHandler"
  oArgs(0).Value = oihandler
  oDocStatus = StarDesktop.loadComponentFromURL(sURL, "_default", 0, oArgs)
End Sub


Sub InteractionHandler_handle(req)
  r = req.getRequest()
  If CheckExceptionType(r, "com.sun.star.ucb.URLAuthenticationRequest") Then
    conts = req.getContinuations()
    for i = 0 to ubound(conts) step 1
      cont = conts(i)
      If HasUnoInterfaces(cont, "com.sun.star.ucb.XInteractionSupplyAuthentication2") Then
        cont.setUserName("foo")
        cont.setPassword("bar")
        cont.select()
        Exit For
      End If
    next
  End If
End Sub


Function CheckExceptionType(e, sType As String) As Boolean
  ret = False
  idlclass = CreateUnoService("com.sun.star.reflection.CoreReflection").getType(e)
  If not IsNull(idlclass) Then
    ret = (idlclass.getTypeClass() = com.sun.star.uno.TypeClass.EXCEPTION and _
           idlclass.getName() = sType)
  End If
  CheckExceptionType = ret
End Function

And pass FilterName to loadComponentFromURL method to choose the filter to open the file, you can find some examples for this way.

[Mr.Dandy]

No, it doesn't work. In fact it causes libreoffice to crash.

I try this code and no problem with AOO:

Code: Select all

Function GetFileViaHttp
	Dim url$
	Dim oHttp As Object
	
	url = "http://username:password@127.0.0.1:8080/requests/status.xml"
	Set oHttp = CreateObject("MSXML2.XMLHTTP")
	
	oHttp.Open "GET", url, False
	oHttp.Send
	GetFileViaHttp = oHttp.responseText
End Function

[dillydal]

No, it doesn't work. In fact it causes libreoffice to crash.

I try this code and no problem with AOO:

Code: Select all

Function GetFileViaHttp
	Dim url$
	Dim oHttp As Object
	
	url = "http://username:password@127.0.0.1:8080/requests/status.xml"
	Set oHttp = CreateObject("MSXML2.XMLHTTP")
	
	oHttp.Open "GET", url, False
	oHttp.Send
	GetFileViaHttp = oHttp.responseText
End Function

When tested your code, the debugger stopped on the line

Code: Select all

oHttp.Open "GET", url, False

and displayed an error messsage -

BASIC runtime error.
An exception occurred
Type: com.sun.star.uno.RuntimeException
Message: [automation bridge] unexpected exception in IUnknownWrapper_Impl::hasMethod !.

[dillydal]

You need custom interaction handler for the authentication.

Code: Select all

Sub AuthenticationTest
  dim sURL as string
  dim oArgs(0) As New com.sun.star.beans.PropertyValue
  dim oDocStatus as object
  dim oihandler
  oihandler = CreateUnoListener("InteractionHandler_", "com.sun.star.task.XInteractionHandler")
  sURL = "http://127.0.0.1:8080/requests/status.xml"
  oArgs(0).Name = "InteractionHandler"
  oArgs(0).Value = oihandler
  oDocStatus = StarDesktop.loadComponentFromURL(sURL, "_default", 0, oArgs)
End Sub


Sub InteractionHandler_handle(req)
  r = req.getRequest()
  If CheckExceptionType(r, "com.sun.star.ucb.URLAuthenticationRequest") Then
    conts = req.getContinuations()
    for i = 0 to ubound(conts) step 1
      cont = conts(i)
      If HasUnoInterfaces(cont, "com.sun.star.ucb.XInteractionSupplyAuthentication2") Then
        cont.setUserName("foo")
        cont.setPassword("bar")
        cont.select()
        Exit For
      End If
    next
  End If
End Sub


Function CheckExceptionType(e, sType As String) As Boolean
  ret = False
  idlclass = CreateUnoService("com.sun.star.reflection.CoreReflection").getType(e)
  If not IsNull(idlclass) Then
    ret = (idlclass.getTypeClass() = com.sun.star.uno.TypeClass.EXCEPTION and _
           idlclass.getName() = sType)
  End If
  CheckExceptionType = ret
End Function

And pass FilterName to loadComponentFromURL method to choose the filter to open the file, you can find some examples for this way.

I don't yet understand your code but it works perfectly! Thanks