[Résolu][Calc] Supprimer ligne vide d'une plage de cellules

[psylo24]

Bonsoir tout le monde e meilleurs voeux pour cette nouvelle année.

Je suis sous libreoffice calc et j'essaie de faire une macro pour supprimer les lignes si une cellule est vide mais cela pour une plage déterminée de ma feuille à savoir de B30 à B50.

Je veux faire ca par une macro car je vais avoir besoin de le faire régulièrement sur cette plage de de cellule.

Voir fichier en piéce jointe

exemple.ods

Merci et à biento

[Noonours]

Bonjour,

Sujet passé des milliards de fois je crois...
une recherche avec Clearcontents t'aurais donné des résultats quasi clefs en mains.

Essaye celui-ci:

Code : Tout sélectionner

Sub Effass

ZoneCible = "B30:B50"

Dim oSheet As Object, oRange As Object

   oFeuille1 = thisComponent.Sheets (0)   ' "Feuille1"
   oPlage = ofeuille1.GetCellRangeByName (ZoneCible)
   with com.sun.star.sheet.CellFlags
   oPlage.clearContents(.VALUE + .STRING + .FORMULA)
   end with
                  
End Sub

Cordialement,

[OOotremer971]

Bonjour à tous,

Hello Noonours c'est un restant de bulle du champagne du nouvel an ou t'as lu en diagonale ?

Code : Tout sélectionner

Option Explicit

Const zoneCible = "B30:B50"


Sub Main
Dim oDoc As Object
Dim oCC As Object
Dim oSheet As Object
Dim oPlage As Object
Dim oRa As Object
Dim oCell As Object
Dim oRow As Object
Dim i As Integer
oDoc = Thiscomponent
oCC = oDoc.CurrentController
oSheet = oCC.ActiveSheet 'récupère la feuille active
oPlage = oSheet.GetCellRangeByName(zoneCible)
oRa = oPlage.RangeAddress
For i = oRa.EndRow To oRa.StartRow Step - 1
	oCell = oSheet.GetCellByPosition(oRa.StartColumn,i)
	If oCell.String = "" Then
		oSheet.Rows.RemoveByIndex(i,1)
	End if
Next 
End Sub

et le fichier pour tester.

[psylo24]

Super merci beaucoup ca fonctionne parfaitement.